meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 glib_req = '>= 2.40.0'
  25 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26
  27 cc = meson.get_compiler('c')
  28 # Ignore several spurious warnings for things gstreamer does very commonly
  29 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31 # NOTE: Only add warnings here if you are sure they're spurious
  32 if cc.get_id() == 'msvc'
  33   add_project_arguments(
  34       '/wd4018', # implicit signed/unsigned conversion
  35       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  36       '/wd4244', # lossy type conversion (e.g. double -> int)
  37       '/wd4305', # truncating type conversion (e.g. double -> float)
  38       language : 'c')
  39 endif
  40
  41 # Symbol visibility
  42 if cc.has_argument('-fvisibility=hidden')
  43   add_project_arguments('-fvisibility=hidden', language: 'c')
  44 endif
  45
  46 # Disable strict aliasing
  47 if cc.has_argument('-fno-strict-aliasing')
  48   add_project_arguments('-fno-strict-aliasing', language: 'c')
  49 endif
  50
  51 cdata = configuration_data()
  52 cdata.set('VERSION', '"@0@"'.format(gst_version))
  53 cdata.set('PACKAGE', '"gst-editing-services"')
  54 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  55 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  56 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  57 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  58 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  59 cdata.set('GST_LICENSE', '"LGPL"')
  60
  61 # Mandatory GST deps
  62 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  63     fallback : ['gstreamer', 'gst_dep'])
  64 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  65     fallback : ['gst-plugins-base', 'pbutils_dep'])
  66 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  67     fallback : ['gst-plugins-base', 'video_dep'])
  68 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  69     fallback : ['gstreamer', 'gst_base_dep'])
  70 if host_machine.system() != 'windows'
  71   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  72     fallback : ['gstreamer', 'gst_check_dep'], required: false)
  73 endif
  74 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  75   fallback : ['gstreamer', 'gst_controller_dep'])
  76 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  77   fallback : ['gst-devtools', 'validate_dep'])
  78
  79 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
  80 libxml_dep = dependency('libxml-2.0')
  81
  82 # TODO Properly port to Gtk 3
  83 # gtk_dep = dependency('gtk+-3.0', required : false)
  84
  85 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  86                gstcontroller_dep, gio_dep, libxml_dep]
  87
  88 if gstvalidate_dep.found()
  89     libges_deps = libges_deps + [gstvalidate_dep]
  90     cdata.set('HAVE_GST_VALIDATE', 1)
  91 endif
  92
  93 configure_file(output : 'config.h', configuration : cdata)
  94
  95
  96 gir = find_program('g-ir-scanner', required : false)
  97 gnome = import('gnome')
  98
  99 # Fixme, not very elegant.
 100 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 101 gir_init_section = [ '--add-init-section=' + \
 102     'extern void gst_init(gint*,gchar**);' + \
 103     'extern void ges_init(void);' + \
 104     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 105     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 106     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 107     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 108     'gst_init(NULL,NULL);' + \
 109     'ges_init();' ]
 110
 111 ges_c_args = ['-DHAVE_CONFIG_H']
 112 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 113
 114 if gst_dep.type_name() == 'internal'
 115     gst_proj = subproject('gstreamer')
 116
 117     if gst_proj.get_variable('disable_gst_debug')
 118         message('GStreamer debug system is disabled')
 119         add_project_arguments('-Wno-unused', language: 'c')
 120     else
 121         message('GStreamer debug system is enabled')
 122     endif
 123 else
 124     # We can't check that in the case of subprojects as we won't
 125     # be able to build against an internal dependency (which is not built yet)
 126     if not cc.compiles('''
 127 #include <gst/gstconfig.h>
 128 #ifdef GST_DISABLE_GST_DEBUG
 129 #error "debugging disabled, make compiler fail"
 130 #endif''' , dependencies: gst_dep)
 131         message('GStreamer debug system is disabled')
 132         add_global_arguments('-Wno-unused', language: 'c')
 133     else
 134         message('GStreamer debug system is enabled')
 135     endif
 136 endif
 137
 138 configinc = include_directories('.')
 139 subdir('ges')
 140 subdir('plugins')
 141 subdir('tools')
 142 subdir('pkgconfig')
 143 subdir('tests')
 144 subdir('examples')
 145
 146 if build_machine.system() == 'windows'
 147   message('Disabling gtk-doc while building on Windows')
 148 elif get_option('disable_gtkdoc')
 149   message('gtk-doc is disabled via options')
 150 else
 151   if find_program('gtkdoc-scan', required : false).found()
 152     subdir('docs')
 153   else
 154     message('Not building documentation as gtk-doc was not found')
 155   endif
 156 endif
 157
 158 python3 = import('python3').find_python()
 159 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')