meson.build

   1 project('gstreamer-full', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.62.0',
   4   default_options : ['buildtype=debugoptimized',
   5                      # Needed due to https://github.com/mesonbuild/meson/issues/1889,
   6                      # but this can cause problems in the future. Remove it
   7                      # when it's no longer necessary.
   8                      'cpp_std=c++14'])
   9
  10 apiversion = '1.0'
  11 gst_version = '>= @0@'.format(meson.project_version())
  12
  13 build_system = build_machine.system()
  14 cc = meson.get_compiler('c')
  15
  16 fs = import('fs')
  17 gnome = import('gnome')
  18 pkgconfig = import('pkgconfig')
  19 python3 = import('python').find_installation()
  20 # Ensure that we're not being run from inside the development environment
  21 # because that will confuse meson, and it might find the already-built
  22 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  23 # reconfigure because ninja doesn't care about the env.
  24 ensure_not_devenv = '''
  25 import os
  26 assert('GST_ENV' not in os.environ)
  27 '''
  28 cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
  29 if cmdres.returncode() != 0
  30   error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
  31 endif
  32
  33 # Install gst-indent pre-commit hook
  34 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
  35
  36 # On macOS, you have to run "Install Certificates.command" otherwise Python
  37 # doesn't have access to the latest SSL CA Certificates, and Meson will fail to
  38 # download wrap files from websites that use, for example, Let's Encrypt.
  39 # We already recommend this in the README, but add a warning here as well.
  40 # Can't make this an error because the user might be using XCode's Python
  41 # 3 which doesn't have this script.
  42 if build_system == 'darwin'
  43   python3_cacert_file = python3.get_path('data') / 'etc/openssl/cert.pem'
  44   install_cert_cmd = '/Applications/Python @0@/Install Certificates.command'.format(python3.language_version())
  45   if not fs.is_symlink(python3_cacert_file) and fs.is_file(install_cert_cmd)
  46     warning('Please run "@0@" so that Python has access to the latest SSL certificates. Meson might fail to download some wraps without it.'.format(install_cert_cmd))
  47   endif
  48 endif
  49
  50 documented_projects = ''
  51 # Make it possible to use msys2 built zlib which fails
  52 # when not using the mingw toolchain as it uses unistd.h
  53 if not meson.is_subproject() and cc.get_id() == 'msvc'
  54   uname = find_program('uname', required: false)
  55   if uname.found()
  56     ret = run_command(uname, '-o', check: false)
  57     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  58       ret = run_command(uname, '-r', check: false)
  59       # The kernel version returned by uname is actually the msys version
  60       if ret.returncode() == 0 and ret.stdout().startswith('2')
  61         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  62         if cc.find_library('z').found()
  63           add_global_arguments('-DZ_SOLO', language: 'c')
  64         endif
  65       endif
  66     endif
  67   endif
  68 endif
  69
  70 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  71 # not a subproject, because subprojects are not allowed to call
  72 # add_global_arguments().
  73 if not meson.is_subproject() and cc.get_id() == 'msvc'
  74   add_global_arguments(
  75       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  76       language: ['c', 'cpp'])
  77 endif
  78
  79 building_full = get_option('default_library') == 'static'
  80 tools_option = 'tools=auto'
  81 if building_full and not get_option('tools').disabled()
  82   # Do not build subprojects tools when we build them against gst-full
  83   tools_option = 'tools=disabled'
  84 endif
  85
  86 # Ordered list of subprojects (dict has no ordering guarantees)
  87 subprojects = [
  88   ['gstreamer', {'build-hotdoc': true, 'subproject_options': [tools_option]}],
  89   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
  90   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
  91   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
  92   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
  93   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
  94   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
  95   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
  96   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
  97   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
  98   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
  99   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
 100   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
 101   ['gstreamer-sharp', { 'option': get_option('sharp') }],
 102   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
 103   ['gst-python', { 'option': get_option('python')}],
 104   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
 105   ['gst-plugins-rs', { 'option': get_option('rs'), 'build-hotdoc': true, 'match_gst_version': false}],
 106 ]
 107
 108 symlink = '''
 109 import os
 110
 111 os.symlink(os.path.join('@1@', 'subprojects', '@0@'),
 112   os.path.join('@1@', '@0@'))
 113 '''
 114
 115 if build_system == 'windows'
 116   subproject('win-flex-bison-binaries')
 117   subproject('win-nasm')
 118 elif build_system == 'darwin'
 119   subproject('macos-bison-binary')
 120 endif
 121
 122 orc_subproject = subproject('orc', required: get_option('orc'))
 123
 124 foreach custom_subproj: get_option('custom_subprojects').split(',')
 125     if custom_subproj != ''
 126         message ('Adding custom subproject ' + custom_subproj)
 127         subprojects += [[custom_subproj, {'match_gst_version': false}]]
 128     endif
 129 endforeach
 130
 131
 132 subprojects_names = []
 133 plugins_doc_caches = []
 134 orc_update_targets = []
 135 all_plugins = []
 136 all_tools = {}
 137 # Using a list and not a dict to keep the ordering to build the chain of `gir`
 138 # dependencies
 139 all_libraries = []
 140 foreach sp : subprojects
 141   project_name = sp[0]
 142   build_infos = sp[1]
 143   is_required = build_infos.get('option', true)
 144   sysdep = build_infos.get('sysdep', '')
 145   sysdep_version = build_infos.get('sysdep_version', '')
 146   match_gst_version = build_infos.get('match_gst_version', true)
 147   default_options =  build_infos.get('subproject_options', [])
 148
 149   if match_gst_version
 150     subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
 151   elif sysdep != ''
 152       sysdep_dep = dependency(sysdep, version: sysdep_version, required: false, default_options: default_options)
 153       if not sysdep_dep.found()
 154         subproj = subproject(project_name, required: is_required, default_options: default_options)
 155       endif
 156   else
 157     subproj = subproject(project_name, required: is_required, default_options: default_options)
 158   endif
 159
 160   if subproj.found()
 161     plugins = subproj.get_variable('gst_plugins', [])
 162     legacy_plugins = subproj.get_variable('plugins', [])
 163     all_plugins += plugins
 164     if plugins.length() == 0 and legacy_plugins.length() > 0
 165       warning(f'DEPRECATED use of the `plugins` variable in @project_name@.')
 166       warning('The variable should now be called `gst_plugins` and use:')
 167       warning('`declare_dependency( link_with: <plugin_target>, variable: {\'full_path\': <plugin_target>.full_path()})` instead')
 168       foreach plugin: legacy_plugins
 169         all_plugins += [declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})]
 170       endforeach
 171     endif
 172
 173     all_libraries += subproj.get_variable('gst_libraries', [])
 174     if not get_option('tools').disabled()
 175       all_tools += subproj.get_variable('gst_tools', {})
 176     endif
 177
 178     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 179
 180     subprojects_names += [project_name]
 181
 182     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 183       plugins_doc_caches += [subproj.get_variable('gst_plugins_doc_dep', [])]
 184       if documented_projects != ''
 185         documented_projects += ','
 186       endif
 187       documented_projects  += project_name
 188     endif
 189   endif
 190 endforeach
 191
 192 # Check if we need to also build glib-networking for TLS modules
 193 giomodules = []
 194 glib_dep = dependency('glib-2.0')
 195 if glib_dep.type_name() == 'internal'
 196   subp = subproject('glib-networking', required : get_option('tls'),
 197              default_options: ['gnutls=auto', 'openssl=auto'])
 198   if subp.found()
 199     giomodules += subp.get_variable('giomodules', [])
 200   endif
 201 endif
 202
 203 gst_plugins_doc_dep = custom_target('plugins-doc-cache',
 204   command: [python3, '-c', 'print("Built all doc caches")'],
 205   input: plugins_doc_caches,
 206   output: 'plugins_doc_caches',
 207   capture: true,
 208 )
 209
 210 if meson.is_cross_build() or build_machine.system() == 'windows'
 211     if get_option('doc').enabled()
 212         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 213     endif
 214
 215     documented_projects = ''
 216     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 217 else
 218   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 219   if not hotdoc_p.found()
 220     documented_projects = ''
 221     message('Not building documentation as hotdoc was not found')
 222   endif
 223 endif
 224
 225 write_file_contents = '''
 226 import os
 227 import sys
 228
 229 assert len(sys.argv) >= 3
 230 fname = sys.argv[1]
 231 contents = sys.argv[2]
 232
 233 with open(fname, 'w') as f:
 234     f.write(contents)
 235 '''
 236
 237 configure_file(
 238   output : 'GstDocumentedSubprojects',
 239   command : [python3,
 240              '-c', write_file_contents,
 241              '@OUTPUT@',
 242              documented_projects]
 243 )
 244
 245 if documented_projects != ''
 246   subproject('gst-docs', required: get_option('doc').enabled())
 247   message('Gst docs subprojects: ' + documented_projects)
 248 endif
 249
 250 all_plugins_paths = []
 251 all_plugins_dirs = []
 252 plugins_names = []
 253 foreach plugin: all_plugins
 254   plugin_path = plugin.get_variable('full_path')
 255   all_plugins_paths += plugin_path
 256   all_plugins_dirs += fs.parent(plugin_path)
 257   plugins_names += plugin_path
 258 endforeach
 259
 260 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 261 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 262 all_plugins_paths = pathsep.join(all_plugins_paths)
 263
 264 devenv = environment()
 265 if not building_full
 266   devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 267 else
 268   # Make sure the current build directory is first in PATH so we prefer tools
 269   # built here that links on gst-full instead instead of those built in
 270   # subprojects.
 271   devenv.prepend('PATH', meson.current_build_dir())
 272 endif
 273 devenv.set('CURRENT_GST', meson.current_source_dir())
 274 devenv.set('GST_VERSION', meson.project_version())
 275 devenv.set('GST_ENV', 'gst-' + meson.project_version())
 276 devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
 277 devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
 278 meson.add_devenv(devenv)
 279
 280 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 281 configure_file(
 282   output : 'GstPluginsPath.json',
 283   command : [generate_plugins_paths,
 284              '@OUTPUT@',
 285              all_plugins_paths]
 286 )
 287
 288 if building_full
 289   cdata = configuration_data()
 290   cdata.set_quoted('GST_API_VERSION', apiversion)
 291   cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
 292   cdata.set_quoted('PACKAGE_VERSION', gst_version)
 293   cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 294   configure_file(output : 'config.h', configuration : cdata)
 295   configinc = include_directories('.')
 296   gst_c_args = ['-DHAVE_CONFIG_H']
 297
 298   # Generate a .c file which declare and register all built plugins
 299   all_plugin_names = ';'.join(plugins_names)
 300
 301   static_plugins = get_option('gst-full-plugins')
 302   if static_plugins == '*'
 303     static_plugins = all_plugin_names
 304   endif
 305   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 306   init_static_plugins_c = configure_file(
 307     output: 'gstinitstaticplugins.c',
 308     command : [generate_init_static_plugins,
 309                '-o ' + '@OUTPUT@',
 310                '-p ' + static_plugins,
 311                '-e ' + get_option('gst-full-elements'),
 312                '-t ' + get_option('gst-full-typefind-functions'),
 313                '-d ' + get_option('gst-full-device-providers'),
 314                '-T ' + get_option('gst-full-dynamic-types'),
 315                '--giomodules', ';'.join(giomodules),
 316                ]
 317   )
 318
 319   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 320
 321   # Get a list of libraries that needs to be exposed in the ABI.
 322   exposed_libs = []
 323   exposed_deps = []
 324   exposed_girs = []
 325   incdir_deps = []
 326   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 327   all_libs = '*' in wanted_libs
 328
 329   foreach pkgname_library : all_libraries
 330     pkg_name = pkgname_library[0]
 331     lib_def = pkgname_library[1]
 332
 333     if pkg_name in wanted_libs or all_libs
 334       if lib_def.has_key('lib')
 335         exposed_deps += dependency(pkg_name)
 336         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 337         exposed_libs += [lib_def['lib']]
 338       endif
 339
 340       if lib_def.has_key('gir')
 341         exposed_girs += lib_def['gir']
 342       endif
 343     endif
 344   endforeach
 345
 346   # glib and gobject are part of our public API. If we are using glib from the
 347   # system then our pkg-config file must require it. If we built it as
 348   # subproject then we need to link_whole it.
 349   glib_deps = []
 350   glib_dep = dependency('glib-2.0')
 351   gobject_dep = dependency('gobject-2.0')
 352   if gobject_dep.type_name() == 'internal'
 353     glib_subproject = subproject('glib')
 354     exposed_libs += glib_subproject.get_variable('libglib')
 355     exposed_libs += glib_subproject.get_variable('libgobject')
 356     incdir_deps += [
 357       glib_dep.partial_dependency(includes: true),
 358       gobject_dep.partial_dependency(includes: true),
 359     ]
 360   else
 361     glib_deps = [glib_dep, gobject_dep]
 362   endif
 363
 364   link_deps = []
 365   if get_option('gst-full-version-script') != ''
 366     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 367     link_arg = '-Wl,--version-script=' + symbol_map
 368     if cc.has_link_argument(link_arg)
 369       gstfull_link_args += link_arg
 370       link_deps += symbol_map
 371     elif cc.get_id() == 'msvc'
 372       warning('FIXME: Provide a def file to publish the public symbols')
 373     else
 374       warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
 375     endif
 376   endif
 377
 378   giomodules_deps = []
 379   foreach module : giomodules
 380     giomodules_deps += dependency(module)
 381   endforeach
 382
 383   # Build both shared and static library
 384   gstfull = both_libraries('gstreamer-full-1.0',
 385     init_static_plugins_c,
 386     link_args: gstfull_link_args,
 387     link_whole : exposed_libs,
 388     dependencies : [incdir_deps, glib_deps, all_plugins, giomodules_deps],
 389     link_depends : link_deps,
 390     install : true,
 391   )
 392
 393   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 394     dependencies : incdir_deps + glib_deps,
 395     include_directories: include_directories('.')
 396   )
 397
 398   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 399   if gst_full_libs_private == []
 400     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 401   endif
 402
 403   if not get_option('introspection').disabled()
 404     built_girs = {}
 405     foreach gir: exposed_girs
 406       includes = []
 407       foreach include: gir.get('includes', [])
 408         includes += [built_girs.get(include, include)]
 409       endforeach
 410
 411       gir += {
 412         'includes': includes,
 413         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 414         'install': true,
 415       }
 416       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 417     endforeach
 418   endif
 419
 420   pkgconfig.generate(gstfull,
 421     requires: glib_deps,
 422     libraries_private: gst_full_libs_private,
 423     subdirs : 'gstreamer-1.0')
 424   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 425
 426   if not get_option('tools').disabled()
 427     foreach tool, data: all_tools
 428       exe_name = '@0@-@1@'.format(tool, apiversion)
 429       extra_args = data.get('extra_c_args', [])
 430       sources = data.get('files')
 431       install_tag = data.get('install_tag', 'bin')
 432       deps = []
 433       foreach d : data.get('deps', [])
 434         if d not in exposed_deps
 435           deps += d
 436         endif
 437       endforeach
 438
 439       executable(exe_name,
 440         sources,
 441         install: true,
 442         install_tag: install_tag,
 443         include_directories : [configinc],
 444         dependencies : [gst_full_dep] + deps,
 445         c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
 446       )
 447
 448       if data.has_key('man_page')
 449         install_man(data.get('man_page'))
 450       endif
 451
 452     endforeach
 453   endif
 454 endif
 455
 456 message('Building subprojects: ' + ', '.join(subprojects_names))
 457
 458 setenv = find_program('gst-env.py')
 459
 460 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
 461               '--srcdir=@0@'.format(meson.global_source_root())]
 462
 463 subdir('tests')
 464 subdir('ci/fuzzing')
 465
 466 if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 467   # FIXME: Ideally we could get the wrapper directly from meson
 468   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 469   sysroot = meson.get_cross_property('sys_root')
 470   if sysroot != ''
 471     # Logic from meson
 472     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 473   endif
 474 endif
 475
 476 run_target('devenv', command : devenv_cmd)
 477
 478 if orc_subproject.found() and orc_update_targets.length() > 0
 479   alias_target('update-orc-dist', orc_update_targets)
 480 endif
 481
 482 dotnet_format = find_program('dotnet-format', required: false)
 483 if dotnet_format.found()
 484     run_target('csharp_format_check',
 485         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 486             '--check'
 487         ],
 488     )
 489     run_target('csharp_format_apply',
 490         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 491         ],
 492     )
 493 endif
 494
 495 summary({
 496   'gstreamer-full library': building_full,
 497 }, section: 'Build options', bool_yn: true, list_sep: '  ')
 498
 499 gst_tools = []
 500 foreach tool, data: all_tools
 501   gst_tools += tool
 502 endforeach
 503
 504 summary({
 505     'Tools': gst_tools,
 506 }, section: 'Build options', list_sep: ', ')