meson.build

   1 project('gst-rtsp-server', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.33.0',
   4   default_options : ['warning_level=1', 'buildtype=debugoptimized'])
   5
   6 gst_version = meson.project_version()
   7 version_arr = gst_version.split('.')
   8 gst_version_major = version_arr[0]
   9 gst_version_minor = version_arr[1]
  10 gst_version_micro = version_arr[2]
  11 if version_arr.length() == 4
  12   gst_version_nano = version_arr[3]
  13 else
  14   gst_version_nano = 0
  15 endif
  16
  17 glib_req = '>= 2.40.0'
  18 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  19
  20 api_version = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  27
  28 cdata = configuration_data()
  29 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-rtsp-server-1.0')
  30 cdata.set_quoted('PACKAGE', 'gst-rtsp-server')
  31 cdata.set_quoted('VERSION', gst_version)
  32 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  33 cdata.set_quoted('GST_API_VERSION', api_version)
  34 cdata.set_quoted('GST_LICENSE', 'LGPL')
  35
  36 # FIXME: ENABLE_NLS (currently also missing from autotools build)
  37 # cdata.set('ENABLE_NLS', true)
  38 # cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
  39
  40 # GStreamer package name and origin url
  41 gst_package_name = get_option('with-package-name')
  42 if gst_package_name == ''
  43   if gst_version_nano == 0
  44     gst_package_name = 'GStreamer RTSP Server Library source release'
  45   elif gst_version_nano == 1
  46     gst_package_name = 'GStreamer RTSP Server Library git'
  47   else
  48     gst_package_name = 'GStreamer RTSP Server Library prerelease'
  49   endif
  50 endif
  51 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  52 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  53
  54 configure_file(output : 'config.h', configuration : cdata)
  55
  56 rtspserver_args = ['-DHAVE_CONFIG_H']
  57
  58 rtspserver_incs = include_directories('gst/rtsp-server', '.')
  59
  60 glib_dep = dependency('glib-2.0', version : glib_req)
  61 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  62   fallback : ['gstreamer', 'gst_dep'])
  63 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
  64   fallback : ['gst-plugins-base', 'rtsp_dep'])
  65 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
  66   fallback : ['gst-plugins-base', 'rtp_dep'])
  67 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
  68   fallback : ['gst-plugins-base', 'sdp_dep'])
  69 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
  70   fallback : ['gst-plugins-base', 'app_dep'])
  71 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
  72   fallback : ['gstreamer', 'gst_net_dep'])
  73
  74 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
  75
  76 gir = find_program('g-ir-scanner', required : false)
  77 gnome = import('gnome')
  78 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
  79 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
  80     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
  81     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
  82     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
  83     'gst_init(NULL,NULL);' ]
  84
  85 subdir('gst')
  86 subdir('tests')
  87 subdir('examples')
  88 subdir('pkgconfig')