meson.build

   1 project('All GStreamer modules', 'c',
   2   version : '1.19.2.1',
   3   meson_version : '>= 0.54.0',
   4   default_options : ['buildtype=debugoptimized'])
   5
   6 gst_version = '>= @0@'.format(meson.project_version())
   7
   8 build_system = build_machine.system()
   9 cc = meson.get_compiler('c')
  10
  11 gnome = import('gnome')
  12 pkgconfig = import('pkgconfig')
  13 python3 = import('python').find_installation()
  14 # Ensure that we're not being run from inside the gst-uninstalled env
  15 # because that will confuse meson, and it might find the already-built
  16 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  17 # reconfigure because ninja doesn't care about the env.
  18 ensure_not_uninstalled = '''
  19 import os
  20 assert('GST_ENV' not in os.environ)
  21 '''
  22 cmdres = run_command(python3, '-c', ensure_not_uninstalled)
  23 if cmdres.returncode() != 0
  24   error('Do not run `ninja` or `meson` for gst-build inside the uninstalled environment, you will run into problems')
  25 endif
  26
  27 # Install gst-indent pre-commit hook
  28 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")')
  29
  30 # Ensure that the user does not have Strawberry Perl in PATH, since it ships
  31 # with a pkg-config.bat and broken pkgconfig files for libffi and zlib. Will
  32 # cause a build error, such as in
  33 # https://gitlab.freedesktop.org/gstreamer/gst-build/-/issues/41
  34 ensure_no_strawberry_perl = '''
  35 import os
  36 assert(r'Strawberry\perl\bin' not in os.environ['PATH'])
  37 '''
  38 if build_system == 'windows'
  39   cmdres = run_command(python3, '-c', ensure_no_strawberry_perl)
  40   if cmdres.returncode() != 0
  41     error('You have Strawberry Perl in PATH which is known to cause build issues with gst-build. Please remove it from PATH or uninstall it.')
  42   endif
  43 endif
  44
  45 documented_projects = ''
  46 # Make it possible to use msys2 built zlib which fails
  47 # when not using the mingw toolchain as it uses unistd.h
  48 if not meson.is_subproject() and cc.get_id() == 'msvc'
  49   uname = find_program('uname', required: false)
  50   if uname.found()
  51     ret = run_command(uname, '-o')
  52     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  53       ret = run_command(uname, '-r')
  54       # The kernel version returned by uname is actually the msys version
  55       if ret.returncode() == 0 and ret.stdout().startswith('2')
  56         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  57         if cc.find_library('z').found()
  58           add_global_arguments('-DZ_SOLO', language: 'c')
  59         endif
  60       endif
  61     endif
  62   endif
  63 endif
  64
  65 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  66 # not a subproject, because subprojects are not allowed to call
  67 # add_global_arguments().
  68 if not meson.is_subproject() and cc.get_id() == 'msvc'
  69   add_global_arguments(
  70       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  71       language: ['c', 'cpp'])
  72 endif
  73
  74 # Ordered list of subprojects (dict has no ordering guarantees)
  75 subprojects = [
  76   ['gstreamer', {'build-hotdoc': true}],
  77   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
  78   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
  79   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
  80   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
  81   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
  82   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
  83   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
  84   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true }],
  85   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
  86   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true}],
  87   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
  88   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
  89   ['gstreamer-sharp', { 'option': get_option('sharp') }],
  90   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.38.1' }],
  91   ['gst-python', { 'option': get_option('python')}],
  92   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
  93   ['gst-plugins-rs', { 'option': get_option('rs'), 'match_gst_version': false}],
  94 ]
  95
  96 symlink = '''
  97 import os
  98
  99 os.symlink(os.path.join('@1@', 'subprojects', '@0@'),
 100   os.path.join('@1@', '@0@'))
 101 '''
 102
 103 if build_system == 'windows'
 104   subproject('win-flex-bison-binaries')
 105   subproject('win-nasm')
 106 elif build_system == 'darwin'
 107   subproject('macos-bison-binary')
 108 endif
 109
 110 orc_subproject = subproject('orc', required: get_option('orc'))
 111
 112 subprojects_names = []
 113 plugins_doc_caches = []
 114 orc_update_targets = []
 115 all_plugins = []
 116 all_libraries = []
 117 foreach sp : subprojects
 118   project_name = sp[0]
 119   build_infos = sp[1]
 120   is_required = build_infos.get('option', true)
 121   sysdep = build_infos.get('sysdep', '')
 122   sysdep_version = build_infos.get('sysdep_version', '')
 123   match_gst_version = build_infos.get('match_gst_version', true)
 124
 125   if match_gst_version
 126     subproj = subproject(project_name, version: gst_version, required: is_required)
 127   elif sysdep != ''
 128       sysdep_dep = dependency(sysdep, version: sysdep_version, required: false)
 129       if not sysdep_dep.found()
 130         subproj = subproject(project_name, required: is_required)
 131       endif
 132   else
 133     subproj = subproject(project_name, required: is_required)
 134   endif
 135
 136   if subproj.found()
 137     plugins = subproj.get_variable('plugins', [])
 138     all_plugins += plugins
 139     all_libraries += subproj.get_variable('libraries', [])
 140
 141     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 142
 143     subprojects_names += [project_name]
 144     cmdres = run_command(python3, '-c', symlink.format(project_name, meson.current_source_dir()))
 145     if cmdres.returncode() == 0
 146       message('Created symlink to ' + project_name)
 147     endif
 148
 149     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 150       if plugins.length() > 0
 151         plugins_doc_caches += [subproj.get_variable('plugins_doc_dep')]
 152       endif
 153       if documented_projects != ''
 154         documented_projects += ','
 155       endif
 156       documented_projects  += project_name
 157     endif
 158   endif
 159 endforeach
 160
 161 # Check if we need to also build glib-networking for TLS modules
 162 glib_dep = dependency('glib-2.0')
 163 if glib_dep.type_name() == 'internal'
 164   subproject('glib-networking', required : get_option('tls'),
 165              default_options: ['gnutls=auto', 'openssl=auto'])
 166 endif
 167
 168 plugins_doc_dep = custom_target('plugins-doc-cache',
 169   command: [python3, '-c', 'print("Built all doc caches")'],
 170   input: plugins_doc_caches,
 171   output: 'plugins_doc_caches',
 172   capture: true,
 173 )
 174
 175 if meson.is_cross_build() or build_machine.system() == 'windows'
 176     if get_option('doc').enabled()
 177         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 178     endif
 179
 180     documented_projects = ''
 181     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 182 else
 183   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 184   if not hotdoc_p.found()
 185     documented_projects = ''
 186     message('Not building documentation as hotdoc was not found')
 187   endif
 188 endif
 189
 190 write_file_contents = '''
 191 import os
 192 import sys
 193
 194 assert len(sys.argv) >= 3
 195 fname = sys.argv[1]
 196 contents = sys.argv[2]
 197
 198 with open(fname, 'w') as f:
 199     f.write(contents)
 200 '''
 201
 202 configure_file(
 203   output : 'GstDocumentedSubprojects',
 204   command : [python3,
 205              '-c', write_file_contents,
 206              '@OUTPUT@',
 207              documented_projects]
 208 )
 209
 210 if documented_projects != ''
 211   subproject('gst-docs', required: get_option('doc').enabled())
 212   message('Gst docs subprojects: ' + documented_projects)
 213 endif
 214
 215 all_plugins_paths = []
 216 foreach plugin: all_plugins
 217   all_plugins_paths += plugin.full_path()
 218 endforeach
 219 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 220 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 221 all_plugins_paths = pathsep.join(all_plugins_paths)
 222
 223 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 224 configure_file(
 225   output : 'GstPluginsPath.json',
 226   command : [generate_plugins_paths,
 227              '@OUTPUT@',
 228              all_plugins_paths]
 229 )
 230
 231 if get_option('default_library') == 'static'
 232   # Generate a .c file which declare and register all built plugins
 233   plugins_names = []
 234   foreach plugin: all_plugins
 235     plugins_names += plugin.full_path()
 236   endforeach
 237   all_plugin_names = ';'.join(plugins_names)
 238
 239   static_plugins = get_option('gst-full-plugins')
 240   if static_plugins == '*'
 241     static_plugins = all_plugin_names
 242   endif
 243   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 244   init_static_plugins_c = configure_file(
 245     output: 'gstinitstaticplugins.c',
 246     command : [generate_init_static_plugins,
 247                '-o ' + '@OUTPUT@',
 248                '-p ' + static_plugins,
 249                '-e ' + get_option('gst-full-elements'),
 250                '-t ' + get_option('gst-full-typefind-functions'),
 251                '-d ' + get_option('gst-full-device-providers'),
 252                '-T ' + get_option('gst-full-dynamic-types')
 253                ]
 254   )
 255
 256   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 257
 258   # Get a list of libraries that needs to be exposed in the ABI.
 259   exposed_libs = []
 260   exposed_girs = []
 261   incdir_deps = []
 262   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 263   all_libs = '*' in wanted_libs
 264
 265   foreach pkgname_library : all_libraries
 266     pkg_name = pkgname_library[0]
 267     lib_def = pkgname_library[1]
 268
 269     if pkg_name in wanted_libs or all_libs
 270       if lib_def.has_key('lib')
 271         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 272         exposed_libs += [lib_def['lib']]
 273       endif
 274
 275       if lib_def.has_key('gir')
 276         exposed_girs += lib_def['gir']
 277       endif
 278     endif
 279   endforeach
 280
 281   # glib and gobject are part of our public API. If we are using glib from the
 282   # system then our pkg-config file must require it. If we built it as
 283   # subproject then we need to link_whole it.
 284   glib_deps = []
 285   glib_dep = dependency('glib-2.0')
 286   gobject_dep = dependency('gobject-2.0')
 287   if gobject_dep.type_name() == 'internal'
 288     glib_subproject = subproject('glib')
 289     exposed_libs += glib_subproject.get_variable('libglib')
 290     exposed_libs += glib_subproject.get_variable('libgobject')
 291     incdir_deps += [
 292       glib_dep.partial_dependency(includes: true),
 293       gobject_dep.partial_dependency(includes: true),
 294     ]
 295   else
 296     glib_deps = [glib_dep, gobject_dep]
 297   endif
 298
 299   link_deps = []
 300   if get_option('gst-full-version-script') != ''
 301     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 302     link_arg = '-Wl,--version-script=' + symbol_map
 303     if cc.has_link_argument(link_arg)
 304       gstfull_link_args += link_arg
 305       link_deps += symbol_map
 306     elif cc.get_id() == 'msvc'
 307       warning('FIXME: Provide a def file to publish the public symbols')
 308     else
 309       error('Failed to link with version script (' + symbol_map + '), check logs for details')
 310     endif
 311   endif
 312
 313   # Build both shared and static library
 314   gstfull = both_libraries('gstreamer-full-1.0',
 315     init_static_plugins_c,
 316     link_with : all_plugins,
 317     link_args: gstfull_link_args,
 318     link_whole : exposed_libs,
 319     dependencies : incdir_deps + glib_deps,
 320     link_depends : link_deps,
 321     install : true,
 322   )
 323
 324   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 325     dependencies : incdir_deps + glib_deps,
 326     include_directories: include_directories('.')
 327   )
 328
 329   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 330   if gst_full_libs_private == []
 331     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 332   endif
 333
 334   if not get_option('introspection').disabled()
 335     built_girs = {}
 336     foreach gir: exposed_girs
 337       includes = []
 338       foreach include: gir.get('includes', [])
 339         includes += [built_girs.get(include, include)]
 340       endforeach
 341
 342       gir += {
 343         'includes': includes,
 344         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 345         'install': true,
 346       }
 347       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 348     endforeach
 349   endif
 350
 351   pkgconfig.generate(gstfull,
 352     requires: glib_deps,
 353     libraries_private: gst_full_libs_private,
 354     subdirs : 'gstreamer-1.0')
 355   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 356 endif
 357
 358 foreach custom_subproj: get_option('custom_subprojects').split(',')
 359     if custom_subproj != ''
 360         message ('Adding custom subproject ' + custom_subproj)
 361         subproject(custom_subproj)
 362         subprojects_names += [custom_subproj]
 363     endif
 364 endforeach
 365
 366 message('Building subprojects: ' + ', '.join(subprojects_names))
 367
 368 setenv = find_program('gst-env.py')
 369 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.build_root()),
 370               '--gstbuilddir=@0@'.format(meson.current_build_dir()),
 371               '--srcdir=@0@'.format(meson.source_root())]
 372
 373 subdir('tests')
 374 if meson.has_exe_wrapper() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 375   # FIXME: Ideally we could get the wrapper directly from meson
 376   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 377   sysroot = meson.get_cross_property('sys_root')
 378   if sysroot != ''
 379     # Logic from meson
 380     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 381   endif
 382 endif
 383
 384 run_target('uninstalled', command : devenv_cmd)
 385 run_target('devenv', command : devenv_cmd)
 386
 387 if orc_subproject.found() and orc_update_targets.length() > 0
 388   alias_target('update-orc-dist', orc_update_targets)
 389 endif