meson.build

   1 project('gstreamer', 'c',
   2   version : '1.19.0.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 datadir = join_paths(prefix, get_option('datadir'))
  32 libexecdir = get_option('libexecdir')
  33 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  34
  35 cc = meson.get_compiler('c')
  36
  37 cdata = configuration_data()
  38
  39 if cc.get_id() == 'msvc'
  40   msvc_args = [
  41       # Ignore several spurious warnings for things gstreamer does very commonly
  42       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44       # NOTE: Only add warnings here if you are sure they're spurious
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50
  51       # Enable some warnings on MSVC to match GCC/Clang behaviour
  52       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  53       '/w14101', # 'identifier' : unreferenced local variable
  54       '/w14189', # 'identifier' : local variable is initialized but not referenced
  55   ]
  56   add_project_arguments(msvc_args, language: 'c')
  57 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  58   # FIXME: Add an option for this if people ask for it
  59   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  60 endif
  61
  62 # Symbol visibility
  63 have_visibility_hidden = false
  64 if cc.get_id() == 'msvc'
  65   export_define = '__declspec(dllexport) extern'
  66 elif cc.has_argument('-fvisibility=hidden')
  67   add_project_arguments('-fvisibility=hidden', language: 'c')
  68   export_define = 'extern __attribute__ ((visibility ("default")))'
  69   have_visibility_hidden = true
  70 else
  71   export_define = 'extern'
  72 endif
  73
  74 # Passing this through the command line would be too messy
  75 cdata.set('GST_API_EXPORT', export_define)
  76
  77 # Disable strict aliasing
  78 if cc.has_argument('-fno-strict-aliasing')
  79   add_project_arguments('-fno-strict-aliasing', language: 'c')
  80 endif
  81
  82 # Define G_DISABLE_DEPRECATED for development versions
  83 if gst_version_is_dev
  84   message('Disabling deprecated GLib API')
  85   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  86 endif
  87
  88 cast_checks = get_option('gobject-cast-checks')
  89 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  90   message('Disabling GLib cast checks')
  91   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  92 endif
  93
  94 glib_asserts = get_option('glib-asserts')
  95 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  96   message('Disabling GLib asserts')
  97   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  98 endif
  99
 100 glib_checks = get_option('glib-checks')
 101 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 102   message('Disabling GLib checks')
 103   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 104 endif
 105
 106 cdata.set_quoted('GST_API_VERSION', apiversion)
 107 cdata.set_quoted('GST_DATADIR', datadir)
 108 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 109 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 110 cdata.set_quoted('GST_API_VERSION', '1.0')
 111 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 112 cdata.set_quoted('GST_LICENSE', 'LGPL')
 113 cdata.set_quoted('PACKAGE', 'gstreamer')
 114 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 115 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 116 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 117 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 118 cdata.set_quoted('PACKAGE_URL', '')
 119 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 120 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 121 cdata.set_quoted('VERSION', gst_version)
 122 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 123 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 124 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 125   description: 'plugin directory path component, used to find plugins on relocatable builds on windows')
 126 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 127   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 128 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 129
 130 mem_align_opt = get_option('memory-alignment')
 131 if mem_align_opt == 'malloc'
 132   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 133 elif mem_align_opt == 'pagesize'
 134   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 135 else
 136   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 137 endif
 138
 139 if ['darwin', 'ios'].contains(host_system)
 140   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 141 endif
 142
 143 if gst_version_nano > 0
 144     # Have GST_ERROR message printed when running from git
 145     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 146 else
 147     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 148 endif
 149
 150 # GStreamer package name and origin url
 151 gst_package_name = get_option('package-name')
 152 if gst_package_name == ''
 153   if gst_version_nano == 0
 154     gst_package_name = 'GStreamer source release'
 155   elif gst_version_nano == 1
 156     gst_package_name = 'GStreamer git'
 157   else
 158     gst_package_name = 'GStreamer prerelease'
 159   endif
 160 endif
 161 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 162 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 163
 164 # These are only needed/used by the ABI tests
 165 host_defines = [
 166   [ 'x86', 'HAVE_CPU_I386' ],
 167   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 168   [ 'arm', 'HAVE_CPU_ARM' ],
 169   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 170   [ 'mips', 'HAVE_CPU_MIPS' ],
 171   [ 'powerpc', 'HAVE_CPU_PPC' ],
 172   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 173   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 174   [ 'sparc', 'HAVE_CPU_SPARC' ],
 175   [ 'ia64', 'HAVE_CPU_IA64' ],
 176   [ 'hppa', 'HAVE_CPU_HPPA' ],
 177   [ 'm68k', 'HAVE_CPU_M68K' ],
 178   [ 's390', 'HAVE_CPU_S390' ],
 179 ]
 180 foreach h : host_defines
 181   if h.get(0) == host_machine.cpu_family()
 182     cdata.set(h.get(1), 1)
 183   endif
 184 endforeach
 185 # FIXME: should really be called HOST_CPU or such
 186 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 187
 188 check_headers = [
 189   'dlfcn.h',
 190   'inttypes.h',
 191   'memory.h',
 192   'poll.h',
 193   'stdint.h',
 194   'stdio_ext.h',
 195   'strings.h',
 196   'string.h',
 197   'sys/param.h',
 198   'sys/poll.h',
 199   'sys/prctl.h',
 200   'sys/socket.h',
 201   'sys/stat.h',
 202   'sys/times.h',
 203   'sys/time.h',
 204   'sys/types.h',
 205   'sys/utsname.h',
 206   'sys/wait.h',
 207   'ucontext.h',
 208   'unistd.h',
 209   'sys/resource.h',
 210   'sys/uio.h',
 211 ]
 212
 213 if host_system == 'windows'
 214   check_headers += ['winsock2.h']
 215 endif
 216
 217 foreach h : check_headers
 218   if cc.has_header(h)
 219     define = 'HAVE_' + h.underscorify().to_upper()
 220     cdata.set(define, 1)
 221   endif
 222 endforeach
 223
 224 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 225   cdata.set('HAVE_TM_GMTOFF', 1)
 226 endif
 227
 228 check_functions = [
 229   'gmtime_r',
 230   'sigaction',
 231   'getrusage',
 232   'fseeko',
 233   'ftello',
 234   'poll',
 235   'ppoll',
 236   'pselect',
 237   'getpagesize',
 238   'clock_gettime',
 239   'strnlen',
 240   # These are needed by libcheck
 241   'getline',
 242   'mkstemp',
 243   'alarm',
 244   'gettimeofday',
 245 ]
 246
 247 foreach f : check_functions
 248   if cc.has_function(f)
 249     define = 'HAVE_' + f.underscorify().to_upper()
 250     cdata.set(define, 1)
 251   endif
 252 endforeach
 253
 254 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 255   cdata.set('HAVE_LOCALTIME_R', 1)
 256   # Needed by libcheck
 257   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 258 endif
 259
 260 if cc.links('''#include <pthread.h>
 261                int main() {
 262                  pthread_setname_np("example"); return 0;
 263                }''', name : 'pthread_setname_np(const char*)')
 264   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 265 endif
 266 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 267   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 268 endif
 269 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 270   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 271 endif
 272
 273 # Check for futex(2)
 274 if cc.links('''#include <linux/futex.h>
 275                #include <sys/syscall.h>
 276                #include <unistd.h>
 277                int main (int argc, char ** argv) {
 278                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 279                  return 0;
 280                }''', name : 'futex(2) system call')
 281   cdata.set('HAVE_FUTEX', 1)
 282 endif
 283
 284 # Check for posix timers and monotonic clock
 285 time_prefix = '#include <time.h>\n'
 286 if cdata.has('HAVE_UNISTD_H')
 287   time_prefix += '#include <unistd.h>'
 288 endif
 289
 290 posix_timers_src = time_prefix + '''
 291 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 292 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 293 #endif
 294 '''
 295 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 296   cdata.set('HAVE_POSIX_TIMERS', 1)
 297 endif
 298
 299 monotonic_clock_src = time_prefix + '''
 300 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 301 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 302 #endif
 303 '''
 304 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 305   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 306 endif
 307
 308 # Check for __uint128_t (gcc) by checking for 128-bit division
 309 uint128_t_src = '''int main() {
 310 static __uint128_t v1 = 100;
 311 static __uint128_t v2 = 10;
 312 static __uint128_t u;
 313 u = v1 / v2;
 314 }'''
 315 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 316   cdata.set('HAVE_UINT128_T', 1)
 317 endif
 318
 319 # All supported platforms have long long now
 320 cdata.set('HAVE_LONG_LONG', 1)
 321
 322 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 323 # building with MSVC
 324 if cc.get_id() == 'msvc'
 325   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 326 else
 327   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 328 endif
 329
 330 # -------------------------------------------------------------------------------------
 331 # config.h things needed by libcheck
 332 # -------------------------------------------------------------------------------------
 333 if cc.has_function('getpid')
 334   cdata.set('HAVE_GETPID', 1)
 335 elif host_system == 'windows' and cc.has_function('_getpid')
 336   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 337   cdata.set('HAVE__GETPID', 1)
 338 endif
 339 if cc.has_function('strdup')
 340   cdata.set('HAVE_DECL_STRDUP', 1)
 341 elif host_system == 'windows' and cc.has_function('_strdup')
 342   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 343 endif
 344 if host_system != 'windows'
 345   cdata.set('HAVE_FORK', 1)
 346 else
 347   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 348   cdata.set('HAVE_FORK', 0)
 349 endif
 350 if cc.has_function('strsignal')
 351   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 352 endif
 353 # Check for availability of types
 354 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 355   cdata.set('clockid_t', 'int')
 356 endif
 357 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 358   cdata.set('timer_t', 'int')
 359 endif
 360 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 361                       prefix : '#include <time.h>')
 362   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 363 endif
 364 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 365                       prefix : '#include <time.h>')
 366   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 367 endif
 368
 369 # Platform deps; only ws2_32 and execinfo for now
 370 platform_deps = []
 371 if host_system == 'windows'
 372   platform_deps = [cc.find_library('ws2_32')]
 373 endif
 374
 375 building_for_uwp = false
 376 if host_system == 'windows'
 377   # Check whether we're building for UWP apps
 378   code = '''
 379   #include <windows.h>
 380   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 381   #error "Not building for UWP"
 382   #endif'''
 383   if cc.compiles(code, name : 'building for UWP')
 384     building_for_uwp = true
 385   endif
 386 endif
 387
 388 backtrace_deps = []
 389 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 390 dw_dep = dependency('libdw', required: get_option('libdw'))
 391 dbghelp_option = get_option('dbghelp')
 392 if dbghelp_option.enabled() and building_for_uwp
 393   error('DbgHelp is not supported for UWP')
 394 endif
 395 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 396 backtrace_deps = [unwind_dep, dw_dep]
 397 backtrace_source_info = false
 398 backtrace_minimal = false
 399 # MSVC debug stack trace support
 400 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 401   cdata.set('HAVE_DBGHELP', 1)
 402   backtrace_source_info = true
 403 # DWARF stack trace support with libunwind and elf-utils
 404 elif unwind_dep.found()
 405   cdata.set('HAVE_UNWIND', 1)
 406   if dw_dep.found()
 407     cdata.set('HAVE_DW', 1)
 408     backtrace_source_info = true
 409   endif
 410   backtrace_minimal = true
 411 # Basic backtrace() stack trace support
 412 elif cc.has_function('backtrace')
 413   cdata.set('HAVE_BACKTRACE', 1)
 414   backtrace_minimal = true
 415 endif
 416 # Print messages about what was enabled
 417 if not backtrace_source_info
 418   if not backtrace_minimal
 419     message('NO support for stack traces.')
 420   else
 421     message('Minimal support for stack traces, no source info.')
 422   endif
 423 endif
 424
 425 if cc.has_header('execinfo.h')
 426   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 427     cdata.set('HAVE_BACKTRACE', 1)
 428   else
 429     execinfo_dep = cc.find_library('execinfo', required : false)
 430     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 431       cdata.set('HAVE_BACKTRACE', 1)
 432       platform_deps += execinfo_dep
 433     endif
 434   endif
 435 endif
 436
 437 gst_debug = get_option('gst_debug')
 438 if not gst_debug
 439   add_project_arguments(['-Wno-unused'], language: 'c')
 440 endif
 441
 442 warning_flags = [
 443   '-Wmissing-declarations',
 444   '-Wmissing-prototypes',
 445   '-Wredundant-decls',
 446   '-Wundef',
 447   '-Wwrite-strings',
 448   '-Wformat',
 449   '-Wformat-nonliteral',
 450   '-Wformat-security',
 451   '-Wold-style-definition',
 452   '-Winit-self',
 453   '-Wmissing-include-dirs',
 454   '-Waddress',
 455   '-Waggregate-return',
 456   '-Wno-multichar',
 457   '-Wdeclaration-after-statement',
 458   '-Wvla',
 459   '-Wpointer-arith',
 460 ]
 461
 462 foreach extra_arg : warning_flags
 463   if cc.has_argument (extra_arg)
 464     add_project_arguments([extra_arg], language: 'c')
 465   endif
 466 endforeach
 467
 468 # Used by the gstutils test
 469 gmp_dep = cc.find_library('gmp', required : false)
 470 cdata.set('HAVE_GMP', gmp_dep.found())
 471 gsl_dep = cc.find_library('gsl', required : false)
 472 gslcblas_dep = cc.find_library('gslcblas', required : false)
 473 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 474 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 475
 476 # Used by gstinfo.c
 477 dl_dep = cc.find_library('dl', required : false)
 478 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 479 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 480 cdata.set('USE_POISONING', get_option('poisoning'))
 481
 482 configinc = include_directories('.')
 483 libsinc = include_directories('libs')
 484 privinc = include_directories('gst')
 485
 486 # Find dependencies
 487 glib_dep = dependency('glib-2.0', version : '>=2.56.0',
 488   fallback: ['glib', 'libglib_dep'])
 489 gobject_dep = dependency('gobject-2.0',
 490   fallback: ['glib', 'libgobject_dep'])
 491 gmodule_dep = dependency('gmodule-2.0',
 492   fallback: ['glib', 'libgmodule_dep'])
 493 if host_system == 'windows'
 494     gio_dep = dependency('gio-2.0',
 495         fallback: ['glib', 'libgio_dep'])
 496 else
 497     gio_dep = [dependency('gio-2.0',
 498                   fallback: ['glib', 'libgio_dep']),
 499                dependency('gio-unix-2.0',
 500                   fallback: ['glib', 'libgio_dep'])]
 501 endif
 502
 503 mathlib = cc.find_library('m', required : false)
 504 # Needed for timer_create/settime/delete
 505 # Also provides clock_gettime in glibc < 2.17
 506 rt_lib = cc.find_library('rt', required : false)
 507
 508 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 509 gnome = import('gnome')
 510
 511 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 512
 513 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 514     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 515     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 516     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 517     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 518     'gst_init(NULL,NULL);', '--quiet']
 519
 520 gst_c_args = ['-DHAVE_CONFIG_H']
 521
 522 # FIXME: This is only needed on windows and probably breaks when
 523 # default_library = 'both'. We should add this flag to static_c_args instead
 524 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 525 if get_option('default_library') == 'static'
 526   gst_c_args += ['-DGST_STATIC_COMPILATION']
 527 endif
 528
 529 # Used in gst/parse/meson.build and below
 530 python3 = import('python').find_installation()
 531
 532 bashcomp_option = get_option('bash-completion')
 533 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 534 bash_completions_dir = ''
 535 bash_helpers_dir = ''
 536
 537 bashcomp_found = false
 538 if bashcomp_dep.found()
 539   bashcomp_found = true
 540   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 541   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: bashcomp_dir_override)
 542   if bash_completions_dir == ''
 543     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 544     if bashcomp_option.enabled()
 545       error(msg)
 546     else
 547       message(msg)
 548     endif
 549     bashcomp_found = false
 550   endif
 551
 552   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: bashcomp_dir_override)
 553   if bash_helpers_dir == ''
 554     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 555     if bashcomp_option.enabled()
 556       error(msg)
 557     else
 558       message(msg)
 559     endif
 560     bashcomp_found = false
 561   endif
 562 endif
 563
 564 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 565
 566 pkgconfig = import('pkgconfig')
 567 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 568 if get_option('default_library') == 'shared'
 569   # If we don't build static plugins there is no need to generate pc files
 570   plugins_pkgconfig_install_dir = disabler()
 571 endif
 572 pkgconfig_variables = ['exec_prefix=${prefix}',
 573     'toolsdir=${exec_prefix}/bin',
 574     'pluginsdir=${libdir}/gstreamer-1.0',
 575     'datarootdir=${prefix}/share',
 576     'datadir=${datarootdir}',
 577     'girdir=${datadir}/gir-1.0',
 578     'typelibdir=${libdir}/girepository-1.0',
 579     'libexecdir=${prefix}/libexec',
 580     'pluginscannerdir=${libexecdir}/gstreamer-1.0']
 581 pkgconfig_subdirs = ['gstreamer-1.0']
 582
 583 subdir('gst')
 584 subdir('libs')
 585 subdir('plugins')
 586 if not get_option('tools').disabled()
 587   subdir('tools')
 588 endif
 589 subdir('tests')
 590 subdir('data')
 591 subdir('docs')
 592
 593 # xgettext is optional (on Windows for instance)
 594 if find_program('xgettext', required : get_option('nls')).found()
 595   cdata.set('ENABLE_NLS', 1)
 596   subdir('po')
 597 endif
 598
 599 subdir('scripts')
 600
 601 # Set release date
 602 if gst_version_nano == 0
 603   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 604   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'))
 605   if run_result.returncode() == 0
 606     release_date = run_result.stdout().strip()
 607     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 608     message('Package release date: ' + release_date)
 609   else
 610     # Error out if our release can't be found in the .doap file
 611     error(run_result.stderr())
 612   endif
 613 endif
 614
 615 configure_file(output : 'config.h', configuration : cdata)
 616 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 617 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 618
 619 if meson.version().version_compare('>= 0.54')
 620   plugin_names = []
 621   foreach plugin: plugins
 622     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 623     split = plugin.name().split('gst')
 624     if split.length() == 2
 625       plugin_names += [split[1]]
 626     else
 627       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 628       plugin_names += [plugin.name()]
 629     endif
 630   endforeach
 631   summary({'Plugins':plugin_names}, list_sep: ', ')
 632 endif