meson.build

   1 project('gst-plugins-bad', 'c', 'cpp',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 api_version = '1.0'
  23 soversion = 0
  24 # maintaining compatibility with the previous libtool versioning
  25 # current = minor * 100 + micro
  26 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  27
  28 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  29
  30 cc = meson.get_compiler('c')
  31 cxx = meson.get_compiler('cpp')
  32
  33 if cc.get_id() == 'msvc'
  34   # Ignore several spurious warnings for things gstreamer does very commonly
  35   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37   # NOTE: Only add warnings here if you are sure they're spurious
  38   msvc_args = [
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43   ]
  44   add_project_arguments(msvc_args, language : 'c')
  45   add_project_arguments(msvc_args, language : 'cpp')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   if cxx.has_argument('-Wno-non-virtual-dtor')
  51     add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  52   endif
  53
  54   noseh_link_args = []
  55 endif
  56
  57 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  58   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  59 endif
  60
  61 # Symbol visibility
  62 if cc.has_argument('-fvisibility=hidden')
  63   add_project_arguments('-fvisibility=hidden', language: 'c')
  64 endif
  65 if cxx.has_argument('-fvisibility=hidden')
  66   add_project_arguments('-fvisibility=hidden', language: 'cpp')
  67 endif
  68
  69 # Disable strict aliasing
  70 if cc.has_argument('-fno-strict-aliasing')
  71   add_project_arguments('-fno-strict-aliasing', language: 'c')
  72 endif
  73 if cxx.has_argument('-fno-strict-aliasing')
  74   add_project_arguments('-fno-strict-aliasing', language: 'cpp')
  75 endif
  76
  77 # Define G_DISABLE_DEPRECATED for development versions
  78 if gst_version_is_dev
  79   message('Disabling deprecated GLib API')
  80   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  81 endif
  82
  83 cast_checks = get_option('gobject-cast-checks')
  84 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  85   message('Disabling GLib cast checks')
  86   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  87 endif
  88
  89 glib_asserts = get_option('glib-asserts')
  90 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  91   message('Disabling GLib asserts')
  92   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  93 endif
  94
  95 cdata = configuration_data()
  96 check_headers = [
  97   ['HAVE_DLFCN_H', 'dlfcn.h'],
  98   ['HAVE_FCNTL_H', 'fcntl.h'],
  99   ['HAVE_INTTYPES_H', 'inttypes.h'],
 100   ['HAVE_MEMORY_H', 'memory.h'],
 101   ['HAVE_MSACM_H', 'msacm.h'],
 102   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 103   ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
 104   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 105   ['HAVE_PTHREAD_H', 'pthread.h'],
 106   ['HAVE_STDINT_H', 'stdint.h'],
 107   ['HAVE_STDLIB_H', 'stdlib.h'],
 108   ['HAVE_STRINGS_H', 'strings.h'],
 109   ['HAVE_STRING_H', 'string.h'],
 110   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 111   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 112   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 113   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 114   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 115   ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
 116   ['HAVE_UNISTD_H', 'unistd.h'],
 117   ['HAVE_WINDOWS_H', 'windows.h'],
 118   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 119   ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
 120 ]
 121
 122 foreach h : check_headers
 123   if cc.has_header(h.get(1))
 124     cdata.set(h.get(0), 1)
 125   endif
 126 endforeach
 127
 128 check_functions = [
 129 # check token HAVE_ACM
 130 # check token HAVE_ANDROID_MEDIA
 131 # check token HAVE_APEXSINK
 132 # check token HAVE_APPLE_MEDIA
 133 # check token HAVE_ASSRENDER
 134 # check token HAVE_AVC
 135 # check token HAVE_BLUEZ
 136 # check token HAVE_BZ2
 137 # check token HAVE_CFLOCALECOPYCURRENT
 138 # check token HAVE_CFPREFERENCESCOPYAPPVALUE
 139 # check token HAVE_CHROMAPRINT
 140 # check token HAVE_CPU_ALPHA
 141 # check token HAVE_CPU_ARM
 142 # check token HAVE_CPU_CRIS
 143 # check token HAVE_CPU_CRISV32
 144 # check token HAVE_CPU_HPPA
 145 # check token HAVE_CPU_I386
 146 # check token HAVE_CPU_IA64
 147 # check token HAVE_CPU_M68K
 148 # check token HAVE_CPU_MIPS
 149 # check token HAVE_CPU_PPC
 150 # check token HAVE_CPU_PPC64
 151 # check token HAVE_CPU_S390
 152 # check token HAVE_CPU_SPARC
 153 # check token HAVE_CPU_X86_64
 154 # check token HAVE_CURL
 155 # check token HAVE_DAALA
 156 # check token HAVE_DASH
 157 # check token HAVE_DC1394
 158   ['HAVE_DCGETTEXT', 'dcgettext'],
 159 # check token HAVE_DECKLINK
 160 # check token HAVE_DIRECT3D
 161 # check token HAVE_DIRECTDRAW
 162 # check token HAVE_DIRECTFB
 163 # check token HAVE_DIRECTSOUND
 164 # check token HAVE_DOWHILE_MACROS
 165 # check token HAVE_DTS
 166 # check token HAVE_DVB
 167 # check token HAVE_EXPERIMENTAL
 168 # check token HAVE_EXTERNAL
 169 # check token HAVE_FAAC
 170 # check token HAVE_FAAD
 171 # check token HAVE_FBDEV
 172 # check token HAVE_FLITE
 173 # check token HAVE_FLUIDSYNTH
 174   ['HAVE_GETPAGESIZE', 'getpagesize'],
 175 # check token HAVE_GETTEXT
 176 # check token HAVE_GL
 177 # check token HAVE_GLCHAR
 178 # check token HAVE_GLEGLIMAGEOES
 179 # check token HAVE_GLINTPTR
 180 # check token HAVE_GLSIZEIPTR
 181 # check token HAVE_GME
 182   ['HAVE_GMTIME_R', 'gmtime_r'],
 183 # check token HAVE_GRAPHENE
 184 # check token HAVE_GSETTINGS
 185 # check token HAVE_GSM
 186 # check token HAVE_GUDEV
 187 # check token HAVE_HLS
 188 # check token HAVE_ICONV
 189 # check token HAVE_JPEG
 190 # check token HAVE_KATE
 191 # check token HAVE_LADSPA
 192 # check token HAVE_LIBGCRYPT
 193 # check token HAVE_LIBGME_ACCURACY
 194 # check token HAVE_LIBMMS
 195 # check token HAVE_LIBNSL
 196 # check token HAVE_LIBSOCKET
 197 # check token HAVE_LIBUSB
 198 # check token HAVE_LIBVISUAL
 199 # check token HAVE_LINSYS
 200 # check token HAVE_LRDF
 201 # check token HAVE_LV2
 202 # check token HAVE_MIMIC
 203   ['HAVE_MMAP', 'mmap'],
 204 # check token HAVE_MODPLUG
 205 # check token HAVE_MPEG2ENC
 206 # check token HAVE_MPG123
 207 # check token HAVE_MPLEX
 208 # check token HAVE_MUSEPACK
 209 # check token HAVE_MYTHTV
 210 # check token HAVE_NAS
 211 # check token HAVE_NEON
 212 # check token HAVE_NETTLE
 213 # check token HAVE_OFA
 214 # check token HAVE_OPENAL
 215 # check token HAVE_OPENCV
 216 # check token HAVE_OPENEXR
 217 # check token HAVE_OPENJPEG
 218 # check token HAVE_OPENJPEG_1
 219 # check token HAVE_OPENNI2
 220 # check token HAVE_OPENSLES
 221 # check token HAVE_OPUS
 222 # check token HAVE_ORC
 223 # check token HAVE_OSX_VIDEO
 224   ['HAVE_PIPE2', 'pipe2'],
 225 # check token HAVE_PNG
 226 # check token HAVE_PVR
 227 # check token HAVE_QUICKTIME
 228 # check token HAVE_RDTSC
 229 # check token HAVE_RESINDVD
 230 # check token HAVE_RSVG
 231 # check token HAVE_RSVG_2_36_2
 232 # check token HAVE_RTMP
 233 # check token HAVE_SBC
 234 # check token HAVE_SDL
 235 # check token HAVE_SHM
 236 # check token HAVE_SMOOTHSTREAMING
 237 # check token HAVE_SNDFILE
 238 # check token HAVE_SNDIO
 239 # check token HAVE_SOUNDTOUCH
 240 # check token HAVE_SOUNDTOUCH_1_4
 241 # check token HAVE_SPANDSP
 242 # check token HAVE_SPC
 243 # check token HAVE_SRTP
 244 # check token HAVE_SSH2
 245 # check token HAVE_TELETEXTDEC
 246 # check token HAVE_TIGER
 247 # check token HAVE_TIMIDITY
 248 # check token HAVE_UVCH264
 249 # check token HAVE_VALGRIND
 250 # check token HAVE_VCD
 251 # check token HAVE_VDPAU
 252 # check token HAVE_VIDEOTOOLBOX
 253 # check token HAVE_VOAACENC
 254 # check token HAVE_VOAMRWBENC
 255 # check token HAVE_WASAPI
 256 # check token HAVE_WAYLAND
 257 # check token HAVE_WEBP
 258 # check token HAVE_WILDMIDI
 259 # check token HAVE_WIN32
 260 # check token HAVE_WININET
 261 # check token HAVE_WINKS
 262 # check token HAVE_WINSCREENCAP
 263 # check token HAVE_XVID
 264 # check token HAVE_ZBAR
 265 ]
 266
 267 foreach f : check_functions
 268   if cc.has_function(f.get(1))
 269     cdata.set(f.get(0), 1)
 270   endif
 271 endforeach
 272
 273 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 274 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 275 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 276 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 277 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 278
 279 cdata.set_quoted('VERSION', gst_version)
 280 cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
 281 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 282 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 283 cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
 284 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
 285 cdata.set_quoted('GST_API_VERSION', api_version)
 286 cdata.set_quoted('GST_LICENSE', 'LGPL')
 287 cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
 288 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 289
 290 warning_flags = [
 291   '-Wmissing-declarations',
 292   '-Wredundant-decls',
 293   '-Wwrite-strings',
 294   '-Wformat',
 295   '-Wformat-security',
 296   '-Winit-self',
 297   '-Wmissing-include-dirs',
 298   '-Waddress',
 299   '-Wno-multichar',
 300   '-Wvla',
 301   '-Wpointer-arith',
 302 ]
 303
 304 warning_c_flags = [
 305   '-Wmissing-prototypes',
 306   '-Wdeclaration-after-statement',
 307   '-Wold-style-definition',
 308   '-Wnested-externs',
 309 ]
 310
 311 warning_cxx_flags = [
 312   '-Wformat-nonliteral',
 313 ]
 314
 315 foreach extra_arg : warning_c_flags
 316   if cc.has_argument (extra_arg)
 317     add_project_arguments([extra_arg], language: 'c')
 318   endif
 319 endforeach
 320
 321 foreach extra_arg : warning_cxx_flags
 322   if cxx.has_argument (extra_arg)
 323     add_project_arguments([extra_arg], language: 'cpp')
 324   endif
 325 endforeach
 326
 327 foreach extra_arg : warning_flags
 328   if cc.has_argument (extra_arg)
 329     add_project_arguments([extra_arg], language: 'c')
 330   endif
 331   if cxx.has_argument (extra_arg)
 332     add_project_arguments([extra_arg], language: 'cpp')
 333   endif
 334 endforeach
 335
 336 # GStreamer package name and origin url
 337 gst_package_name = get_option('package-name')
 338 if gst_package_name == ''
 339   if gst_version_nano == 0
 340     gst_package_name = 'GStreamer Bad Plug-ins source release'
 341   elif gst_version_nano == 1
 342     gst_package_name = 'GStreamer Bad Plug-ins git'
 343   else
 344     gst_package_name = 'GStreamer Bad Plug-ins prerelease'
 345   endif
 346 endif
 347 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 348 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 349
 350 # FIXME: This should be exposed as a configuration option
 351 host_system = host_machine.system()
 352 if host_system == 'linux'
 353   cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
 354 elif ['darwin', 'ios'].contains(host_system)
 355   cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
 356   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 357   # Yes, we set this for iOS too. Same as Autotools.
 358   cdata.set('HAVE_OSX', 1)
 359 else
 360   cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
 361 endif
 362
 363 # Mandatory GST deps
 364 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 365   fallback : ['gstreamer', 'gst_dep'])
 366 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 367   fallback : ['gstreamer', 'gst_base_dep'])
 368 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 369   fallback : ['gstreamer', 'gst_net_dep'])
 370 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 371   fallback : ['gstreamer', 'gst_controller_dep'])
 372
 373 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 374     fallback : ['gst-plugins-base', 'pbutils_dep'])
 375 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 376     fallback : ['gst-plugins-base', 'allocators_dep'])
 377 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 378     fallback : ['gst-plugins-base', 'app_dep'])
 379 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 380     fallback : ['gst-plugins-base', 'audio_dep'])
 381 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 382     fallback : ['gst-plugins-base', 'fft_dep'])
 383 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 384     fallback : ['gst-plugins-base', 'riff_dep'])
 385 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 386     fallback : ['gst-plugins-base', 'rtp_dep'])
 387 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 388     fallback : ['gst-plugins-base', 'rtsp_dep'])
 389 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 390     fallback : ['gst-plugins-base', 'sdp_dep'])
 391 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 392     fallback : ['gst-plugins-base', 'tag_dep'])
 393 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 394     fallback : ['gst-plugins-base', 'video_dep'])
 395 if host_machine.system() != 'windows'
 396   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 397     required : get_option('tests'),
 398     fallback : ['gstreamer', 'gst_check_dep'])
 399 endif
 400
 401 # GStreamer OpenGL
 402 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 403     fallback : ['gst-plugins-base', 'gstgl_dep'], required: get_option('gl'))
 404
 405 if gstgl_dep.found()
 406   if gstgl_dep.type_name() == 'pkgconfig'
 407     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 408     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 409     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 410   else
 411     gstbase = subproject('gst-plugins-base')
 412     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 413     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 414     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 415   endif
 416
 417   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 418   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 419   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 420
 421   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 422     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 423   endforeach
 424
 425   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 426     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 427   endforeach
 428
 429   foreach api : ['opengl', 'gles2']
 430     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 431   endforeach
 432 endif
 433
 434 libm = cc.find_library('m', required : false)
 435 glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
 436 gmodule_dep = dependency('gmodule-2.0', fallback: ['glib', 'libgmodule_dep'])
 437 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 438 # gio-unix-2.0 is used by sys/bluez
 439
 440 # Optional dep of ext/gl and gst/librfb
 441 x11_dep = dependency('x11', required : get_option('x11'))
 442 if x11_dep.found()
 443   cdata.set('HAVE_X11', 1)
 444 endif
 445
 446 if host_machine.system() == 'windows'
 447   winsock2 = [cc.find_library('ws2_32')]
 448 else
 449   winsock2 = []
 450 endif
 451
 452 if ['darwin', 'ios'].contains(host_system)
 453   add_languages('objc')
 454   if host_system == 'ios'
 455     cdata.set('HAVE_IOS', 1)
 456   endif
 457
 458   avfoundation_dep = dependency('AVFoundation', required : false)
 459   if avfoundation_dep.found()
 460       cdata.set('HAVE_AVFOUNDATION', 1)
 461   endif
 462
 463   videotoolbox_dep = dependency('VideoToolbox', required : false)
 464   if videotoolbox_dep.found()
 465       cdata.set('HAVE_VIDEOTOOLBOX', 1)
 466   endif
 467
 468 #  FIXME: framework.version() returns 'unknown'
 469 #  if videotoolbox_dep.version().version_compare('>=10.9.6')
 470 #    cdata.set('HAVE_VIDEOTOOLBOX_10_9_6', 1)
 471 #  endif
 472 endif
 473
 474 have_orcc = false
 475 orcc_args = []
 476 # Used by various libraries/elements that use Orc code
 477 orc_dep = dependency('orc-0.4', required : get_option('orc'))
 478 orcc = find_program('orcc', required : get_option('orc'))
 479 if orc_dep.found() and orcc.found()
 480   have_orcc = true
 481   orcc_args = [orcc, '--include', 'glib.h']
 482   cdata.set('HAVE_ORC', 1)
 483 else
 484   message('Orc Compiler not found or disabled, will use backup C code')
 485   cdata.set('DISABLE_ORC', 1)
 486 endif
 487
 488 if gst_dep.type_name() == 'internal'
 489   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 490 else
 491   # We can't check that in the case of subprojects as we won't
 492   # be able to build against an internal dependency (which is not built yet)
 493   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 494 endif
 495
 496 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 497   add_project_arguments('-Wno-unused', language: 'c')
 498 endif
 499
 500 gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
 501 configinc = include_directories('.')
 502 libsinc = include_directories('gst-libs')
 503
 504 python3 = import('python3').find_python()
 505
 506 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 507 gnome = import('gnome')
 508 build_gir = gir.found() and not meson.is_cross_build()
 509 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 510     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 511     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 512     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 513     'gst_init(NULL,NULL);' ]
 514
 515 pkgconfig = import('pkgconfig')
 516 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 517 if get_option('default_library') == 'shared'
 518   # If we don't build static plugins there is no need to generate pc files
 519   plugins_pkgconfig_install_dir = disabler()
 520 endif
 521
 522 subdir('gst-libs')
 523 subdir('gst')
 524 subdir('sys')
 525 subdir('ext')
 526 subdir('tests')
 527 subdir('pkgconfig')
 528
 529 # xgettext is optional (on Windows for instance)
 530 if find_program('xgettext', required : get_option('nls')).found()
 531   cdata.set('ENABLE_NLS', 1)
 532   subdir('po')
 533 endif
 534
 535 configure_file(output : 'config.h', configuration : cdata)
 536
 537 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')