meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.17.2.1',
   3   meson_version : '>= 0.49',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version = meson.project_version()
  10 version_arr = gst_version.split('.')
  11 gst_version_major = version_arr[0].to_int()
  12 gst_version_minor = version_arr[1].to_int()
  13 gst_version_micro = version_arr[2].to_int()
  14  if version_arr.length() == 4
  15   gst_version_nano = version_arr[3].to_int()
  16 else
  17   gst_version_nano = 0
  18 endif
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 curversion = gst_version_minor * 100 + gst_version_micro
  25 libversion = '@0@.@1@.0'.format(soversion, curversion)
  26 osxversion = curversion + 1
  27
  28 glib_req = '>= 2.44.0'
  29 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  30
  31 cc = meson.get_compiler('c')
  32 mathlib = cc.find_library('m', required : false)
  33
  34 cdata = configuration_data()
  35
  36 prefix = get_option('prefix')
  37 datadir = prefix / get_option('datadir')
  38
  39 # Ignore several spurious warnings for things gstreamer does very commonly
  40 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  41 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  42 # NOTE: Only add warnings here if you are sure they're spurious
  43 if cc.get_id() == 'msvc'
  44   add_project_arguments(
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       language : 'c')
  50 endif
  51
  52 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  53   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  54 endif
  55
  56 # Symbol visibility
  57 if cc.get_id() == 'msvc'
  58   export_define = '__declspec(dllexport) extern'
  59 elif cc.has_argument('-fvisibility=hidden')
  60   add_project_arguments('-fvisibility=hidden', language: 'c')
  61   export_define = 'extern __attribute__ ((visibility ("default")))'
  62 else
  63   export_define = 'extern'
  64 endif
  65
  66 # Passing this through the command line would be too messy
  67 cdata.set('GST_API_EXPORT', export_define)
  68
  69 # Disable strict aliasing
  70 if cc.has_argument('-fno-strict-aliasing')
  71   add_project_arguments('-fno-strict-aliasing', language: 'c')
  72 endif
  73
  74 cdata.set('VERSION', '"@0@"'.format(gst_version))
  75 cdata.set('PACKAGE', '"gst-editing-services"')
  76 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  77 cdata.set('PACKAGE_BUGREPORT', '"https://gitlab.freedesktop.org/gstreamer/gst-editing-services/issues/new"')
  78 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  79 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  80 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  81 cdata.set('GST_LICENSE', '"LGPL"')
  82
  83 # Mandatory GST deps
  84 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  85     fallback : ['gstreamer', 'gst_dep'])
  86 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  87     fallback : ['gst-plugins-base', 'pbutils_dep'])
  88 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  89     fallback : ['gst-plugins-base', 'video_dep'])
  90 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  91     fallback : ['gstreamer', 'gst_base_dep'])
  92 if host_machine.system() != 'windows'
  93   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  94     required : get_option('tests'),
  95     fallback : ['gstreamer', 'gst_check_dep'])
  96 endif
  97 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  98   fallback : ['gstreamer', 'gst_controller_dep'])
  99 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : get_option('validate'),
 100   fallback : ['gst-devtools', 'validate_dep'])
 101
 102 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 103 libxml_dep = dependency('libxml-2.0', required: get_option('xptv'))
 104 cdata.set('DISABLE_XPTV', not libxml_dep.found())
 105
 106 # TODO Properly port to Gtk 3
 107 # gtk_dep = dependency('gtk+-3.0', required : false)
 108
 109 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
 110                gstcontroller_dep, gio_dep, libxml_dep, mathlib]
 111
 112 if gstvalidate_dep.found()
 113     libges_deps = libges_deps + [gstvalidate_dep]
 114     cdata.set('HAVE_GST_VALIDATE', 1)
 115 endif
 116
 117 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 118 gnome = import('gnome')
 119
 120 # Fixme, not very elegant.
 121 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 122 gir_init_section = [ '--add-init-section=' + \
 123     'extern void gst_init(gint*,gchar**);' + \
 124     'extern void ges_init(void);' + \
 125     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 126     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 127     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 128     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 129     'gst_init(NULL,NULL);' + \
 130     'ges_init();', '--quiet']
 131
 132 has_python = false
 133 if build_gir
 134   pymod = import('python')
 135   python = pymod.find_installation(required: get_option('python'))
 136   if python.found()
 137     # Workaround for https://github.com/mesonbuild/meson/issues/5629
 138     pythonver = python.language_version()
 139     python_dep = dependency('python-@0@-embed'.format(pythonver), version: '>=3', required: false)
 140     if not python_dep.found()
 141       python_dep = python.dependency(required : get_option('python'))
 142     endif
 143   else
 144     python_dep = dependency('', required: false)
 145   endif
 146   if python_dep.found()
 147     python_abi_flags = python.get_variable('ABIFLAGS', '')
 148     pylib_loc = get_option('libpython-dir')
 149
 150     error_msg = ''
 151     if not cc.compiles('#include <Python.h>', dependencies: [python_dep])
 152       error_msg = 'Could not compile a simple program against python'
 153     elif pylib_loc == ''
 154       check_path_exists = 'import os, sys; assert(os.path.exists(sys.argv[1]))'
 155       pylib_loc = python.get_variable('LIBPL', '')
 156       if host_machine.system() != 'windows' and host_machine.system() != 'darwin'
 157         pylib_ldlibrary = python.get_variable('LDLIBRARY', '')
 158         if run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary)).returncode() != 0
 159           # Workaround for Fedora
 160           pylib_loc = python.get_variable('LIBDIR', '')
 161           message('pylib_loc = @0@'.format(pylib_loc))
 162         endif
 163
 164         res = run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary))
 165         if res.returncode() != 0
 166           error_msg = '@0@ doesn\' exist, can\'t use python'.format(join_paths(pylib_loc, pylib_ldlibrary))
 167         endif
 168       endif
 169       if error_msg == ''
 170         pylib_suffix = 'so'
 171         if host_machine.system() == 'windows'
 172           pylib_suffix = 'dll'
 173         elif host_machine.system() == 'darwin'
 174           pylib_suffix = 'dylib'
 175         endif
 176
 177         gmodule_dep = dependency('gmodule-2.0')
 178         libges_deps = libges_deps + [python_dep, gmodule_dep]
 179         has_python = true
 180         message('python_abi_flags = @0@'.format(python_abi_flags))
 181         message('pylib_loc = @0@'.format(pylib_loc))
 182         cdata.set('HAS_PYTHON', true)
 183         cdata.set('PY_LIB_LOC', '"@0@"'.format(pylib_loc))
 184         cdata.set('PY_ABI_FLAGS', '"@0@"'.format(python_abi_flags))
 185         cdata.set('PY_LIB_SUFFIX', '"@0@"'.format(pylib_suffix))
 186         cdata.set('PYTHON_VERSION', '"@0@"'.format(python_dep.version()))
 187       else
 188           if get_option('python').enabled()
 189             error(error_msg)
 190           else
 191             message(error_msg)
 192           endif
 193       endif
 194     endif
 195   endif
 196 endif
 197
 198 ges_c_args = ['-DHAVE_CONFIG_H', '-DG_LOG_DOMAIN="GES"']
 199 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 200
 201 pkgconfig = import('pkgconfig')
 202 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 203 if get_option('default_library') == 'shared'
 204   # If we don't build static plugins there is no need to generate pc files
 205   plugins_pkgconfig_install_dir = disabler()
 206 endif
 207
 208 if gst_dep.type_name() == 'internal'
 209   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 210 else
 211   # We can't check that in the case of subprojects as we won't
 212   # be able to build against an internal dependency (which is not built yet)
 213   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 214 endif
 215
 216 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 217   add_project_arguments('-Wno-unused', language: 'c')
 218 endif
 219
 220 warning_flags = [
 221   '-Wmissing-declarations',
 222   '-Wmissing-prototypes',
 223   '-Wredundant-decls',
 224   '-Wundef',
 225   '-Wwrite-strings',
 226   '-Wformat',
 227   '-Wformat-security',
 228   '-Winit-self',
 229   '-Wmissing-include-dirs',
 230   '-Waddress',
 231   '-Wno-multichar',
 232   '-Wdeclaration-after-statement',
 233   '-Wvla',
 234   '-Wpointer-arith',
 235 ]
 236
 237 foreach extra_arg : warning_flags
 238   if cc.has_argument (extra_arg)
 239     add_project_arguments([extra_arg], language: 'c')
 240   endif
 241 endforeach
 242
 243 python3 = import('python').find_installation()
 244 configinc = include_directories('.')
 245 subdir('ges')
 246 subdir('plugins')
 247 if not get_option('tools').disabled()
 248   subdir('tools')
 249 endif
 250 subdir('pkgconfig')
 251 subdir('tests')
 252 if not get_option('examples').disabled()
 253   subdir('examples')
 254 endif
 255 subdir('docs')
 256
 257 override_detector = '''
 258 import sys
 259 import os
 260
 261 prefix = sys.argv[1]
 262 version = sys.version_info
 263
 264 # If we are installing in the same prefix as PyGobject
 265 # make sure to install in the right place.
 266 import gi.overrides
 267
 268 overrides_path = os.path.dirname(gi.overrides.__file__)
 269 if os.path.commonprefix([overrides_path, prefix]) == prefix:
 270     print(overrides_path)
 271     exit(0)
 272
 273 # Otherwise follow python's way of install site packages inside
 274 # the provided prefix
 275 if os.name == 'posix':
 276     print(os.path.join(
 277         prefix, 'lib', 'python%d.%d' % (version.major, version.minor),
 278         'site-packages', 'gi', 'overrides'))
 279 else:
 280     print(os.path.join(
 281         prefix, 'Lib', 'Python%d%d' % (version.major, version.minor),
 282         'site-packages', 'gi', 'overrides'))
 283 '''
 284 pygi_override_dir = get_option('pygi-overrides-dir')
 285 if pygi_override_dir == ''
 286     cres = run_command(python3, '-c', override_detector, get_option('prefix'))
 287     if cres.returncode() == 0
 288       pygi_override_dir = cres.stdout().strip()
 289     endif
 290     if cres.stderr() != ''
 291         message(cres.stderr())
 292     endif
 293 endif
 294
 295 if pygi_override_dir != ''
 296   message('pygobject overrides directory ' + pygi_override_dir)
 297   subdir('bindings/python')
 298 endif
 299
 300 # Set release date
 301 if gst_version_nano == 0
 302   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 303   run_result = run_command(extract_release_date, gst_version, files('gst-editing-services.doap'))
 304   if run_result.returncode() == 0
 305     release_date = run_result.stdout().strip()
 306     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 307     message('Package release date: ' + release_date)
 308   else
 309     # Error out if our release can't be found in the .doap file
 310     error(run_result.stderr())
 311   endif
 312 endif
 313
 314 configure_file(output: 'config.h', configuration: cdata)
 315
 316 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')