meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 libva_req = ['>= 0.30.4', '!= 0.99.0']
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 # Mandatory GST deps
  23 cc = meson.get_compiler('c')
  24
  25 libm = cc.find_library('m', required : false)
  26 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  27   fallback : ['gstreamer', 'gst_dep'])
  28 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  29   fallback : ['gstreamer', 'gst_base_dep'])
  30 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  31     fallback : ['gst-plugins-base', 'pbutils_dep'])
  32 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  33     fallback : ['gst-plugins-base', 'allocators_dep'])
  34 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  35     fallback : ['gst-plugins-base', 'video_dep'])
  36 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  37     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  38 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  39     fallback : ['gst-plugins-bad', 'gstgl_dep'], required: false)
  40 gmodule_dep = dependency('gmodule-2.0', required: false)
  41
  42 libva_version = ''
  43 if get_option('with_libva') == 'auto'
  44   libva_dep = dependency('libva-2.0', required : false)
  45   if not libva_dep.found()
  46     libva_dep = dependency('libva', version: libva_req)
  47   else
  48     libva_version = '-2.0'
  49   endif
  50 else
  51   if get_option('with_libva') == '2'
  52     libva_dep = dependency('libva-2.0')
  53     libva_version = '-2.0'
  54   else
  55     libva_dep = dependency('libva', version: libva_req)
  56   endif
  57 endif
  58
  59 libva_drm_dep = dependency('libva-drm' + libva_version, version: '>= 0.33.0',
  60     required: false)
  61 libva_wayland_dep = dependency('libva-wayland' + libva_version,
  62     version: '>= 0.33.0', required: false)
  63 libva_x11_dep = dependency('libva-x11' + libva_version, version: '>= 0.31.0',
  64     required: false)
  65 libdrm_dep = dependency('libdrm', required: false)
  66 libudev_dep = dependency('libudev', required: false)
  67 egl_dep = dependency('egl', required: false)
  68 gl_dep = dependency('gl', required: false)
  69 glesv2_dep = dependency('glesv2', required: false)
  70 glesv3_dep = dependency('glesv3', required: false)
  71 libdl_dep = cc.find_library('dl', rqeuired: false)
  72 wayland_client_dep = dependency('wayland-client', required: false)
  73 x11_dep = dependency('x11', required: false)
  74 xrandr_dep = dependency('xrandr', required: false)
  75 xrender_dep = dependency('xrender', required: false)
  76
  77 GLES_VERSION_MASK = 0
  78 GLES_VERSION_MASK += gl_dep.found() ? 1 : 0
  79 GLES_VERSION_MASK += glesv2_dep.found() ? 4 : 0
  80 GLES_VERSION_MASK += glesv3_dep.found() ? 8 : 0
  81
  82 USE_ENCODERS = libva_dep.version().version_compare('>= 0.34.0') and get_option('with_encoders') != 'no'
  83 USE_H265_DECODER = cc.has_header('va/va_dec_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  84 USE_H265_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  85 USE_JPEG_DECODER = cc.has_header('va/va_dec_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  86 USE_JPEG_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  87 USE_VP8_DECODER = cc.has_header('va/va_dec_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  88 USE_VP8_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  89 USE_VP9_DECODER = cc.has_header('va/va_dec_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  90 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  91
  92 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
  93 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
  94 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
  95 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and get_option('with_wayland') != 'no'
  96 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
  97
  98 cdata = configuration_data()
  99 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
 100 cdata.set('PACKAGE', '"gstreamer-vaapi"')
 101 cdata.set('VERSION', '"@0@"'.format(gst_version))
 102 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 103 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
 104 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
 105 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
 106 cdata.set10('USE_DRM', USE_DRM)
 107 cdata.set10('USE_EGL', USE_EGL)
 108 cdata.set10('USE_ENCODERS', USE_ENCODERS)
 109 cdata.set10('USE_GLX', USE_GLX)
 110 cdata.set10('USE_H265_DECODER', USE_H265_DECODER)
 111 cdata.set10('USE_H265_ENCODER', USE_H265_ENCODER)
 112 cdata.set10('USE_JPEG_DECODER', USE_JPEG_DECODER)
 113 cdata.set10('USE_JPEG_ENCODER', USE_JPEG_ENCODER)
 114 cdata.set10('USE_VP8_DECODER', USE_VP8_DECODER)
 115 cdata.set10('USE_VP8_ENCODER', USE_VP8_ENCODER)
 116 cdata.set10('USE_VP9_DECODER', USE_VP9_DECODER)
 117 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
 118 cdata.set10('USE_WAYLAND', USE_WAYLAND)
 119 cdata.set10('USE_X11', USE_X11)
 120 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 121 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 122 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 123 cdata.set10('USE_VA_VPP', true)
 124 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 125 cdata.set('GLES_VERSION_MASK', GLES_VERSION_MASK)
 126 runcmd = run_command('pkg-config', '--variable=driverdir', 'libva')
 127 if runcmd.returncode() == 0
 128   cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(runcmd.stdout().strip()))
 129 endif
 130
 131 api_version = '1.0'
 132 soversion = 0
 133 # maintaining compatibility with the previous libtool versioning
 134 # current = minor * 100 + micro
 135 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
 136
 137 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 138
 139 configure_file(configuration: cdata, output: 'config.h')
 140 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 141 configinc = include_directories('.')
 142 libsinc = include_directories('gst-libs')
 143
 144 subdir('gst-libs')
 145 subdir('gst')
 146 #subdir('tests')
 147
 148 python3 = import('python3').find_python()
 149 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')