meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 glib_req = '>= 2.40.0'
  25 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26
  27 cc = meson.get_compiler('c')
  28 # Ignore several spurious warnings for things gstreamer does very commonly
  29 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31 # NOTE: Only add warnings here if you are sure they're spurious
  32 if cc.get_id() == 'msvc'
  33   add_project_arguments(
  34       '/wd4018', # implicit signed/unsigned conversion
  35       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  36       '/wd4244', # lossy type conversion (e.g. double -> int)
  37       '/wd4305', # truncating type conversion (e.g. double -> float)
  38       language : 'c')
  39 endif
  40
  41 # Symbol visibility
  42 if cc.has_argument('-fvisibility=hidden')
  43   add_project_arguments('-fvisibility=hidden', language: 'c')
  44 endif
  45
  46 cdata = configuration_data()
  47 cdata.set('VERSION', '"@0@"'.format(gst_version))
  48 cdata.set('PACKAGE', '"gst-editing-services"')
  49 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  50 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  51 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  52 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  53 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  54 cdata.set('GST_LICENSE', '"LGPL"')
  55
  56 # Mandatory GST deps
  57 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  58     fallback : ['gstreamer', 'gst_dep'])
  59 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  60     fallback : ['gst-plugins-base', 'pbutils_dep'])
  61 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  62     fallback : ['gst-plugins-base', 'video_dep'])
  63 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  64     fallback : ['gstreamer', 'gst_base_dep'])
  65 if host_machine.system() != 'windows'
  66   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  67     fallback : ['gstreamer', 'gst_check_dep'], required: false)
  68 endif
  69 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  70   fallback : ['gstreamer', 'gst_controller_dep'])
  71 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  72   fallback : ['gst-devtools', 'validate_dep'])
  73
  74 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
  75 libxml_dep = dependency('libxml-2.0')
  76
  77 # TODO Properly port to Gtk 3
  78 # gtk_dep = dependency('gtk+-3.0', required : false)
  79
  80 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  81                gstcontroller_dep, gio_dep, libxml_dep]
  82
  83 if gstvalidate_dep.found()
  84     libges_deps = libges_deps + [gstvalidate_dep]
  85     cdata.set('HAVE_GST_VALIDATE', 1)
  86 endif
  87
  88 configure_file(output : 'config.h', configuration : cdata)
  89
  90
  91 gir = find_program('g-ir-scanner', required : false)
  92 gnome = import('gnome')
  93
  94 # Fixme, not very elegant.
  95 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
  96 gir_init_section = [ '--add-init-section=' + \
  97     'extern void gst_init(gint*,gchar**);' + \
  98     'extern void ges_init(void);' + \
  99     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 100     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 101     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 102     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 103     'gst_init(NULL,NULL);' + \
 104     'ges_init();' ]
 105
 106 ges_c_args = ['-DHAVE_CONFIG_H']
 107 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 108
 109 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 110
 111 if gst_dep.type_name() == 'internal'
 112     gst_proj = subproject('gstreamer')
 113
 114     if gst_proj.get_variable('disable_gst_debug')
 115         message('GStreamer debug system is disabled')
 116         add_project_arguments('-Wno-unused', language: 'c')
 117     else
 118         message('GStreamer debug system is enabled')
 119     endif
 120 else
 121     # We can't check that in the case of subprojects as we won't
 122     # be able to build against an internal dependency (which is not built yet)
 123     if not cc.compiles('''
 124 #include <gst/gstconfig.h>
 125 #ifdef GST_DISABLE_GST_DEBUG
 126 #error "debugging disabled, make compiler fail"
 127 #endif''' , dependencies: gst_dep)
 128         message('GStreamer debug system is disabled')
 129         add_global_arguments('-Wno-unused', language: 'c')
 130     else
 131         message('GStreamer debug system is enabled')
 132     endif
 133 endif
 134
 135 configinc = include_directories('.')
 136 subdir('ges')
 137 subdir('plugins')
 138 subdir('tools')
 139 subdir('pkgconfig')
 140 subdir('tests')
 141 subdir('examples')
 142
 143 if build_machine.system() == 'windows'
 144   message('Disabling gtk-doc while building on Windows')
 145 elif get_option('disable_gtkdoc')
 146   message('gtk-doc is disabled via options')
 147 else
 148   if find_program('gtkdoc-scan', required : false).found()
 149     subdir('docs')
 150   else
 151     message('Not building documentation as gtk-doc was not found')
 152   endif
 153 endif
 154
 155 python3 = import('python3').find_python()
 156 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')