meson.build

   1 project('gstreamer', 'c', 'cpp',
   2   version : '1.11.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 prefix = get_option('prefix')
  25 libtype = get_option('library_format')
  26
  27 libexecdir = get_option('libexecdir')
  28 helpers_install_dir = libexecdir + '/gstreamer-1.0/'
  29
  30 cc = meson.get_compiler('c')
  31
  32 # Ignore several spurious warnings for things gstreamer does very commonly
  33 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  34 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  35 # NOTE: Only add warnings here if you are sure they're spurious
  36 if cc.get_id() == 'msvc'
  37   add_project_arguments(
  38       '/wd4018', # implicit signed/unsigned conversion
  39       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  40       '/wd4244', # lossy type conversion (e.g. double -> int)
  41       '/wd4305', # truncating type conversion (e.g. double -> float)
  42       language : 'c')
  43 endif
  44
  45 cdata = configuration_data()
  46 cdata.set('GST_VERSION_MAJOR', gst_version_major)
  47 cdata.set('GST_VERSION_MINOR', gst_version_minor)
  48 cdata.set('GST_VERSION_MICRO', gst_version_micro)
  49 cdata.set('GST_VERSION_NANO', gst_version_nano)
  50 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  51 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  52 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  53 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  54 cdata.set('GST_API_VERSION', '"1.0"')
  55 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  56 cdata.set('GST_LICENSE', '"LGPL"')
  57 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  58 cdata.set('GST_PACKAGE_NAME', '"GStreamer source release"')
  59 cdata.set('PACKAGE', '"gstreamer"')
  60 cdata.set('PACKAGE_NAME', '"GStreamer"')
  61 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  62 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  64 cdata.set('PACKAGE_URL', '""')
  65 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  66 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  67 cdata.set('VERSION', '"@0@"'.format(gst_version))
  68 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  69 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  70 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  71 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  72
  73 if gst_version_nano > 0
  74     # Have GST_ERROR message printed when running from git
  75     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  76 else
  77     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  78 endif
  79
  80 # These are only needed/used by the ABI tests
  81 host_defines = [
  82   [ 'x86', 'HAVE_CPU_I386' ],
  83   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  84   [ 'arm', 'HAVE_CPU_ARM' ],
  85   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
  86   [ 'mips', 'HAVE_CPU_MIPS' ],
  87   [ 'powerpc', 'HAVE_CPU_PPC' ],
  88   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
  89   [ 'alpha', 'HAVE_CPU_ALPHA' ],
  90   [ 'sparc', 'HAVE_CPU_SPARC' ],
  91   [ 'ia64', 'HAVE_CPU_IA64' ],
  92   [ 'hppa', 'HAVE_CPU_HPPA' ],
  93   [ 'm68k', 'HAVE_CPU_M68K' ],
  94   [ 's390', 'HAVE_CPU_S390' ],
  95 ]
  96 foreach h : host_defines
  97   if h.get(0) == host_machine.cpu()
  98     cdata.set(h.get(1), 1)
  99   endif
 100 endforeach
 101 # FIXME: should really be called HOST_CPU or such
 102 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 103
 104 check_headers = [['dlfcn.h','HAVE_DLFCN_H'],
 105   ['inttypes.h', 'HAVE_INTTYPES_H'],
 106   ['memory.h', 'HAVE_MEMORY_H'],
 107   ['poll.h', 'HAVE_POLL_H'],
 108   ['stdint.h', 'HAVE_STDINT_H'],
 109   ['stdio_ext.h', 'HAVE_STDIO_EXT_H'],
 110   ['strings.h', 'HAVE_STRINGS_H'],
 111   ['string.h', 'HAVE_STRING_H'],
 112   ['sys/param.h', 'HAVE_SYS_PARAM_H'],
 113   ['sys/poll.h', 'HAVE_SYS_POLL_H'],
 114   ['sys/prctl.h', 'HAVE_SYS_PRCTL_H'],
 115   ['sys/socket.h', 'HAVE_SYS_SOCKET_H'],
 116   ['sys/stat.h', 'HAVE_SYS_STAT_H'],
 117   ['sys/times.h', 'HAVE_SYS_TIMES_H'],
 118   ['sys/time.h', 'HAVE_SYS_TIME_H'],
 119   ['sys/types.h', 'HAVE_SYS_TYPES_H'],
 120   ['sys/utsname.h', 'HAVE_SYS_UTSNAME_H'],
 121   ['sys/wait.h', 'HAVE_SYS_WAIT_H'],
 122   ['ucontext.h', 'HAVE_UCONTEXT_H'],
 123   ['unistd.h', 'HAVE_UNISTD_H'],
 124   ['valgrind/valgrind.h', 'HAVE_VALGRIND_VALGRIND_H'],
 125   ['sys/resource.h', 'HAVE_SYS_RESOURCE_H'],
 126 ]
 127
 128 if host_machine.system() == 'windows'
 129   check_headers += [ ['winsock2.h', 'HAVE_WINSOCK2_H'] ]
 130 endif
 131
 132 foreach h : check_headers
 133   if cc.has_header(h.get(0))
 134     cdata.set(h.get(1), 1)
 135   endif
 136 endforeach
 137
 138 gmtoff_src = '''#include <time.h>
 139 int main(void) {
 140   struct tm t;
 141   t.tm_gmtoff = 0;
 142   return 0;
 143 }
 144 '''
 145
 146 if cc.compiles(gmtoff_src, name : 'tm_gmtoff from time.h')
 147   cdata.set('HAVE_TM_GMTOFF', 1)
 148 endif
 149
 150 if cc.has_function('gmtime_r', prefix : '#include<time.h>')
 151   cdata.set('HAVE_GMTIME_R', 1)
 152 endif
 153 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 154   cdata.set('HAVE_LOCALTIME_R', 1)
 155 endif
 156 if cc.has_function('sigaction', prefix : '#include<signal.h>')
 157   cdata.set('HAVE_SIGACTION', 1)
 158 endif
 159 have_getrusage = cc.has_function('getrusage', prefix : '#include <sys/time.h>\n#include <sys/resource.h>')
 160 if have_getrusage
 161   cdata.set('HAVE_GETRUSAGE', 1)
 162 endif
 163
 164 if cc.has_function('fseeko', prefix : '#include<stdio.h>')
 165   cdata.set('HAVE_FSEEKO', 1)
 166 endif
 167 if cc.has_function('ftello', prefix : '#include<stdio.h>')
 168   cdata.set('HAVE_FTELLO', 1)
 169 endif
 170 if cc.has_function('fsetpos', prefix : '#include<stdio.h>')
 171   cdata.set('HAVE_FSETPOS', 1)
 172 endif
 173 if cc.has_function('fgetpos', prefix : '#include<stdio.h>')
 174   cdata.set('HAVE_FGETPOS', 1)
 175 endif
 176 if cc.has_function('poll', prefix : '#include<poll.h>')
 177   cdata.set('HAVE_POLL', 1)
 178 endif
 179 if cc.has_function('pselect', prefix : '#include<sys/select.h>')
 180   cdata.set('HAVE_PSELECT', 1)
 181 endif
 182 cdata.set('HAVE_MMAP', 1)
 183
 184 if cc.has_function('posix_memalign', prefix : '#include<stdlib.h>')
 185   cdata.set('HAVE_POSIX_MEMALIGN', 1)
 186 endif
 187 if cc.has_function('getpagesize', prefix : '#include<unistd.h>')
 188   cdata.set('HAVE_GETPAGESIZE', 1)
 189 endif
 190
 191 # With XCode 8, clock_gettime will be incorrectly detected as being available
 192 # regardless of what version of OS X you target because the symbol is available
 193 # in the .tbd file as a weak symbol.
 194 # See: https://bugzilla.gnome.org/show_bug.cgi?id=772451
 195 #
 196 # We cannot simply do cc.has_function with -Wl,-no_weak_imports because the
 197 # check does its own prototype decl that doesn't trigger that compiler flag.
 198 #
 199 # It's only starting from macOS 10.12 and iOS 10.0 that clock_gettime is
 200 # actually available, so we can unconditionally disable it for older versions.
 201 disable_clock_gettime_src = '''#include <AvailabilityMacros.h>
 202 #include <TargetConditionals.h>
 203 #if defined(TARGET_OS_MAC)
 204 #  if MAC_OS_X_VERSION_MIN_REQUIRED < MAC_OS_X_VERSION_10_12
 205 #    error "Not compiling for OS X 10.12 or later"
 206 #  endif
 207 #else
 208 #  if __IPHONE_OS_VERSION_MIN_REQUIRED < __IPHONE_10_0
 209 #    error "Not compiling for iOS 10.0 or later"
 210 #  endif
 211 #endif
 212 '''
 213
 214 if cc.has_function('clock_gettime', prefix : '#include <time.h>')
 215   if host_machine.system() == 'darwin'
 216     if cc.compiles(disable_clock_gettime_src, name : 'target darwin/ios version has clock_gettime')
 217       cdata.set('HAVE_CLOCK_GETTIME', 1)
 218     endif
 219   else
 220     cdata.set('HAVE_CLOCK_GETTIME', 1)
 221   endif
 222 endif
 223
 224 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 225 # building with MSVC
 226 if cc.get_id() == 'msvc'
 227   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 228 else
 229   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 230 endif
 231
 232 # -------------------------------------------------------------------------------------
 233 # config.h things needed by libcheck (FIXME: move into the libcheck meson.build) (tpm)
 234 # -------------------------------------------------------------------------------------
 235 # FIXME: check if it is _getpid or getpid on windows (tpm)
 236 if cc.has_function('getpid', prefix : '#include <sys/types.h>\n#include <unistd.h>')
 237   cdata.set('HAVE_GETPID', 1)
 238 elif cc.has_function('_getpid', prefix : '#include <process.h>')
 239   cdata.set('HAVE__GETPID', 1)
 240 endif
 241 # FIXME: check for _strdup() but how/where and with what includes? (windows?) (tpm)
 242 if cc.has_function('strdup', prefix : '#include <string.h>')
 243   cdata.set('HAVE_DECL_STRDUP', 1)
 244 elif cc.has_function('_strdup', prefix : '#include <string.h>')
 245   cdata.set('HAVE__STRDUP', 1)
 246 endif
 247 if cc.has_function('mkstemp', prefix : '#include <stdlib.h>')
 248   cdata.set('HAVE_MKSTEMP', 1)
 249 endif
 250 if host_machine.system() != 'windows'
 251   cdata.set('HAVE_FORK', 1)
 252 else
 253   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 254   cdata.set('HAVE_FORK', 0)
 255 endif
 256 if cc.has_function('alarm', prefix : '#include <unistd.h>')
 257   cdata.set('HAVE_ALARM', 1)
 258 endif
 259 if cc.has_function('localtime_r', prefix : '#include <time.h>')
 260   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 261 endif
 262 if cc.has_function('strsignal', prefix : '#include <string.h>')
 263   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 264 endif
 265
 266 # Platform deps; only ws2_32 and execinfo for now
 267 platform_deps = []
 268 if host_machine.system() == 'windows'
 269   platform_deps = [cc.find_library('ws2_32')]
 270 endif
 271
 272 unwind_dep = dependency('libunwind', required : false)
 273 dw_dep = dependency('libdw', required: false)
 274 if unwind_dep.found()
 275   cdata.set('HAVE_UNWIND', 1)
 276   if dw_dep.found()
 277     cdata.set('HAVE_DW', 1)
 278   else
 279     message('Support for backtraces is partial only.')
 280   endif
 281 else
 282   if cc.has_function('backtrace')
 283     cdata.set('HAVE_BACKTRACE', 1)
 284   else
 285       message('NO backtraces support.')
 286   endif
 287 endif
 288
 289 if cc.has_header('execinfo.h')
 290   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 291     cdata.set('HAVE_BACKTRACE', 1)
 292   else
 293     execinfo_dep = cc.find_library('execinfo', required : false)
 294     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 295       cdata.set('HAVE_BACKTRACE', 1)
 296       platform_deps += execinfo_dep
 297     endif
 298   endif
 299 endif
 300
 301 configure_file(input : 'config.h.meson',
 302   output : 'config.h',
 303   configuration : cdata)
 304
 305
 306 configinc = include_directories('.')
 307 libsinc = include_directories('libs')
 308 privinc = include_directories('gst')
 309
 310 # Find dependencies
 311 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
 312 gobject_dep = dependency('gobject-2.0')
 313 gmodule_dep = dependency('gmodule-2.0')
 314 if host_machine.system() == 'windows'
 315     gio_dep = dependency('gio-2.0')
 316 else
 317     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
 318 endif
 319
 320 mathlib = cc.find_library('m', required : false)
 321 rt_lib = cc.find_library('rt', required : false) # clock_gettime
 322
 323 gir = find_program('g-ir-scanner', required : false)
 324 gnome = import('gnome')
 325
 326 # Fixme, not very elegant.
 327 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 328
 329 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 330     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 331     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 332     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 333     'gst_init(NULL,NULL);' ]
 334 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 335
 336 gst_c_args = ['-DHAVE_CONFIG_H']
 337 if libtype == 'static'
 338   gst_c_args += ['-DGST_STATIC_COMPILATION']
 339 endif
 340
 341 subdir('gst')
 342 subdir('libs')
 343 subdir('plugins')
 344 subdir('tools')
 345 subdir('pkgconfig')
 346 subdir('tests')
 347 subdir('po')
 348
 349 if build_machine.system() == 'windows'
 350   message('Disabling gtk-doc while building on Windows')
 351 elif get_option('disable_gtkdoc')
 352   message('gtk-doc is disabled via options')
 353 else
 354   if find_program('gtkdoc-scan', required : false).found()
 355     subdir('docs')
 356   else
 357     message('Not building documentation as gtk-doc was not found')
 358   endif
 359 endif
 360
 361 python3 = find_program('python3')
 362 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')