meson.build

   1 project('gstreamer', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 libexecdir = get_option('libexecdir')
  32 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  33
  34 cc = meson.get_compiler('c')
  35
  36 cdata = configuration_data()
  37
  38 # Ignore several spurious warnings for things gstreamer does very commonly
  39 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  40 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  41 # NOTE: Only add warnings here if you are sure they're spurious
  42 if cc.get_id() == 'msvc'
  43   add_project_arguments(
  44       '/wd4018', # implicit signed/unsigned conversion
  45       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  46       '/wd4244', # lossy type conversion (e.g. double -> int)
  47       '/wd4305', # truncating type conversion (e.g. double -> float)
  48       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  49       language : 'c')
  50 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  51   # FIXME: Add an option for this if people ask for it
  52   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  53 endif
  54
  55 # Symbol visibility
  56 have_visibility_hidden = false
  57 if cc.get_id() == 'msvc'
  58   export_define = '__declspec(dllexport) extern'
  59 elif cc.has_argument('-fvisibility=hidden')
  60   add_project_arguments('-fvisibility=hidden', language: 'c')
  61   export_define = 'extern __attribute__ ((visibility ("default")))'
  62   have_visibility_hidden = true
  63 else
  64   export_define = 'extern'
  65 endif
  66
  67 # Passing this through the command line would be too messy
  68 cdata.set('GST_API_EXPORT', export_define)
  69
  70 # Disable strict aliasing
  71 if cc.has_argument('-fno-strict-aliasing')
  72   add_project_arguments('-fno-strict-aliasing', language: 'c')
  73 endif
  74
  75 # Define G_DISABLE_DEPRECATED for development versions
  76 if gst_version_is_dev
  77   message('Disabling deprecated GLib API')
  78   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  79 endif
  80
  81 cast_checks = get_option('gobject-cast-checks')
  82 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  83   message('Disabling GLib cast checks')
  84   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  85 endif
  86
  87 glib_asserts = get_option('glib-asserts')
  88 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  89   message('Disabling GLib asserts')
  90   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  91 endif
  92
  93 glib_checks = get_option('glib-checks')
  94 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  95   message('Disabling GLib checks')
  96   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  97 endif
  98
  99 cdata.set_quoted('GST_API_VERSION', apiversion)
 100 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
 101 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 102 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 103 cdata.set_quoted('GST_API_VERSION', '1.0')
 104 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 105 cdata.set_quoted('GST_LICENSE', 'LGPL')
 106 cdata.set_quoted('PACKAGE', 'gstreamer')
 107 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 108 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 109 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 110 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 111 cdata.set_quoted('PACKAGE_URL', '')
 112 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 113 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 114 cdata.set_quoted('VERSION', gst_version)
 115 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 116 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 117 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 118   description: 'plugin directory path component, used to find plugins on relocatable builds on windows')
 119 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 120   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 121 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 122
 123 mem_align_opt = get_option('memory-alignment')
 124 if mem_align_opt == 'malloc'
 125   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 126 elif mem_align_opt == 'pagesize'
 127   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 128 else
 129   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 130 endif
 131
 132 if ['darwin', 'ios'].contains(host_system)
 133   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 134 endif
 135
 136 if gst_version_nano > 0
 137     # Have GST_ERROR message printed when running from git
 138     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 139 else
 140     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 141 endif
 142
 143 # GStreamer package name and origin url
 144 gst_package_name = get_option('package-name')
 145 if gst_package_name == ''
 146   if gst_version_nano == 0
 147     gst_package_name = 'GStreamer source release'
 148   elif gst_version_nano == 1
 149     gst_package_name = 'GStreamer git'
 150   else
 151     gst_package_name = 'GStreamer prerelease'
 152   endif
 153 endif
 154 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 155 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 156
 157 # These are only needed/used by the ABI tests
 158 host_defines = [
 159   [ 'x86', 'HAVE_CPU_I386' ],
 160   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 161   [ 'arm', 'HAVE_CPU_ARM' ],
 162   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 163   [ 'mips', 'HAVE_CPU_MIPS' ],
 164   [ 'powerpc', 'HAVE_CPU_PPC' ],
 165   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 166   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 167   [ 'sparc', 'HAVE_CPU_SPARC' ],
 168   [ 'ia64', 'HAVE_CPU_IA64' ],
 169   [ 'hppa', 'HAVE_CPU_HPPA' ],
 170   [ 'm68k', 'HAVE_CPU_M68K' ],
 171   [ 's390', 'HAVE_CPU_S390' ],
 172 ]
 173 foreach h : host_defines
 174   if h.get(0) == host_machine.cpu()
 175     cdata.set(h.get(1), 1)
 176   endif
 177 endforeach
 178 # FIXME: should really be called HOST_CPU or such
 179 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 180
 181 check_headers = [
 182   'dlfcn.h',
 183   'inttypes.h',
 184   'memory.h',
 185   'poll.h',
 186   'stdint.h',
 187   'stdio_ext.h',
 188   'strings.h',
 189   'string.h',
 190   'sys/param.h',
 191   'sys/poll.h',
 192   'sys/prctl.h',
 193   'sys/socket.h',
 194   'sys/stat.h',
 195   'sys/times.h',
 196   'sys/time.h',
 197   'sys/types.h',
 198   'sys/utsname.h',
 199   'sys/wait.h',
 200   'ucontext.h',
 201   'unistd.h',
 202   'valgrind/valgrind.h',
 203   'sys/resource.h',
 204   'sys/uio.h',
 205 ]
 206
 207 if host_system == 'windows'
 208   check_headers += ['winsock2.h']
 209 endif
 210
 211 foreach h : check_headers
 212   if cc.has_header(h)
 213     define = 'HAVE_' + h.underscorify().to_upper()
 214     cdata.set(define, 1)
 215   endif
 216 endforeach
 217
 218 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 219   cdata.set('HAVE_TM_GMTOFF', 1)
 220 endif
 221
 222 check_functions = [
 223   'gmtime_r',
 224   'sigaction',
 225   'getrusage',
 226   'fseeko',
 227   'ftello',
 228   'poll',
 229   'ppoll',
 230   'pselect',
 231   'getpagesize',
 232   'clock_gettime',
 233   # These are needed by libcheck
 234   'getline',
 235   'mkstemp',
 236   'alarm',
 237   'gettimeofday',
 238 ]
 239
 240 foreach f : check_functions
 241   if cc.has_function(f)
 242     define = 'HAVE_' + f.underscorify().to_upper()
 243     cdata.set(define, 1)
 244   endif
 245 endforeach
 246
 247 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 248   cdata.set('HAVE_LOCALTIME_R', 1)
 249   # Needed by libcheck
 250   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 251 endif
 252
 253 if cc.links('''#include <pthread.h>
 254                int main() {
 255                  pthread_setname_np("example"); return 0;
 256                }''', name : 'pthread_setname_np(const char*)')
 257   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 258 endif
 259
 260 # Check for posix timers and monotonic clock
 261 time_prefix = '#include <time.h>\n'
 262 if cdata.has('HAVE_UNISTD_H')
 263   time_prefix += '#include <unistd.h>'
 264 endif
 265
 266 posix_timers_src = time_prefix + '''
 267 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 268 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 269 #endif
 270 '''
 271 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 272   cdata.set('HAVE_POSIX_TIMERS', 1)
 273 endif
 274
 275 monotonic_clock_src = time_prefix + '''
 276 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 277 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 278 #endif
 279 '''
 280 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 281   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 282 endif
 283
 284 # Check for __uint128_t (gcc) by checking for 128-bit division
 285 uint128_t_src = '''int main() {
 286 static __uint128_t v1 = 100;
 287 static __uint128_t v2 = 10;
 288 static __uint128_t u;
 289 u = v1 / v2;
 290 }'''
 291 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 292   cdata.set('HAVE_UINT128_T', 1)
 293 endif
 294
 295 # All supported platforms have long long now
 296 cdata.set('HAVE_LONG_LONG', 1)
 297
 298 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 299 # building with MSVC
 300 if cc.get_id() == 'msvc'
 301   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 302 else
 303   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 304 endif
 305
 306 # -------------------------------------------------------------------------------------
 307 # config.h things needed by libcheck
 308 # -------------------------------------------------------------------------------------
 309 if cc.has_function('getpid')
 310   cdata.set('HAVE_GETPID', 1)
 311 elif host_system == 'windows' and cc.has_function('_getpid')
 312   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 313   cdata.set('HAVE__GETPID', 1)
 314 endif
 315 if cc.has_function('strdup')
 316   cdata.set('HAVE_DECL_STRDUP', 1)
 317 elif host_system == 'windows' and cc.has_function('_strdup')
 318   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 319 endif
 320 if host_system != 'windows'
 321   cdata.set('HAVE_FORK', 1)
 322 else
 323   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 324   cdata.set('HAVE_FORK', 0)
 325 endif
 326 if cc.has_function('strsignal')
 327   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 328 endif
 329 # Check for availability of types
 330 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 331   cdata.set('clockid_t', 'int')
 332 endif
 333 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 334   cdata.set('timer_t', 'int')
 335 endif
 336 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 337                       prefix : '#include <time.h>')
 338   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 339 endif
 340 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 341                       prefix : '#include <time.h>')
 342   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 343 endif
 344
 345 # Platform deps; only ws2_32 and execinfo for now
 346 platform_deps = []
 347 if host_system == 'windows'
 348   platform_deps = [cc.find_library('ws2_32')]
 349 endif
 350
 351 backtrace_deps = []
 352 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 353 dw_dep = dependency('libdw', required: get_option('libdw'))
 354 dbghelp_dep = dependency('DbgHelp', required : get_option('dbghelp'))
 355 backtrace_deps = [unwind_dep, dw_dep, dbghelp_dep]
 356 backtrace_source_info = false
 357 backtrace_minimal = false
 358 # MSVC debug stack trace support
 359 if host_system == 'windows' and dbghelp_dep.found()
 360   cdata.set('HAVE_DBGHELP', 1)
 361   backtrace_source_info = true
 362 # DWARF stack trace support with libunwind and elf-utils
 363 elif unwind_dep.found()
 364   cdata.set('HAVE_UNWIND', 1)
 365   if dw_dep.found()
 366     cdata.set('HAVE_DW', 1)
 367     backtrace_source_info = true
 368   endif
 369   backtrace_minimal = true
 370 # Basic backtrace() stack trace support
 371 elif cc.has_function('backtrace')
 372   cdata.set('HAVE_BACKTRACE', 1)
 373   backtrace_minimal = true
 374 endif
 375 # Print messages about what was enabled
 376 if not backtrace_source_info
 377   if not backtrace_minimal
 378     message('NO support for stack traces.')
 379   else
 380     message('Minimal support for stack traces, no source info.')
 381   endif
 382 endif
 383
 384 if cc.has_header('execinfo.h')
 385   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 386     cdata.set('HAVE_BACKTRACE', 1)
 387   else
 388     execinfo_dep = cc.find_library('execinfo', required : false)
 389     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 390       cdata.set('HAVE_BACKTRACE', 1)
 391       platform_deps += execinfo_dep
 392     endif
 393   endif
 394 endif
 395
 396 gst_debug = get_option('gst_debug')
 397 if not gst_debug
 398   add_project_arguments(['-Wno-unused'], language: 'c')
 399 endif
 400
 401 warning_flags = [
 402   '-Wmissing-declarations',
 403   '-Wmissing-prototypes',
 404   '-Wredundant-decls',
 405   '-Wundef',
 406   '-Wwrite-strings',
 407   '-Wformat',
 408   '-Wformat-nonliteral',
 409   '-Wformat-security',
 410   '-Wold-style-definition',
 411   '-Winit-self',
 412   '-Wmissing-include-dirs',
 413   '-Waddress',
 414   '-Waggregate-return',
 415   '-Wno-multichar',
 416   '-Wdeclaration-after-statement',
 417   '-Wvla',
 418   '-Wpointer-arith',
 419 ]
 420
 421 foreach extra_arg : warning_flags
 422   if cc.has_argument (extra_arg)
 423     add_project_arguments([extra_arg], language: 'c')
 424   endif
 425 endforeach
 426
 427 # Used by the gstutils test
 428 gmp_dep = cc.find_library('gmp', required : false)
 429 cdata.set('HAVE_GMP', gmp_dep.found())
 430 gsl_dep = cc.find_library('gsl', required : false)
 431 gslcblas_dep = cc.find_library('gslcblas', required : false)
 432 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 433 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 434
 435 # Used by gstinfo.c
 436 dl_dep = cc.find_library('dl', required : false)
 437 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 438 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 439 cdata.set('USE_POISONING', get_option('poisoning'))
 440
 441 configinc = include_directories('.')
 442 libsinc = include_directories('libs')
 443 privinc = include_directories('gst')
 444
 445 # Find dependencies
 446 glib_dep = dependency('glib-2.0', version : '>=2.44.0',
 447   fallback: ['glib', 'libglib_dep'])
 448 gobject_dep = dependency('gobject-2.0',
 449   fallback: ['glib', 'libgobject_dep'])
 450 gmodule_dep = dependency('gmodule-2.0',
 451   fallback: ['glib', 'libgmodule_dep'])
 452 if host_system == 'windows'
 453     gio_dep = dependency('gio-2.0',
 454         fallback: ['glib', 'libgio_dep'])
 455 else
 456     gio_dep = [dependency('gio-2.0',
 457                   fallback: ['glib', 'libgio_dep']),
 458                dependency('gio-unix-2.0',
 459                   fallback: ['glib', 'libgio_dep'])]
 460 endif
 461
 462 mathlib = cc.find_library('m', required : false)
 463 # Needed for timer_create/settime/delete
 464 # Also provides clock_gettime in glibc < 2.17
 465 rt_lib = cc.find_library('rt', required : false)
 466
 467 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 468 gnome = import('gnome')
 469
 470 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 471
 472 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 473     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 474     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 475     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 476     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 477     'gst_init(NULL,NULL);', '--quiet']
 478
 479 gst_c_args = ['-DHAVE_CONFIG_H']
 480
 481 # FIXME: This is only needed on windows and probably breaks when
 482 # default_library = 'both'. We should add this flag to static_c_args instead
 483 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 484 if get_option('default_library') == 'static'
 485   gst_c_args += ['-DGST_STATIC_COMPILATION']
 486 endif
 487
 488 # Used in gst/parse/meson.build and below
 489 python3 = import('python').find_installation()
 490
 491 bashcomp_option = get_option('bash-completion')
 492 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 493 bash_completions_dir = ''
 494 bash_helpers_dir = ''
 495
 496 bashcomp_found = false
 497 if bashcomp_dep.found()
 498   bashcomp_found = true
 499   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 500   if bash_completions_dir == ''
 501     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 502     if bashcomp_option.enabled()
 503       error(msg)
 504     else
 505       message(msg)
 506     endif
 507     bashcomp_found = false
 508   endif
 509
 510   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 511   if bash_helpers_dir == ''
 512     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 513     if bashcomp_option.enabled()
 514       error(msg)
 515     else
 516       message(msg)
 517     endif
 518     bashcomp_found = false
 519   endif
 520 endif
 521
 522 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 523
 524 pkgconfig = import('pkgconfig')
 525 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 526 if get_option('default_library') == 'shared'
 527   # If we don't build static plugins there is no need to generate pc files
 528   plugins_pkgconfig_install_dir = disabler()
 529 endif
 530
 531 subdir('gst')
 532 subdir('libs')
 533 subdir('plugins')
 534 if not get_option('tools').disabled()
 535   subdir('tools')
 536 endif
 537 subdir('pkgconfig')
 538 subdir('tests')
 539 subdir('data')
 540 subdir('docs')
 541
 542 # xgettext is optional (on Windows for instance)
 543 if find_program('xgettext', required : get_option('nls')).found()
 544   cdata.set('ENABLE_NLS', 1)
 545   subdir('po')
 546 endif
 547
 548 configure_file(output : 'config.h', configuration : cdata)
 549 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 550 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))