meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.19.0.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 api_version = '1.0'
  19 libavfilter_dep = dependency('libavfilter', version: '>= 7.16.100',
  20   fallback: ['FFmpeg', 'libavfilter_dep'])
  21 libavformat_dep = dependency('libavformat', version: '>= 58.12.100',
  22   fallback: ['FFmpeg', 'libavformat_dep'])
  23 libavcodec_dep = dependency('libavcodec', version: '>= 58.18.100',
  24   fallback: ['FFmpeg', 'libavcodec_dep'])
  25 libavutil_dep = dependency('libavutil', version: '>= 56.14.100',
  26   fallback: ['FFmpeg', 'libavutil_dep'])
  27
  28 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  29
  30 cc = meson.get_compiler('c')
  31
  32 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  33 #if LIBAVCODEC_VERSION_MICRO >= 100
  34 /* FFmpeg uses 100+ as its micro version */
  35 #else
  36 #error libav provider should be FFmpeg
  37 #endif'''
  38
  39 libav_deps_type_name = ''
  40
  41 foreach dep: libav_deps
  42   if libav_deps_type_name != '' and dep.type_name() != libav_deps_type_name
  43     error('Libav deps must be either all internal or all external')
  44   endif
  45   libav_deps_type_name = dep.type_name()
  46 endforeach
  47
  48 if dep.type_name() != 'internal'
  49   if not cc.compiles(check_ffmpeg_src, dependencies : libav_deps, name : 'libav is provided by FFmpeg')
  50     error('Uncompatible libavcodec found')
  51   endif
  52 endif
  53
  54 cdata = configuration_data()
  55 cdata.set('LIBAV_SOURCE', '"system install"')
  56 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  57 cdata.set('PACKAGE', '"gst-libav"')
  58
  59 # GStreamer package name and origin url
  60 gst_package_name = get_option('package-name')
  61 if gst_package_name == ''
  62   if gst_version_nano == 0
  63     gst_package_name = 'GStreamer FFMPEG Plug-ins source release'
  64   elif gst_version_nano == 1
  65     gst_package_name = 'GStreamer FFMPEG Plug-ins git'
  66   else
  67     gst_package_name = 'GStreamer FFMPEG Plug-ins prerelease'
  68   endif
  69 endif
  70 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  71 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
  72
  73
  74 check_headers = [['unistd.h', 'HAVE_UNISTD_H']]
  75
  76 foreach h : check_headers
  77   if cc.has_header(h.get(0))
  78     cdata.set(h.get(1), 1)
  79   endif
  80 endforeach
  81
  82 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  83 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  84   fallback : ['gstreamer', 'gst_dep'])
  85 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  86   fallback : ['gstreamer', 'gst_base_dep'])
  87 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  88   required : get_option('tests'),
  89   fallback : ['gstreamer', 'gst_check_dep'])
  90
  91 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  92     fallback : ['gst-plugins-base', 'video_dep'])
  93 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
  94     fallback : ['gst-plugins-base', 'audio_dep'])
  95 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  96     fallback : ['gst-plugins-base', 'pbutils_dep'])
  97 libm = cc.find_library('m', required : false)
  98
  99 gst_libav_args = ['-DHAVE_CONFIG_H']
 100 if cc.get_id() == 'msvc'
 101   # Ignore several spurious warnings for things gstreamer does very commonly
 102   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
 103   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
 104   # NOTE: Only add warnings here if you are sure they're spurious
 105   add_project_arguments(
 106       '/wd4018', # implicit signed/unsigned conversion
 107       '/wd4146', # unary minus on unsigned (beware INT_MIN)
 108       '/wd4244', # lossy type conversion (e.g. double -> int)
 109       '/wd4305', # truncating type conversion (e.g. double -> float)
 110       language : 'c')
 111 endif
 112
 113 # Symbol visibility
 114 if cc.has_argument('-fvisibility=hidden')
 115   add_project_arguments('-fvisibility=hidden', language: 'c')
 116 endif
 117
 118 # Don't export any symbols from static ffmpeg libraries
 119 if cc.has_link_argument('-Wl,--exclude-libs=ALL')
 120   add_project_link_arguments('-Wl,--exclude-libs=ALL', language: 'c')
 121 endif
 122
 123 # Disable strict aliasing
 124 if cc.has_argument('-fno-strict-aliasing')
 125   add_project_arguments('-fno-strict-aliasing', language: 'c')
 126 endif
 127
 128 if gst_dep.type_name() == 'internal'
 129     gst_proj = subproject('gstreamer')
 130
 131     if not gst_proj.get_variable('gst_debug')
 132         message('GStreamer debug system is disabled')
 133         add_project_arguments('-Wno-unused', language: 'c')
 134     else
 135         message('GStreamer debug system is enabled')
 136     endif
 137 else
 138     # We can't check that in the case of subprojects as we won't
 139     # be able to build against an internal dependency (which is not built yet)
 140     if not cc.compiles('''
 141 #include <gst/gstconfig.h>
 142 #ifdef GST_DISABLE_GST_DEBUG
 143 #error "debugging disabled, make compiler fail"
 144 #endif''' , dependencies: gst_dep)
 145         message('GStreamer debug system is disabled')
 146         add_project_arguments('-Wno-unused', language: 'c')
 147     else
 148         message('GStreamer debug system is enabled')
 149     endif
 150 endif
 151
 152 warning_flags = [
 153   '-Wmissing-declarations',
 154   '-Wmissing-prototypes',
 155   '-Wold-style-definition',
 156   '-Wredundant-decls',
 157   '-Wundef',
 158   '-Wwrite-strings',
 159   '-Wformat',
 160   '-Wformat-nonliteral',
 161   '-Wformat-security',
 162   '-Winit-self',
 163   '-Wmissing-include-dirs',
 164   '-Waddress',
 165   '-Wno-multichar',
 166   '-Waggregate-return',
 167   '-Wdeclaration-after-statement',
 168   '-Wvla',
 169   '-Wpointer-arith',
 170 ]
 171
 172 foreach extra_arg : warning_flags
 173   if cc.has_argument (extra_arg)
 174     add_project_arguments([extra_arg], language: 'c')
 175   endif
 176 endforeach
 177
 178 configinc = include_directories('.')
 179 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 180
 181 pkgconfig = import('pkgconfig')
 182 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 183 if get_option('default_library') == 'shared'
 184   # If we don't build static plugins there is no need to generate pc files
 185   plugins_pkgconfig_install_dir = disabler()
 186 endif
 187
 188 plugins = []
 189 subdir('ext/libav')
 190 subdir('docs')
 191 subdir('tests')
 192
 193 # Set release date
 194 if gst_version_nano == 0
 195   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 196   run_result = run_command(extract_release_date, gst_version, files('gst-libav.doap'))
 197   if run_result.returncode() == 0
 198     release_date = run_result.stdout().strip()
 199     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 200     message('Package release date: ' + release_date)
 201   else
 202     # Error out if our release can't be found in the .doap file
 203     error(run_result.stderr())
 204   endif
 205 endif
 206
 207 configure_file(output: 'config.h', configuration: cdata)
 208
 209 python3 = import('python').find_installation()
 210 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')