meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version = meson.project_version()
  10 version_arr = gst_version.split('.')
  11 gst_version_major = version_arr[0].to_int()
  12 gst_version_minor = version_arr[1].to_int()
  13 gst_version_micro = version_arr[2].to_int()
  14  if version_arr.length() == 4
  15   gst_version_nano = version_arr[3].to_int()
  16 else
  17   gst_version_nano = 0
  18 endif
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 curversion = gst_version_minor * 100 + gst_version_micro
  25 libversion = '@0@.@1@.0'.format(soversion, curversion)
  26 osxversion = curversion + 1
  27
  28 glib_req = '>= 2.40.0'
  29 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  30
  31 cc = meson.get_compiler('c')
  32 # Ignore several spurious warnings for things gstreamer does very commonly
  33 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  34 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  35 # NOTE: Only add warnings here if you are sure they're spurious
  36 if cc.get_id() == 'msvc'
  37   add_project_arguments(
  38       '/wd4018', # implicit signed/unsigned conversion
  39       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  40       '/wd4244', # lossy type conversion (e.g. double -> int)
  41       '/wd4305', # truncating type conversion (e.g. double -> float)
  42       language : 'c')
  43 endif
  44
  45 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  46   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  47 endif
  48
  49 # Symbol visibility
  50 if cc.has_argument('-fvisibility=hidden')
  51   add_project_arguments('-fvisibility=hidden', language: 'c')
  52 endif
  53
  54 # Disable strict aliasing
  55 if cc.has_argument('-fno-strict-aliasing')
  56   add_project_arguments('-fno-strict-aliasing', language: 'c')
  57 endif
  58
  59 cdata = configuration_data()
  60 cdata.set('VERSION', '"@0@"'.format(gst_version))
  61 cdata.set('PACKAGE', '"gst-editing-services"')
  62 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  64 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  65 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  66 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  67 cdata.set('GST_LICENSE', '"LGPL"')
  68
  69 # Mandatory GST deps
  70 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  71     fallback : ['gstreamer', 'gst_dep'])
  72 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  73     fallback : ['gst-plugins-base', 'pbutils_dep'])
  74 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  75     fallback : ['gst-plugins-base', 'video_dep'])
  76 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  77     fallback : ['gstreamer', 'gst_base_dep'])
  78 if host_machine.system() != 'windows'
  79   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  80     fallback : ['gstreamer', 'gst_check_dep'], required: false)
  81 endif
  82 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  83   fallback : ['gstreamer', 'gst_controller_dep'])
  84 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  85   fallback : ['gst-devtools', 'validate_dep'])
  86
  87 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
  88 libxml_dep = dependency('libxml-2.0')
  89
  90 # TODO Properly port to Gtk 3
  91 # gtk_dep = dependency('gtk+-3.0', required : false)
  92
  93 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  94                gstcontroller_dep, gio_dep, libxml_dep]
  95
  96 if gstvalidate_dep.found()
  97     libges_deps = libges_deps + [gstvalidate_dep]
  98     cdata.set('HAVE_GST_VALIDATE', 1)
  99 endif
 100
 101 configure_file(output : 'config.h', configuration : cdata)
 102
 103
 104 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 105 gnome = import('gnome')
 106
 107 # Fixme, not very elegant.
 108 build_gir = gir.found() and not meson.is_cross_build()
 109 gir_init_section = [ '--add-init-section=' + \
 110     'extern void gst_init(gint*,gchar**);' + \
 111     'extern void ges_init(void);' + \
 112     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 113     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 114     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 115     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 116     'gst_init(NULL,NULL);' + \
 117     'ges_init();' ]
 118
 119 ges_c_args = ['-DHAVE_CONFIG_H', '-DG_LOG_DOMAIN="GES"']
 120 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 121
 122 if gst_dep.type_name() == 'internal'
 123   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 124 else
 125   # We can't check that in the case of subprojects as we won't
 126   # be able to build against an internal dependency (which is not built yet)
 127   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 128 endif
 129
 130 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 131   add_project_arguments('-Wno-unused', language: 'c')
 132 endif
 133
 134 warning_flags = [
 135   '-Wmissing-declarations',
 136   '-Wmissing-prototypes',
 137   '-Wredundant-decls',
 138   '-Wundef',
 139   '-Wwrite-strings',
 140   '-Wformat',
 141   '-Wformat-security',
 142   '-Winit-self',
 143   '-Wmissing-include-dirs',
 144   '-Waddress',
 145   '-Wno-multichar',
 146   '-Wdeclaration-after-statement',
 147   '-Wvla',
 148   '-Wpointer-arith',
 149 ]
 150
 151 foreach extra_arg : warning_flags
 152   if cc.has_argument (extra_arg)
 153     add_project_arguments([extra_arg], language: 'c')
 154   endif
 155 endforeach
 156
 157 configinc = include_directories('.')
 158 subdir('ges')
 159 subdir('plugins')
 160 subdir('tools')
 161 subdir('pkgconfig')
 162 subdir('tests')
 163 subdir('examples')
 164
 165 override_detector = '''
 166 import sys
 167 import os
 168
 169 prefix = sys.argv[1]
 170 version = sys.version_info
 171
 172 # If we are installing in the same prefix as PyGobject
 173 # make sure to install in the right place.
 174 import gi.overrides
 175
 176 overrides_path = os.path.dirname(gi.overrides.__file__)
 177 if os.path.commonprefix([overrides_path, prefix]) == prefix:
 178     print(overrides_path)
 179     exit(0)
 180
 181 # Otherwise follow python's way of install site packages inside
 182 # the provided prefix
 183 if os.name == 'posix':
 184     print(os.path.join(
 185         prefix, 'lib', 'python%d.%d' % (version.major, version.minor),
 186         'site-packages', 'gi', 'overrides'))
 187 else:
 188     print(os.path.join(
 189         prefix, 'Lib', 'Python%d%d' % (version.major, version.minor),
 190         'site-packages', 'gi', 'overrides'))
 191 '''
 192 python3 = import('python3').find_python()
 193 pygi_override_dir = get_option('pygi-overrides-dir')
 194 if pygi_override_dir == ''
 195     cres = run_command(python3, '-c', override_detector, get_option('prefix'))
 196     if cres.returncode() == 0
 197       pygi_override_dir = cres.stdout().strip()
 198     endif
 199     if cres.stderr() != ''
 200         message(cres.stderr())
 201     endif
 202 endif
 203
 204 if pygi_override_dir != ''
 205   message('pygobject overrides directory ' + pygi_override_dir)
 206   subdir('bindings/python')
 207 endif
 208
 209 if build_machine.system() == 'windows'
 210   message('Disabling gtk-doc while building on Windows')
 211 else
 212   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 213     subdir('docs')
 214   else
 215     message('Not building documentation as gtk-doc was not found')
 216   endif
 217 endif
 218
 219 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')