meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22
  23 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  24
  25 cc = meson.get_compiler('c')
  26
  27 if cc.get_id() == 'msvc'
  28   # Ignore several spurious warnings for things gstreamer does very commonly
  29   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31   # NOTE: Only add warnings here if you are sure they're spurious
  32   add_project_arguments(
  33       '/wd4018', # implicit signed/unsigned conversion
  34       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  35       '/wd4244', # lossy type conversion (e.g. double -> int)
  36       '/wd4305', # truncating type conversion (e.g. double -> float)
  37       language : 'c')
  38   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  39   # are built with MinGW
  40   noseh_link_args = ['/SAFESEH:NO']
  41 else
  42   noseh_link_args = []
  43 endif
  44
  45 # Symbol visibility
  46 if cc.has_argument('-fvisibility=hidden')
  47   add_project_arguments('-fvisibility=hidden', language: 'c')
  48 endif
  49
  50 # Disable strict aliasing
  51 if cc.has_argument('-fno-strict-aliasing')
  52   add_project_arguments('-fno-strict-aliasing', language: 'c')
  53 endif
  54
  55 cdata = configuration_data()
  56
  57 check_headers = [
  58   ['HAVE_DLFCN_H', 'dlfcn.h'],
  59   ['HAVE_FCNTL_H', 'fcntl.h'],
  60   ['HAVE_INTTYPES_H', 'inttypes.h'],
  61   ['HAVE_MEMORY_H', 'memory.h'],
  62   ['HAVE_PROCESS_H', 'process.h'],
  63   ['HAVE_STDINT_H', 'stdint.h'],
  64   ['HAVE_STDLIB_H', 'stdlib.h'],
  65   ['HAVE_STRINGS_H', 'strings.h'],
  66   ['HAVE_STRING_H', 'string.h'],
  67   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
  68   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  69   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  70   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  71   ['HAVE_SYS_TIME_H', 'sys/time.h'],
  72   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  73   ['HAVE_UNISTD_H', 'unistd.h'],
  74 ]
  75
  76 foreach h : check_headers
  77   if cc.has_header(h.get(1))
  78     cdata.set(h.get(0), 1)
  79   endif
  80 endforeach
  81
  82 check_functions = [
  83   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
  84   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
  85   ['HAVE_COSH', 'cosh', '#include<math.h>'],
  86 # check token HAVE_CPU_ALPHA
  87 # check token HAVE_CPU_ARM
  88 # check token HAVE_CPU_CRIS
  89 # check token HAVE_CPU_CRISV32
  90 # check token HAVE_CPU_HPPA
  91 # check token HAVE_CPU_I386
  92 # check token HAVE_CPU_IA64
  93 # check token HAVE_CPU_M68K
  94 # check token HAVE_CPU_MIPS
  95 # check token HAVE_CPU_PPC
  96 # check token HAVE_CPU_PPC64
  97 # check token HAVE_CPU_S390
  98 # check token HAVE_CPU_SPARC
  99 # check token HAVE_CPU_X86_64
 100   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 101 # check token HAVE_DIRECTSOUND
 102 # check token HAVE_EXPERIMENTAL
 103 # check token HAVE_EXTERNAL
 104 # check token HAVE_FPCLASS
 105 # check token HAVE_GCC_ASM
 106   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 107 # check token HAVE_GETTEXT
 108 # check token HAVE_GST_V4L2
 109 # check token HAVE_IOS
 110   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 111 # check token HAVE_LIBV4L2
 112   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 113   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 114 # check token HAVE_OSX_AUDIO
 115 # check token HAVE_OSX_VIDEO
 116 # check token HAVE_RDTSC
 117   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 118 # check token HAVE_WAVEFORM
 119 ]
 120
 121 libm = cc.find_library('m', required : false)
 122
 123 foreach f : check_functions
 124   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 125     cdata.set(f.get(0), 1)
 126   endif
 127 endforeach
 128
 129 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 130 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 131 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 132 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 133 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 134 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 135
 136 # Here be fixmes.
 137 # FIXME: check if this is correct
 138 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 139 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 140 cdata.set('VERSION', '"@0@"'.format(gst_version))
 141 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 142 cdata.set('GST_LICENSE', '"LGPL"')
 143 cdata.set('PACKAGE', '"gst-plugins-good"')
 144 cdata.set('GETTEXT_PACKAGE', '"gst-plugins-good-1.0"')
 145
 146 # GStreamer package name and origin url
 147 gst_package_name = get_option('with-package-name')
 148 if gst_package_name == ''
 149   if gst_version_nano == 0
 150     gst_package_name = 'GStreamer Good Plug-ins source release'
 151   elif gst_version_nano == 1
 152     gst_package_name = 'GStreamer Good Plug-ins git'
 153   else
 154     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 155   endif
 156 endif
 157 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 158 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 159
 160 # Mandatory GST deps
 161 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 162   fallback : ['gstreamer', 'gst_dep'])
 163 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 164   fallback : ['gstreamer', 'gst_base_dep'])
 165 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 166   fallback : ['gstreamer', 'gst_net_dep'])
 167 if host_machine.system() != 'windows'
 168   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 169     fallback : ['gstreamer', 'gst_check_dep'])
 170 endif
 171 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 172   fallback : ['gstreamer', 'gst_controller_dep'])
 173
 174 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 175     fallback : ['gst-plugins-base', 'pbutils_dep'])
 176 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 177     fallback : ['gst-plugins-base', 'allocators_dep'])
 178 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 179     fallback : ['gst-plugins-base', 'app_dep'])
 180 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 181     fallback : ['gst-plugins-base', 'audio_dep'])
 182 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 183     fallback : ['gst-plugins-base', 'fft_dep'])
 184 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 185     fallback : ['gst-plugins-base', 'riff_dep'])
 186 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 187     fallback : ['gst-plugins-base', 'rtp_dep'])
 188 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 189     fallback : ['gst-plugins-base', 'rtsp_dep'])
 190 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 191     fallback : ['gst-plugins-base', 'sdp_dep'])
 192 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 193     fallback : ['gst-plugins-base', 'tag_dep'])
 194 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 195     fallback : ['gst-plugins-base', 'video_dep'])
 196
 197 zlib_dep = dependency('zlib', required : false)
 198 bz2lib = cc.find_library('bz2', required : false)
 199 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 200              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 201 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 202
 203 cdata.set('HAVE_ZLIB', zlib_dep.found())
 204 cdata.set('HAVE_BZ2', bz2lib.found())
 205
 206 # Check all of the things.
 207 # TODO: None of these are actually used yet because
 208 # the build files haven't been written
 209 deps = [
 210   ['gtk_dep','gtk+-3.0', '', ''],
 211   ['gtkx_dep','gtk+-x11-3.0', '', ''],
 212   ['caca_dep','caca', '', ''],
 213   ['libraw1394_dep','libraw1394', '>=2.0.0', ''],
 214   ['libiec61883_dep','libiec61883', '>=1.0.0', ''],
 215 ]
 216
 217 foreach d : deps
 218   varname = d[0]
 219   depname = d[1]
 220   version = d[2]
 221   confhname = d[3]
 222   if version == ''
 223     curdep = dependency(depname, required : false)
 224   else
 225     curdep = dependency(depname, required : false, version : version)
 226   endif
 227   set_variable(varname, curdep)
 228   if curdep.found() and confhname != ''
 229     cdata.set(confhname, 1)
 230   endif
 231 endforeach
 232
 233 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 234 configinc = include_directories('.')
 235 libsinc = include_directories('gst-libs')
 236
 237 have_orcc = false
 238 orcc_args = []
 239 if get_option('use_orc') != 'no'
 240   need_orc = get_option('use_orc') == 'yes'
 241   # Used by various libraries/elements that use Orc code
 242   orc_dep = dependency('orc-0.4', version : '>= 0.4.17', required : need_orc)
 243   orcc = find_program('orcc', required : need_orc)
 244   if orc_dep.found() and orcc.found()
 245     have_orcc = true
 246     orcc_args = [orcc, '--include', 'glib.h']
 247     cdata.set('HAVE_ORC', 1)
 248   else
 249     message('Orc Compiler not found, will use backup C code')
 250     cdata.set('DISABLE_ORC', 1)
 251   endif
 252 else
 253   cdata.set('DISABLE_ORC', 1)
 254 endif
 255
 256 if gst_dep.type_name() == 'internal'
 257     gst_proj = subproject('gstreamer')
 258
 259     if gst_proj.get_variable('disable_gst_debug')
 260         message('GStreamer debug system is disabled')
 261         add_project_arguments('-Wno-unused', language: 'c')
 262     else
 263         message('GStreamer debug system is enabled')
 264     endif
 265 else
 266     # We can't check that in the case of subprojects as we won't
 267     # be able to build against an internal dependency (which is not built yet)
 268     if not cc.compiles('''
 269 #include <gst/gstconfig.h>
 270 #ifdef GST_DISABLE_GST_DEBUG
 271 #error "debugging disabled, make compiler fail"
 272 #endif''' , dependencies: gst_dep)
 273         message('GStreamer debug system is disabled')
 274         add_project_arguments('-Wno-unused', language: 'c')
 275     else
 276         message('GStreamer debug system is enabled')
 277     endif
 278 endif
 279
 280 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 281
 282 subdir('gst')
 283 subdir('sys')
 284 subdir('ext')
 285 subdir('tests')
 286 subdir('pkgconfig')
 287
 288 # xgettext is optional (on Windows for instance)
 289 if find_program('xgettext', required : false).found()
 290   subdir('po')
 291 endif
 292
 293 configure_file(output : 'config.h', configuration : cdata)
 294
 295 python3 = import('python3').find_python()
 296 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')