meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.19.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', native: false, required: false)
  20
  21 glib_req = '>= 2.44.0'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25
  26 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  27 plugins = []
  28
  29 cc = meson.get_compiler('c')
  30 if have_cxx
  31   cxx = meson.get_compiler('cpp')
  32 endif
  33
  34 if cc.get_id() == 'msvc'
  35   msvc_args = [
  36       # Ignore several spurious warnings for things gstreamer does very commonly
  37       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39       # NOTE: Only add warnings here if you are sure they're spurious
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  45
  46       # Enable some warnings on MSVC to match GCC/Clang behaviour
  47       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  48       '/w14101', # 'identifier' : unreferenced local variable
  49       '/w14189', # 'identifier' : local variable is initialized but not referenced
  50   ]
  51   if have_cxx
  52     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  53   else
  54     add_project_arguments(msvc_args, language: 'c')
  55   endif
  56   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  57   # are built with MinGW
  58   noseh_link_args = ['/SAFESEH:NO']
  59 else
  60   noseh_link_args = []
  61 endif
  62
  63 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  64   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  65 endif
  66 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  67   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  68 endif
  69
  70 cdata = configuration_data()
  71 check_headers = [
  72   ['HAVE_DLFCN_H', 'dlfcn.h'],
  73   ['HAVE_INTTYPES_H', 'inttypes.h'],
  74   ['HAVE_MALLOC_H', 'malloc.h'],
  75   ['HAVE_MEMORY_H', 'memory.h'],
  76   ['HAVE_STDINT_H', 'stdint.h'],
  77   ['HAVE_STDLIB_H', 'stdlib.h'],
  78   ['HAVE_STRINGS_H', 'strings.h'],
  79   ['HAVE_STRING_H', 'string.h'],
  80   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  81   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  82   ['HAVE_UNISTD_H', 'unistd.h'],
  83   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  84 ]
  85
  86 foreach h : check_headers
  87   if cc.has_header(h.get(1))
  88     cdata.set(h.get(0), 1)
  89   endif
  90 endforeach
  91
  92 check_functions = [
  93   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
  94 ]
  95
  96 foreach f : check_functions
  97   if cc.has_function(f.get(1))
  98     cdata.set(f.get(0), 1)
  99   endif
 100 endforeach
 101
 102 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 103 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 104 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 105 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 106 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 107
 108 cdata.set_quoted('VERSION', gst_version)
 109 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 110 cdata.set_quoted('GST_LICENSE', 'LGPL')
 111 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 112 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 113
 114 # GStreamer package name and origin url
 115 gst_package_name = get_option('package-name')
 116 if gst_package_name == ''
 117   if gst_version_nano == 0
 118     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 119   elif gst_version_nano == 1
 120     gst_package_name = 'GStreamer Ugly Plug-ins git'
 121   else
 122     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 123   endif
 124 endif
 125 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 126 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 127
 128 # Mandatory GST deps
 129 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 130     fallback : ['gstreamer', 'gst_dep'])
 131 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 132     fallback : ['gst-plugins-base', 'app_dep'])
 133 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 134     fallback : ['gst-plugins-base', 'video_dep'])
 135 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 136     fallback : ['gst-plugins-base', 'pbutils_dep'])
 137 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 138     fallback : ['gst-plugins-base', 'tag_dep'])
 139 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 140     fallback : ['gst-plugins-base', 'fft_dep'])
 141 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 142     fallback : ['gst-plugins-base', 'audio_dep'])
 143 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 144   fallback : ['gstreamer', 'gst_base_dep'])
 145 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 146     fallback : ['gst-plugins-base', 'riff_dep'])
 147 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 148     fallback : ['gst-plugins-base', 'rtp_dep'])
 149 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 150   fallback : ['gstreamer', 'gst_net_dep'])
 151 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 152     fallback : ['gst-plugins-base', 'sdp_dep'])
 153 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 154     fallback : ['gst-plugins-base', 'rtsp_dep'])
 155 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 156     required : get_option('tests'),
 157     fallback : ['gstreamer', 'gst_check_dep'])
 158 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 159   fallback : ['gstreamer', 'gst_controller_dep'])
 160
 161 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 162     fallback : ['orc', 'orc_dep'])
 163 if orc_dep.found()
 164   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 165 else
 166   cdata.set('DISABLE_ORC', 1)
 167 endif
 168
 169 gmodule_dep = dependency('gmodule-2.0', fallback : ['glib', 'libgmodule_dep'])
 170
 171 ugly_args = ['-DHAVE_CONFIG_H']
 172 configinc = include_directories('.')
 173 libsinc = include_directories('gst-libs')
 174
 175 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 176 if gst_dep.type_name() == 'internal'
 177   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 178 else
 179   # We can't check that in the case of subprojects as we won't
 180   # be able to build against an internal dependency (which is not built yet)
 181   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 182 endif
 183
 184 if gst_debug_disabled
 185   message('GStreamer debug system is disabled')
 186   if cc.has_argument('-Wno-unused')
 187     add_project_arguments('-Wno-unused', language: 'c')
 188   endif
 189   if have_cxx and cxx.has_argument ('-Wno-unused')
 190     add_project_arguments('-Wno-unused', language: 'cpp')
 191   endif
 192 else
 193   message('GStreamer debug system is enabled')
 194 endif
 195
 196 warning_flags = [
 197   '-Wmissing-declarations',
 198   '-Wredundant-decls',
 199   '-Wwrite-strings',
 200   '-Wformat',
 201   '-Wformat-nonliteral',
 202   '-Wformat-security',
 203   '-Winit-self',
 204   '-Wmissing-include-dirs',
 205   '-Waddress',
 206   '-Wno-multichar',
 207   '-Wvla',
 208   '-Wpointer-arith',
 209   '-Waggregate-return',
 210   '-fno-strict-aliasing',
 211   # Symbol visibility
 212   '-fvisibility=hidden',
 213 ]
 214
 215 warning_c_flags = [
 216   '-Wmissing-prototypes',
 217   '-Wold-style-definition',
 218   '-Wdeclaration-after-statement',
 219   '-Wnested-externs'
 220 ]
 221
 222 foreach extra_arg : warning_flags
 223   if cc.has_argument (extra_arg)
 224     add_project_arguments([extra_arg], language: 'c')
 225   endif
 226   if have_cxx and cxx.has_argument (extra_arg)
 227     add_project_arguments([extra_arg], language: 'cpp')
 228   endif
 229 endforeach
 230
 231 foreach extra_arg : warning_c_flags
 232   if cc.has_argument (extra_arg)
 233     add_project_arguments([extra_arg], language: 'c')
 234   endif
 235 endforeach
 236
 237 # Define G_DISABLE_DEPRECATED for development versions
 238 if gst_version_is_dev
 239   message('Disabling deprecated GLib API')
 240   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 241 endif
 242
 243 cast_checks = get_option('gobject-cast-checks')
 244 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 245   message('Disabling GLib cast checks')
 246   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 247 endif
 248
 249 glib_asserts = get_option('glib-asserts')
 250 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 251   message('Disabling GLib asserts')
 252   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 253 endif
 254
 255 glib_checks = get_option('glib-checks')
 256 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 257   message('Disabling GLib checks')
 258   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 259 endif
 260
 261 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 262
 263 pkgconfig = import('pkgconfig')
 264 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 265 if get_option('default_library') == 'shared'
 266   # If we don't build static plugins there is no need to generate pc files
 267   plugins_pkgconfig_install_dir = disabler()
 268 endif
 269
 270 python3 = import('python').find_installation()
 271 subdir('gst')
 272 subdir('ext')
 273 subdir('tests')
 274
 275 # xgettext is optional (on Windows for instance)
 276 if find_program('xgettext', required : get_option('nls')).found()
 277   cdata.set('ENABLE_NLS', 1)
 278   subdir('po')
 279 endif
 280 subdir('docs')
 281 subdir('scripts')
 282
 283 # Set release date
 284 if gst_version_nano == 0
 285   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 286   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'))
 287   if run_result.returncode() == 0
 288     release_date = run_result.stdout().strip()
 289     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 290     message('Package release date: ' + release_date)
 291   else
 292     # Error out if our release can't be found in the .doap file
 293     error(run_result.stderr())
 294   endif
 295 endif
 296
 297 configure_file(output : 'config.h', configuration : cdata)
 298
 299 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 300
 301 if meson.version().version_compare('>= 0.54')
 302   plugin_names = []
 303   foreach plugin: plugins
 304     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 305     split = plugin.name().split('gst')
 306     if split.length() == 2
 307       plugin_names += [split[1]]
 308     else
 309       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 310       plugin_names += [plugin.name()]
 311     endif
 312   endforeach
 313   summary({'Plugins':plugin_names}, list_sep: ', ')
 314 endif