meson.build

   1 project('gstreamer', 'c', 'cpp',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('library_format')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48   # FIXME: Add FATAL_WARNINGS from configure.ac
  49 endif
  50
  51 cdata = configuration_data()
  52 cdata.set('GST_VERSION_MAJOR', gst_version_major)
  53 cdata.set('GST_VERSION_MINOR', gst_version_minor)
  54 cdata.set('GST_VERSION_MICRO', gst_version_micro)
  55 cdata.set('GST_VERSION_NANO', gst_version_nano)
  56 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  57 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  58 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  59 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  60 cdata.set('GST_API_VERSION', '"1.0"')
  61 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  62 cdata.set('GST_LICENSE', '"LGPL"')
  63 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  64 cdata.set('GST_PACKAGE_NAME', '"GStreamer source release"')
  65 cdata.set('PACKAGE', '"gstreamer"')
  66 cdata.set('PACKAGE_NAME', '"GStreamer"')
  67 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  68 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  69 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  70 cdata.set('PACKAGE_URL', '""')
  71 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  72 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  73 cdata.set('VERSION', '"@0@"'.format(gst_version))
  74 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  75 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  76 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  77 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  78
  79 if gst_version_nano > 0
  80     # Have GST_ERROR message printed when running from git
  81     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  82 else
  83     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  84 endif
  85
  86 # These are only needed/used by the ABI tests
  87 host_defines = [
  88   [ 'x86', 'HAVE_CPU_I386' ],
  89   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  90   [ 'arm', 'HAVE_CPU_ARM' ],
  91   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
  92   [ 'mips', 'HAVE_CPU_MIPS' ],
  93   [ 'powerpc', 'HAVE_CPU_PPC' ],
  94   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
  95   [ 'alpha', 'HAVE_CPU_ALPHA' ],
  96   [ 'sparc', 'HAVE_CPU_SPARC' ],
  97   [ 'ia64', 'HAVE_CPU_IA64' ],
  98   [ 'hppa', 'HAVE_CPU_HPPA' ],
  99   [ 'm68k', 'HAVE_CPU_M68K' ],
 100   [ 's390', 'HAVE_CPU_S390' ],
 101 ]
 102 foreach h : host_defines
 103   if h.get(0) == host_machine.cpu()
 104     cdata.set(h.get(1), 1)
 105   endif
 106 endforeach
 107 # FIXME: should really be called HOST_CPU or such
 108 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 109
 110 check_headers = [
 111   'dlfcn.h',
 112   'inttypes.h',
 113   'memory.h',
 114   'poll.h',
 115   'stdint.h',
 116   'stdio_ext.h',
 117   'strings.h',
 118   'string.h',
 119   'sys/param.h',
 120   'sys/poll.h',
 121   'sys/prctl.h',
 122   'sys/socket.h',
 123   'sys/stat.h',
 124   'sys/times.h',
 125   'sys/time.h',
 126   'sys/types.h',
 127   'sys/utsname.h',
 128   'sys/wait.h',
 129   'ucontext.h',
 130   'unistd.h',
 131   'valgrind/valgrind.h',
 132   'sys/resource.h',
 133 ]
 134
 135 if host_machine.system() == 'windows'
 136   check_headers += ['winsock2.h']
 137 endif
 138
 139 foreach h : check_headers
 140   if cc.has_header(h)
 141     define = 'HAVE_' + h.underscorify().to_upper()
 142     cdata.set(define, 1)
 143   endif
 144 endforeach
 145
 146 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 147   cdata.set('HAVE_TM_GMTOFF', 1)
 148 endif
 149
 150 check_functions = [
 151   'gmtime_r',
 152   'sigaction',
 153   'getrusage',
 154   'fseeko',
 155   'ftello',
 156   'poll',
 157   'pselect',
 158   'getpagesize',
 159   'clock_gettime',
 160   # These are needed by libcheck
 161   'getline',
 162   'mkstemp',
 163   'alarm',
 164   'gettimeofday',
 165 ]
 166
 167 foreach f : check_functions
 168   if cc.has_function(f)
 169     define = 'HAVE_' + f.underscorify().to_upper()
 170     cdata.set(define, 1)
 171   endif
 172 endforeach
 173
 174 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 175   cdata.set('HAVE_LOCALTIME_R', 1)
 176   # Needed by libcheck
 177   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 178 endif
 179
 180 if cc.links('''#include <pthread.h>
 181                                                          int main() {
 182                                                                  pthread_setname_np("example");
 183                                                          }''', name : 'pthread_setname_np(const char*)')
 184         cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 185 endif
 186
 187 # Check for posix timers and the monotonic clock
 188 time_prefix = '#include <time.h>\n'
 189 if cdata.has('HAVE_UNISTD_H')
 190   time_prefix += '#include <unistd.h>'
 191 endif
 192
 193 posix_timers_src = time_prefix + '''
 194 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 195 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 196 #endif
 197 '''
 198 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
 199   cdata.set('HAVE_POSIX_TIMERS', 1)
 200 endif
 201
 202 monotonic_clock_src = time_prefix + '''
 203 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 204 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 205 #endif
 206 '''
 207 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
 208   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 209 endif
 210
 211 # Check for __uint128_t (gcc) by checking for 128-bit division
 212 uint128_t_src = '''int main() {
 213 static __uint128_t v1 = 100;
 214 static __uint128_t v2 = 10;
 215 static __uint128_t u;
 216 u = v1 / v2;
 217 }'''
 218 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 219   cdata.set('HAVE_UINT128_T', 1)
 220 endif
 221
 222 # All supported platforms have long long now
 223 cdata.set('HAVE_LONG_LONG', 1)
 224
 225 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 226 # building with MSVC
 227 if cc.get_id() == 'msvc'
 228   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 229 else
 230   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 231 endif
 232
 233 # -------------------------------------------------------------------------------------
 234 # config.h things needed by libcheck
 235 # -------------------------------------------------------------------------------------
 236 if cc.has_function('getpid')
 237   cdata.set('HAVE_GETPID', 1)
 238 elif host_system == 'windows' and cc.has_function('_getpid')
 239   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 240   cdata.set('HAVE__GETPID', 1)
 241 endif
 242 if cc.has_function('strdup')
 243   cdata.set('HAVE_DECL_STRDUP', 1)
 244 elif host_system == 'windows' and cc.has_function('_strdup')
 245   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 246 endif
 247 if host_machine.system() != 'windows'
 248   cdata.set('HAVE_FORK', 1)
 249 else
 250   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 251   cdata.set('HAVE_FORK', 0)
 252 endif
 253 if cc.has_function('strsignal')
 254   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 255 endif
 256 # Check for availability of types
 257 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 258   cdata.set('clockid_t', 'int')
 259 endif
 260 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 261   cdata.set('timer_t', 'int')
 262 endif
 263 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 264                       prefix : '#include <time.h>')
 265   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 266 endif
 267 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 268                       prefix : '#include <time.h>')
 269   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 270 endif
 271
 272 # Platform deps; only ws2_32 and execinfo for now
 273 platform_deps = []
 274 if host_machine.system() == 'windows'
 275   platform_deps = [cc.find_library('ws2_32')]
 276 endif
 277
 278 backtrace_deps = []
 279 if not get_option('disable_libunwind')
 280   unwind_dep = dependency('libunwind', required : false)
 281   dw_dep = dependency('libdw', required: false)
 282   backtrace_deps = [unwind_dep, dw_dep]
 283   if unwind_dep.found()
 284     cdata.set('HAVE_UNWIND', 1)
 285     if dw_dep.found()
 286       cdata.set('HAVE_DW', 1)
 287     else
 288       message('Support for backtraces is partial only.')
 289     endif
 290   else
 291     if cc.has_function('backtrace')
 292       cdata.set('HAVE_BACKTRACE', 1)
 293     else
 294         message('NO backtraces support.')
 295     endif
 296   endif
 297 endif
 298
 299 if cc.has_header('execinfo.h')
 300   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 301     cdata.set('HAVE_BACKTRACE', 1)
 302   else
 303     execinfo_dep = cc.find_library('execinfo', required : false)
 304     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 305       cdata.set('HAVE_BACKTRACE', 1)
 306       platform_deps += execinfo_dep
 307     endif
 308   endif
 309 endif
 310
 311 disable_gst_debug = get_option('disable_gst_debug')
 312 if get_option('disable_gst_debug')
 313     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
 314   add_project_arguments(['-Wno-unused'], language: 'c')
 315 endif
 316
 317 # Used by the gstutils test
 318 gmp_dep = cc.find_library('gmp', required : false)
 319 cdata.set('HAVE_GMP', gmp_dep.found())
 320 gsl_dep = cc.find_library('gsl', required : false)
 321 gslcblas_dep = cc.find_library('gslcblas', required : false)
 322 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 323 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 324
 325 # Used by gstinfo.c
 326 dl_dep = cc.find_library('dl', required : false)
 327 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 328
 329 configure_file(input : 'config.h.meson',
 330   output : 'config.h',
 331   configuration : cdata)
 332
 333
 334 configinc = include_directories('.')
 335 libsinc = include_directories('libs')
 336 privinc = include_directories('gst')
 337
 338 # Find dependencies
 339 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
 340 gobject_dep = dependency('gobject-2.0')
 341 gmodule_dep = dependency('gmodule-2.0')
 342 if host_machine.system() == 'windows'
 343     gio_dep = dependency('gio-2.0')
 344 else
 345     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
 346 endif
 347
 348 mathlib = cc.find_library('m', required : false)
 349 # Needed for timer_create/settime/delete
 350 # Also provides clock_gettime in glibc < 2.17
 351 rt_lib = cc.find_library('rt', required : false)
 352
 353 gir = find_program('g-ir-scanner', required : false)
 354 gnome = import('gnome')
 355
 356 # Fixme, not very elegant.
 357 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 358
 359 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 360     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 361     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 362     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 363     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 364     'gst_init(NULL,NULL);' ]
 365 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 366
 367 # Used by the *_mkenum.py helper scripts
 368 glib_mkenums = find_program('glib-mkenums')
 369
 370 gst_c_args = ['-DHAVE_CONFIG_H']
 371 if libtype == 'static'
 372   gst_c_args += ['-DGST_STATIC_COMPILATION']
 373 endif
 374
 375 # Used in gst/parse/meson.build and below
 376 py3 = find_program('python3', required : false)
 377 if not py3.found()
 378   # Maybe 'python' is Python 3
 379   py3 = find_program('python')
 380 endif
 381
 382 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 383
 384 bashcomp_found = bashcomp_dep.found()
 385 bash_completions_dir = ''
 386 bash_helpers_dir = ''
 387
 388 if bashcomp_found
 389   # get_pkgconfig_variable() won't let us set the prefix
 390   pkgconfig = find_program('pkg-config')
 391
 392   runcmd = run_command(pkgconfig,
 393       '--define-variable=prefix="."',
 394       '--variable=completionsdir',
 395       'bash-completion')
 396
 397   if (runcmd.returncode() == 0)
 398     bash_completions_dir = runcmd.stdout().strip()
 399   else
 400     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 401     bashcomp_found = false
 402   endif
 403
 404   runcmd = run_command(pkgconfig,
 405       '--define-variable=prefix="."',
 406       '--variable=helpersdir',
 407       'bash-completion')
 408
 409   if (runcmd.returncode() == 0)
 410     bash_helpers_dir = runcmd.stdout().strip()
 411   else
 412     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 413     bashcomp_found = false
 414   endif
 415 endif
 416
 417 subdir('gst')
 418 subdir('libs')
 419 subdir('plugins')
 420 subdir('tools')
 421 subdir('pkgconfig')
 422 subdir('tests')
 423 subdir('po')
 424 subdir('data')
 425
 426 if build_machine.system() == 'windows'
 427   message('Disabling gtk-doc while building on Windows')
 428 elif get_option('disable_gtkdoc')
 429   message('gtk-doc is disabled via options')
 430 else
 431   if find_program('gtkdoc-scan', required : false).found()
 432     subdir('docs')
 433   else
 434     message('Not building documentation as gtk-doc was not found')
 435   endif
 436 endif
 437
 438 run_command(py3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 439
 440 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))