meson.build

   1 project('gstreamer-full', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.62.0',
   4   default_options : ['buildtype=debugoptimized',
   5                      # Needed due to https://github.com/mesonbuild/meson/issues/1889,
   6                      # but this can cause problems in the future. Remove it
   7                      # when it's no longer necessary.
   8                      'cpp_std=c++14'])
   9
  10 apiversion = '1.0'
  11 gst_version = '>= @0@'.format(meson.project_version())
  12
  13 build_system = build_machine.system()
  14 cc = meson.get_compiler('c')
  15
  16 fs = import('fs')
  17 gnome = import('gnome')
  18 pkgconfig = import('pkgconfig')
  19 python3 = import('python').find_installation()
  20 # Ensure that we're not being run from inside the development environment
  21 # because that will confuse meson, and it might find the already-built
  22 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  23 # reconfigure because ninja doesn't care about the env.
  24 ensure_not_devenv = '''
  25 import os
  26 assert('GST_ENV' not in os.environ)
  27 '''
  28 cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
  29 if cmdres.returncode() != 0
  30   error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
  31 endif
  32
  33 # Install gst-indent pre-commit hook
  34 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
  35
  36 # On macOS, you have to run "Install Certificates.command" otherwise Python
  37 # doesn't have access to the latest SSL CA Certificates, and Meson will fail to
  38 # download wrap files from websites that use, for example, Let's Encrypt.
  39 # We already recommend this in the README, but add a warning here as well.
  40 # Can't make this an error because the user might be using XCode's Python
  41 # 3 which doesn't have this script.
  42 if build_system == 'darwin'
  43   python3_cacert_file = python3.get_path('data') / 'etc/openssl/cert.pem'
  44   install_cert_cmd = '/Applications/Python @0@/Install Certificates.command'.format(python3.language_version())
  45   if not fs.is_symlink(python3_cacert_file) and fs.is_file(install_cert_cmd)
  46     warning('Please run "@0@" so that Python has access to the latest SSL certificates. Meson might fail to download some wraps without it.'.format(install_cert_cmd))
  47   endif
  48 endif
  49
  50 documented_projects = ''
  51 # Make it possible to use msys2 built zlib which fails
  52 # when not using the mingw toolchain as it uses unistd.h
  53 if not meson.is_subproject() and cc.get_id() == 'msvc'
  54   uname = find_program('uname', required: false)
  55   if uname.found()
  56     ret = run_command(uname, '-o', check: false)
  57     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  58       ret = run_command(uname, '-r', check: false)
  59       # The kernel version returned by uname is actually the msys version
  60       if ret.returncode() == 0 and ret.stdout().startswith('2')
  61         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  62         if cc.find_library('z').found()
  63           add_global_arguments('-DZ_SOLO', language: 'c')
  64         endif
  65       endif
  66     endif
  67   endif
  68 endif
  69
  70 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  71 # not a subproject, because subprojects are not allowed to call
  72 # add_global_arguments().
  73 if not meson.is_subproject() and cc.get_id() == 'msvc'
  74   add_global_arguments(
  75       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  76       language: ['c', 'cpp'])
  77 endif
  78
  79 building_full = get_option('default_library') == 'static'
  80 tools_option = 'tools=auto'
  81 if building_full and not get_option('tools').disabled()
  82   # Do not build subprojects tools when we build them against gst-full
  83   tools_option = 'tools=disabled'
  84 endif
  85
  86 # Ordered list of subprojects (dict has no ordering guarantees)
  87 subprojects = [
  88   ['gstreamer', {'build-hotdoc': true, 'subproject_options': [tools_option]}],
  89   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
  90   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
  91   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
  92   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
  93   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
  94   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
  95   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
  96   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
  97   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
  98   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
  99   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
 100   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
 101   ['gstreamer-sharp', { 'option': get_option('sharp') }],
 102   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
 103   ['gst-python', { 'option': get_option('python')}],
 104   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
 105   ['gst-plugins-rs', { 'option': get_option('rs'), 'build-hotdoc': true, 'match_gst_version': false}],
 106 ]
 107
 108 symlink = '''
 109 import os
 110
 111 os.symlink(os.path.join('@1@', 'subprojects', '@0@'),
 112   os.path.join('@1@', '@0@'))
 113 '''
 114
 115 if build_system == 'windows'
 116   subproject('win-flex-bison-binaries')
 117   subproject('win-nasm')
 118 elif build_system == 'darwin'
 119   subproject('macos-bison-binary')
 120 endif
 121
 122 orc_option = get_option('orc')
 123 # There is a check below to keep this in sync with subprojects/gst-plugins-base/meson.build
 124 orc_req = '>= 0.4.24'
 125 orc_source_option = get_option('orc-source')
 126 orc_subproject = disabler()
 127 if orc_option.allowed()
 128   if orc_source_option == 'subproject'
 129     orc_subproject = subproject('orc', required: orc_option)
 130   else
 131     dependency('orc-0.4', version: orc_req, required: orc_option,
 132                allow_fallback: orc_source_option == 'auto')
 133   endif
 134 endif
 135
 136 foreach custom_subproj: get_option('custom_subprojects').split(',')
 137     if custom_subproj != ''
 138         message ('Adding custom subproject ' + custom_subproj)
 139         subprojects += [[custom_subproj, {'match_gst_version': false}]]
 140     endif
 141 endforeach
 142
 143
 144 subprojects_names = []
 145 plugins_doc_caches = []
 146 orc_update_targets = []
 147 all_plugins = []
 148 all_tools = {}
 149 # Using a list and not a dict to keep the ordering to build the chain of `gir`
 150 # dependencies
 151 all_libraries = []
 152 foreach sp : subprojects
 153   project_name = sp[0]
 154   build_infos = sp[1]
 155   is_required = build_infos.get('option', true)
 156   sysdep = build_infos.get('sysdep', '')
 157   sysdep_version = build_infos.get('sysdep_version', '')
 158   match_gst_version = build_infos.get('match_gst_version', true)
 159   default_options =  build_infos.get('subproject_options', [])
 160
 161   if match_gst_version
 162     subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
 163   elif sysdep != ''
 164       sysdep_dep = dependency(sysdep, version: sysdep_version, required: false, default_options: default_options)
 165       if not sysdep_dep.found()
 166         subproj = subproject(project_name, required: is_required, default_options: default_options)
 167       endif
 168   else
 169     subproj = subproject(project_name, required: is_required, default_options: default_options)
 170   endif
 171
 172   if project_name == 'gst-plugins-base'
 173     gst_base_orc_req = subproj.get_variable('orc_req', '')
 174     if gst_base_orc_req != orc_req
 175       error('orc_req is "@0@" but it should be "@1@" from subprojects/gst-plugins-base/meson.build'
 176             .format(orc_req, gst_base_orc_req))
 177     endif
 178   endif
 179
 180   if subproj.found()
 181     plugins = subproj.get_variable('gst_plugins', [])
 182     legacy_plugins = subproj.get_variable('plugins', [])
 183     all_plugins += plugins
 184     if plugins.length() == 0 and legacy_plugins.length() > 0
 185       warning(f'DEPRECATED use of the `plugins` variable in @project_name@.')
 186       warning('The variable should now be called `gst_plugins` and use:')
 187       warning('`declare_dependency( link_with: <plugin_target>, variable: {\'full_path\': <plugin_target>.full_path()})` instead')
 188       foreach plugin: legacy_plugins
 189         all_plugins += [declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})]
 190       endforeach
 191     endif
 192
 193     all_libraries += subproj.get_variable('gst_libraries', [])
 194     if not get_option('tools').disabled()
 195       all_tools += subproj.get_variable('gst_tools', {})
 196     endif
 197
 198     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 199
 200     subprojects_names += [project_name]
 201
 202     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 203       plugins_doc_caches += [subproj.get_variable('gst_plugins_doc_dep', [])]
 204       if documented_projects != ''
 205         documented_projects += ','
 206       endif
 207       documented_projects  += project_name
 208     endif
 209   endif
 210 endforeach
 211
 212 # Check if we need to also build glib-networking for TLS modules
 213 giomodules = []
 214 glib_dep = dependency('glib-2.0')
 215 if glib_dep.type_name() == 'internal'
 216   subp = subproject('glib-networking', required : get_option('tls'),
 217              default_options: ['gnutls=auto', 'openssl=auto'])
 218   if subp.found()
 219     giomodules += subp.get_variable('giomodules', [])
 220   endif
 221 endif
 222
 223 gst_plugins_doc_dep = custom_target('plugins-doc-cache',
 224   command: [python3, '-c', 'print("Built all doc caches")'],
 225   input: plugins_doc_caches,
 226   output: 'plugins_doc_caches',
 227   capture: true,
 228 )
 229
 230 if meson.is_cross_build() or build_machine.system() == 'windows'
 231     if get_option('doc').enabled()
 232         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 233     endif
 234
 235     documented_projects = ''
 236     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 237 else
 238   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 239   if not hotdoc_p.found()
 240     documented_projects = ''
 241     message('Not building documentation as hotdoc was not found')
 242   endif
 243 endif
 244
 245 write_file_contents = '''
 246 import os
 247 import sys
 248
 249 assert len(sys.argv) >= 3
 250 fname = sys.argv[1]
 251 contents = sys.argv[2]
 252
 253 with open(fname, 'w') as f:
 254     f.write(contents)
 255 '''
 256
 257 configure_file(
 258   output : 'GstDocumentedSubprojects',
 259   command : [python3,
 260              '-c', write_file_contents,
 261              '@OUTPUT@',
 262              documented_projects]
 263 )
 264
 265 if documented_projects != ''
 266   subproject('gst-docs', required: get_option('doc').enabled())
 267   message('Gst docs subprojects: ' + documented_projects)
 268 endif
 269
 270 all_plugins_paths = []
 271 all_plugins_dirs = []
 272 plugins_names = []
 273 foreach plugin: all_plugins
 274   plugin_path = plugin.get_variable('full_path')
 275   all_plugins_paths += plugin_path
 276   all_plugins_dirs += fs.parent(plugin_path)
 277   plugins_names += plugin_path
 278 endforeach
 279
 280 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 281 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 282 all_plugins_paths = pathsep.join(all_plugins_paths)
 283
 284 devenv = environment()
 285 if not building_full
 286   devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 287 else
 288   # Make sure the current build directory is first in PATH so we prefer tools
 289   # built here that links on gst-full instead instead of those built in
 290   # subprojects.
 291   devenv.prepend('PATH', meson.current_build_dir())
 292 endif
 293 devenv.set('CURRENT_GST', meson.current_source_dir())
 294 devenv.set('GST_VERSION', meson.project_version())
 295 devenv.set('GST_ENV', 'gst-' + meson.project_version())
 296 devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
 297 devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
 298 meson.add_devenv(devenv)
 299
 300 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 301 configure_file(
 302   output : 'GstPluginsPath.json',
 303   command : [generate_plugins_paths,
 304              '@OUTPUT@',
 305              all_plugins_paths]
 306 )
 307
 308 if building_full
 309   cdata = configuration_data()
 310   cdata.set_quoted('GST_API_VERSION', apiversion)
 311   cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
 312   cdata.set_quoted('PACKAGE_VERSION', gst_version)
 313   cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 314   configure_file(output : 'config.h', configuration : cdata)
 315   configinc = include_directories('.')
 316   gst_c_args = ['-DHAVE_CONFIG_H']
 317
 318   # Generate a .c file which declare and register all built plugins
 319   all_plugin_names = ';'.join(plugins_names)
 320
 321   static_plugins = get_option('gst-full-plugins')
 322   if static_plugins == '*'
 323     static_plugins = all_plugin_names
 324   endif
 325   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 326   init_static_plugins_c = configure_file(
 327     output: 'gstinitstaticplugins.c',
 328     command : [generate_init_static_plugins,
 329                '-o ' + '@OUTPUT@',
 330                '-p ' + static_plugins,
 331                '-e ' + get_option('gst-full-elements'),
 332                '-t ' + get_option('gst-full-typefind-functions'),
 333                '-d ' + get_option('gst-full-device-providers'),
 334                '-T ' + get_option('gst-full-dynamic-types'),
 335                '--giomodules', ';'.join(giomodules),
 336                ]
 337   )
 338
 339   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 340
 341   # Get a list of libraries that needs to be exposed in the ABI.
 342   exposed_libs = []
 343   exposed_deps = []
 344   exposed_girs = []
 345   incdir_deps = []
 346   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 347   all_libs = '*' in wanted_libs
 348
 349   foreach pkgname_library : all_libraries
 350     pkg_name = pkgname_library[0]
 351     lib_def = pkgname_library[1]
 352
 353     if pkg_name in wanted_libs or all_libs
 354       if lib_def.has_key('lib')
 355         exposed_deps += dependency(pkg_name)
 356         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 357         exposed_libs += [lib_def['lib']]
 358       endif
 359
 360       if lib_def.has_key('gir')
 361         exposed_girs += lib_def['gir']
 362       endif
 363     endif
 364   endforeach
 365
 366   # glib and gobject are part of our public API. If we are using glib from the
 367   # system then our pkg-config file must require it. If we built it as
 368   # subproject then we need to link_whole it.
 369   glib_deps = []
 370   glib_dep = dependency('glib-2.0')
 371   gobject_dep = dependency('gobject-2.0')
 372   if gobject_dep.type_name() == 'internal'
 373     glib_subproject = subproject('glib')
 374     exposed_libs += glib_subproject.get_variable('libglib')
 375     exposed_libs += glib_subproject.get_variable('libgobject')
 376     incdir_deps += [
 377       glib_dep.partial_dependency(includes: true),
 378       gobject_dep.partial_dependency(includes: true),
 379     ]
 380   else
 381     glib_deps = [glib_dep, gobject_dep]
 382   endif
 383
 384   link_deps = []
 385   if get_option('gst-full-version-script') != ''
 386     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 387     link_arg = '-Wl,--version-script=' + symbol_map
 388     if cc.has_link_argument(link_arg)
 389       gstfull_link_args += link_arg
 390       link_deps += symbol_map
 391     elif cc.get_id() == 'msvc'
 392       warning('FIXME: Provide a def file to publish the public symbols')
 393     else
 394       warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
 395     endif
 396   endif
 397
 398   giomodules_deps = []
 399   foreach module : giomodules
 400     giomodules_deps += dependency(module)
 401   endforeach
 402
 403   # Build both shared and static library
 404   gstfull = both_libraries('gstreamer-full-1.0',
 405     init_static_plugins_c,
 406     link_args: gstfull_link_args,
 407     link_whole : exposed_libs,
 408     dependencies : [incdir_deps, glib_deps, all_plugins, giomodules_deps],
 409     link_depends : link_deps,
 410     install : true,
 411   )
 412
 413   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 414     dependencies : incdir_deps + glib_deps,
 415     include_directories: include_directories('.')
 416   )
 417
 418   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 419   if gst_full_libs_private == []
 420     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 421   endif
 422
 423   if not get_option('introspection').disabled()
 424     built_girs = {}
 425     foreach gir: exposed_girs
 426       includes = []
 427       foreach include: gir.get('includes', [])
 428         includes += [built_girs.get(include, include)]
 429       endforeach
 430
 431       gir += {
 432         'includes': includes,
 433         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 434         'install': true,
 435       }
 436       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 437     endforeach
 438   endif
 439
 440   pkgconfig.generate(gstfull,
 441     requires: glib_deps,
 442     libraries_private: gst_full_libs_private,
 443     subdirs : 'gstreamer-1.0')
 444   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 445
 446   if not get_option('tools').disabled()
 447     foreach tool, data: all_tools
 448       exe_name = '@0@-@1@'.format(tool, apiversion)
 449       extra_args = data.get('extra_c_args', [])
 450       sources = data.get('files')
 451       install_tag = data.get('install_tag', 'bin')
 452       deps = []
 453       foreach d : data.get('deps', [])
 454         if d not in exposed_deps
 455           deps += d
 456         endif
 457       endforeach
 458
 459       executable(exe_name,
 460         sources,
 461         install: true,
 462         install_tag: install_tag,
 463         include_directories : [configinc],
 464         dependencies : [gst_full_dep] + deps,
 465         c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
 466       )
 467
 468       if data.has_key('man_page')
 469         install_man(data.get('man_page'))
 470       endif
 471
 472     endforeach
 473   endif
 474 endif
 475
 476 message('Building subprojects: ' + ', '.join(subprojects_names))
 477
 478 setenv = find_program('gst-env.py')
 479
 480 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
 481               '--srcdir=@0@'.format(meson.global_source_root())]
 482
 483 subdir('tests')
 484 subdir('ci/fuzzing')
 485
 486 if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 487   # FIXME: Ideally we could get the wrapper directly from meson
 488   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 489   sysroot = meson.get_cross_property('sys_root')
 490   if sysroot != ''
 491     # Logic from meson
 492     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 493   endif
 494 endif
 495
 496 run_target('devenv', command : devenv_cmd)
 497
 498 if orc_subproject.found() and orc_update_targets.length() > 0
 499   alias_target('update-orc-dist', orc_update_targets)
 500 endif
 501
 502 dotnet_format = find_program('dotnet-format', required: false)
 503 if dotnet_format.found()
 504     run_target('csharp_format_check',
 505         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 506             '--check'
 507         ],
 508     )
 509     run_target('csharp_format_apply',
 510         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 511         ],
 512     )
 513 endif
 514
 515 summary({
 516   'gstreamer-full library': building_full,
 517 }, section: 'Build options', bool_yn: true, list_sep: '  ')
 518
 519 gst_tools = []
 520 foreach tool, data: all_tools
 521   gst_tools += tool
 522 endforeach
 523
 524 summary({
 525     'Tools': gst_tools,
 526 }, section: 'Build options', list_sep: ', ')