meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version = meson.project_version()
  10 version_arr = gst_version.split('.')
  11 gst_version_major = version_arr[0].to_int()
  12 gst_version_minor = version_arr[1].to_int()
  13 gst_version_micro = version_arr[2].to_int()
  14  if version_arr.length() == 4
  15   gst_version_nano = version_arr[3].to_int()
  16 else
  17   gst_version_nano = 0
  18 endif
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 curversion = gst_version_minor * 100 + gst_version_micro
  25 libversion = '@0@.@1@.0'.format(soversion, curversion)
  26 osxversion = curversion + 1
  27
  28 glib_req = '>= 2.44.0'
  29 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  30
  31 cc = meson.get_compiler('c')
  32
  33 cdata = configuration_data()
  34
  35 # Ignore several spurious warnings for things gstreamer does very commonly
  36 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  37 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  38 # NOTE: Only add warnings here if you are sure they're spurious
  39 if cc.get_id() == 'msvc'
  40   add_project_arguments(
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45       language : 'c')
  46 endif
  47
  48 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  49   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  50 endif
  51
  52 # Symbol visibility
  53 if cc.get_id() == 'msvc'
  54   export_define = '__declspec(dllexport) extern'
  55 elif cc.has_argument('-fvisibility=hidden')
  56   add_project_arguments('-fvisibility=hidden', language: 'c')
  57   export_define = 'extern __attribute__ ((visibility ("default")))'
  58 else
  59   export_define = 'extern'
  60 endif
  61
  62 # Passing this through the command line would be too messy
  63 cdata.set('GST_API_EXPORT', export_define)
  64
  65 # Disable strict aliasing
  66 if cc.has_argument('-fno-strict-aliasing')
  67   add_project_arguments('-fno-strict-aliasing', language: 'c')
  68 endif
  69
  70 cdata.set('VERSION', '"@0@"'.format(gst_version))
  71 cdata.set('PACKAGE', '"gst-editing-services"')
  72 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  73 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  74 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  75 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  76 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  77 cdata.set('GST_LICENSE', '"LGPL"')
  78
  79 # Mandatory GST deps
  80 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  81     fallback : ['gstreamer', 'gst_dep'])
  82 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  83     fallback : ['gst-plugins-base', 'pbutils_dep'])
  84 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  85     fallback : ['gst-plugins-base', 'video_dep'])
  86 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  87     fallback : ['gstreamer', 'gst_base_dep'])
  88 if host_machine.system() != 'windows'
  89   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  90     required : get_option('tests'),
  91     fallback : ['gstreamer', 'gst_check_dep'])
  92 endif
  93 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  94   fallback : ['gstreamer', 'gst_controller_dep'])
  95 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : get_option('validate'),
  96   fallback : ['gst-devtools', 'validate_dep'])
  97
  98 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
  99 libxml_dep = dependency('libxml-2.0', required: get_option('xptv'))
 100 cdata.set('DISABLE_XPTV', not libxml_dep.found())
 101
 102 # TODO Properly port to Gtk 3
 103 # gtk_dep = dependency('gtk+-3.0', required : false)
 104
 105 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
 106                gstcontroller_dep, gio_dep, libxml_dep]
 107
 108 if gstvalidate_dep.found()
 109     libges_deps = libges_deps + [gstvalidate_dep]
 110     cdata.set('HAVE_GST_VALIDATE', 1)
 111 endif
 112
 113 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 114 gnome = import('gnome')
 115
 116 # Fixme, not very elegant.
 117 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 118 gir_init_section = [ '--add-init-section=' + \
 119     'extern void gst_init(gint*,gchar**);' + \
 120     'extern void ges_init(void);' + \
 121     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 122     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 123     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 124     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 125     'gst_init(NULL,NULL);' + \
 126     'ges_init();', '--quiet']
 127
 128 has_python = false
 129 if build_gir
 130   pymod = import('python')
 131   python = pymod.find_installation(required: get_option('python'))
 132   if python.found()
 133     # Workaround for https://github.com/mesonbuild/meson/issues/5629
 134     pythonver = python.language_version()
 135     python_dep = dependency('python-@0@-embed'.format(pythonver), version: '>=3', required: false)
 136     if not python_dep.found()
 137       python_dep = python.dependency(required : get_option('python'))
 138     endif
 139   else
 140     python_dep = dependency('', required: false)
 141   endif
 142   if python_dep.found()
 143     python_abi_flags = python.get_variable('ABIFLAGS', '')
 144     pylib_loc = get_option('libpython-dir')
 145
 146     error_msg = ''
 147     if not cc.compiles('#include <Python.h>', dependencies: [python_dep])
 148       error_msg = 'Could not compile a simple program against python'
 149     elif pylib_loc == ''
 150       check_path_exists = 'import os, sys; assert(os.path.exists(sys.argv[1]))'
 151       pylib_loc = python.get_variable('LIBPL', '')
 152       if host_machine.system() != 'windows'
 153         pylib_ldlibrary = python.get_variable('LDLIBRARY', '')
 154         if host_machine.system() == 'darwin'
 155           # OSX is a pain. Python as shipped by apple installs libpython in /usr/lib
 156           # so we hardcode that. Other systems can use -Dlibpythondir to
 157           # override this.
 158           pylib_loc = '/usr/lib'
 159         else
 160           if run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary)).returncode() != 0
 161             # Workaround for Fedora
 162             pylib_loc = python.get_variable('LIBDIR', '')
 163             message('pylib_loc = @0@'.format(pylib_loc))
 164           endif
 165         endif
 166
 167         res = run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary))
 168         if res.returncode() != 0
 169           error_msg = '@0@ doesn\' exist, can\'t use python'.format(join_paths(pylib_loc, pylib_ldlibrary))
 170         endif
 171       endif
 172       if error_msg == ''
 173         pylib_suffix = 'so'
 174         if host_machine.system() == 'windows'
 175           pylib_suffix = 'dll'
 176         elif host_machine.system() == 'darwin'
 177           pylib_suffix = 'dylib'
 178         endif
 179
 180         gmodule_dep = dependency('gmodule-2.0')
 181         libges_deps = libges_deps + [python_dep, gmodule_dep]
 182         has_python = true
 183         message('python_abi_flags = @0@'.format(python_abi_flags))
 184         message('pylib_loc = @0@'.format(pylib_loc))
 185         cdata.set('HAS_PYTHON', true)
 186         cdata.set('PY_LIB_LOC', '"@0@"'.format(pylib_loc))
 187         cdata.set('PY_ABI_FLAGS', '"@0@"'.format(python_abi_flags))
 188         cdata.set('PY_LIB_SUFFIX', '"@0@"'.format(pylib_suffix))
 189         cdata.set('PYTHON_VERSION', '"@0@"'.format(python_dep.version()))
 190       else
 191           if get_option('python').enabled()
 192             error(error_msg)
 193           else
 194             message(error_msg)
 195           endif
 196       endif
 197     endif
 198   endif
 199 endif
 200
 201 configure_file(output : 'config.h', configuration : cdata)
 202
 203 ges_c_args = ['-DHAVE_CONFIG_H', '-DG_LOG_DOMAIN="GES"']
 204 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 205
 206 pkgconfig = import('pkgconfig')
 207 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 208 if get_option('default_library') == 'shared'
 209   # If we don't build static plugins there is no need to generate pc files
 210   plugins_pkgconfig_install_dir = disabler()
 211 endif
 212
 213 if gst_dep.type_name() == 'internal'
 214   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 215 else
 216   # We can't check that in the case of subprojects as we won't
 217   # be able to build against an internal dependency (which is not built yet)
 218   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 219 endif
 220
 221 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 222   add_project_arguments('-Wno-unused', language: 'c')
 223 endif
 224
 225 warning_flags = [
 226   '-Wmissing-declarations',
 227   '-Wmissing-prototypes',
 228   '-Wredundant-decls',
 229   '-Wundef',
 230   '-Wwrite-strings',
 231   '-Wformat',
 232   '-Wformat-security',
 233   '-Winit-self',
 234   '-Wmissing-include-dirs',
 235   '-Waddress',
 236   '-Wno-multichar',
 237   '-Wdeclaration-after-statement',
 238   '-Wvla',
 239   '-Wpointer-arith',
 240 ]
 241
 242 foreach extra_arg : warning_flags
 243   if cc.has_argument (extra_arg)
 244     add_project_arguments([extra_arg], language: 'c')
 245   endif
 246 endforeach
 247
 248 python3 = import('python').find_installation()
 249 configinc = include_directories('.')
 250 subdir('ges')
 251 subdir('plugins')
 252 subdir('tools')
 253 subdir('pkgconfig')
 254 subdir('tests')
 255 subdir('examples')
 256 subdir('docs')
 257
 258 override_detector = '''
 259 import sys
 260 import os
 261
 262 prefix = sys.argv[1]
 263 version = sys.version_info
 264
 265 # If we are installing in the same prefix as PyGobject
 266 # make sure to install in the right place.
 267 import gi.overrides
 268
 269 overrides_path = os.path.dirname(gi.overrides.__file__)
 270 if os.path.commonprefix([overrides_path, prefix]) == prefix:
 271     print(overrides_path)
 272     exit(0)
 273
 274 # Otherwise follow python's way of install site packages inside
 275 # the provided prefix
 276 if os.name == 'posix':
 277     print(os.path.join(
 278         prefix, 'lib', 'python%d.%d' % (version.major, version.minor),
 279         'site-packages', 'gi', 'overrides'))
 280 else:
 281     print(os.path.join(
 282         prefix, 'Lib', 'Python%d%d' % (version.major, version.minor),
 283         'site-packages', 'gi', 'overrides'))
 284 '''
 285 pygi_override_dir = get_option('pygi-overrides-dir')
 286 if pygi_override_dir == ''
 287     cres = run_command(python3, '-c', override_detector, get_option('prefix'))
 288     if cres.returncode() == 0
 289       pygi_override_dir = cres.stdout().strip()
 290     endif
 291     if cres.stderr() != ''
 292         message(cres.stderr())
 293     endif
 294 endif
 295
 296 if pygi_override_dir != ''
 297   message('pygobject overrides directory ' + pygi_override_dir)
 298   subdir('bindings/python')
 299 endif
 300
 301 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')