meson.build

   1 project('gst-plugins-bad', 'c', 'cpp',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 api_version = '1.0'
  23 soversion = 0
  24 # maintaining compatibility with the previous libtool versioning
  25 # current = minor * 100 + micro
  26 curversion = gst_version_minor * 100 + gst_version_micro
  27 libversion = '@0@.@1@.0'.format(soversion, curversion)
  28 osxversion = curversion + 1
  29
  30 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  31
  32 cc = meson.get_compiler('c')
  33 cxx = meson.get_compiler('cpp')
  34
  35 if cc.get_id() == 'msvc'
  36   # Ignore several spurious warnings for things gstreamer does very commonly
  37   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39   # NOTE: Only add warnings here if you are sure they're spurious
  40   msvc_args = [
  41       '/wd4018', # implicit signed/unsigned conversion
  42       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  43       '/wd4244', # lossy type conversion (e.g. double -> int)
  44       '/wd4305', # truncating type conversion (e.g. double -> float)
  45   ]
  46   add_project_arguments(msvc_args, language : 'c')
  47   add_project_arguments(msvc_args, language : 'cpp')
  48   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  49   # are built with MinGW
  50   noseh_link_args = ['/SAFESEH:NO']
  51 else
  52   if cxx.has_argument('-Wno-non-virtual-dtor')
  53     add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  54   endif
  55
  56   noseh_link_args = []
  57 endif
  58
  59 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  60   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  61 endif
  62
  63 # Symbol visibility
  64 if cc.has_argument('-fvisibility=hidden')
  65   add_project_arguments('-fvisibility=hidden', language: 'c')
  66 endif
  67 if cxx.has_argument('-fvisibility=hidden')
  68   add_project_arguments('-fvisibility=hidden', language: 'cpp')
  69 endif
  70
  71 # Disable strict aliasing
  72 if cc.has_argument('-fno-strict-aliasing')
  73   add_project_arguments('-fno-strict-aliasing', language: 'c')
  74 endif
  75 if cxx.has_argument('-fno-strict-aliasing')
  76   add_project_arguments('-fno-strict-aliasing', language: 'cpp')
  77 endif
  78
  79 # Define G_DISABLE_DEPRECATED for development versions
  80 if gst_version_is_dev
  81   message('Disabling deprecated GLib API')
  82   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  83 endif
  84
  85 cast_checks = get_option('gobject-cast-checks')
  86 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  87   message('Disabling GLib cast checks')
  88   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  89 endif
  90
  91 glib_asserts = get_option('glib-asserts')
  92 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  93   message('Disabling GLib asserts')
  94   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  95 endif
  96
  97 glib_checks = get_option('glib-checks')
  98 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  99   message('Disabling GLib checks')
 100   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 101 endif
 102
 103 cdata = configuration_data()
 104 check_headers = [
 105   ['HAVE_DLFCN_H', 'dlfcn.h'],
 106   ['HAVE_FCNTL_H', 'fcntl.h'],
 107   ['HAVE_INTTYPES_H', 'inttypes.h'],
 108   ['HAVE_MEMORY_H', 'memory.h'],
 109   ['HAVE_MSACM_H', 'msacm.h'],
 110   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 111   ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
 112   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 113   ['HAVE_PTHREAD_H', 'pthread.h'],
 114   ['HAVE_STDINT_H', 'stdint.h'],
 115   ['HAVE_STDLIB_H', 'stdlib.h'],
 116   ['HAVE_STRINGS_H', 'strings.h'],
 117   ['HAVE_STRING_H', 'string.h'],
 118   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 119   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 120   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 121   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 122   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 123   ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
 124   ['HAVE_UNISTD_H', 'unistd.h'],
 125   ['HAVE_WINDOWS_H', 'windows.h'],
 126   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 127   ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
 128 ]
 129
 130 foreach h : check_headers
 131   if cc.has_header(h.get(1))
 132     cdata.set(h.get(0), 1)
 133   endif
 134 endforeach
 135
 136 check_functions = [
 137 # check token HAVE_ACM
 138 # check token HAVE_ANDROID_MEDIA
 139 # check token HAVE_APEXSINK
 140 # check token HAVE_APPLE_MEDIA
 141 # check token HAVE_ASSRENDER
 142 # check token HAVE_AVC
 143 # check token HAVE_BLUEZ
 144 # check token HAVE_BZ2
 145 # check token HAVE_CFLOCALECOPYCURRENT
 146 # check token HAVE_CFPREFERENCESCOPYAPPVALUE
 147 # check token HAVE_CHROMAPRINT
 148 # check token HAVE_CPU_ALPHA
 149 # check token HAVE_CPU_ARM
 150 # check token HAVE_CPU_CRIS
 151 # check token HAVE_CPU_CRISV32
 152 # check token HAVE_CPU_HPPA
 153 # check token HAVE_CPU_I386
 154 # check token HAVE_CPU_IA64
 155 # check token HAVE_CPU_M68K
 156 # check token HAVE_CPU_MIPS
 157 # check token HAVE_CPU_PPC
 158 # check token HAVE_CPU_PPC64
 159 # check token HAVE_CPU_S390
 160 # check token HAVE_CPU_SPARC
 161 # check token HAVE_CPU_X86_64
 162 # check token HAVE_CURL
 163 # check token HAVE_DAALA
 164 # check token HAVE_DASH
 165 # check token HAVE_DC1394
 166   ['HAVE_DCGETTEXT', 'dcgettext'],
 167 # check token HAVE_DECKLINK
 168 # check token HAVE_DIRECT3D
 169 # check token HAVE_DIRECTDRAW
 170 # check token HAVE_DIRECTFB
 171 # check token HAVE_DIRECTSOUND
 172 # check token HAVE_DOWHILE_MACROS
 173 # check token HAVE_DTS
 174 # check token HAVE_DVB
 175 # check token HAVE_EXPERIMENTAL
 176 # check token HAVE_EXTERNAL
 177 # check token HAVE_FAAC
 178 # check token HAVE_FAAD
 179 # check token HAVE_FBDEV
 180 # check token HAVE_FLITE
 181 # check token HAVE_FLUIDSYNTH
 182   ['HAVE_GETPAGESIZE', 'getpagesize'],
 183 # check token HAVE_GETTEXT
 184 # check token HAVE_GL
 185 # check token HAVE_GLCHAR
 186 # check token HAVE_GLEGLIMAGEOES
 187 # check token HAVE_GLINTPTR
 188 # check token HAVE_GLSIZEIPTR
 189 # check token HAVE_GME
 190   ['HAVE_GMTIME_R', 'gmtime_r'],
 191 # check token HAVE_GRAPHENE
 192 # check token HAVE_GSETTINGS
 193 # check token HAVE_GSM
 194 # check token HAVE_GUDEV
 195 # check token HAVE_HLS
 196 # check token HAVE_ICONV
 197 # check token HAVE_JPEG
 198 # check token HAVE_KATE
 199 # check token HAVE_LADSPA
 200 # check token HAVE_LIBGCRYPT
 201 # check token HAVE_LIBGME_ACCURACY
 202 # check token HAVE_LIBMMS
 203 # check token HAVE_LIBNSL
 204 # check token HAVE_LIBSOCKET
 205 # check token HAVE_LIBUSB
 206 # check token HAVE_LIBVISUAL
 207 # check token HAVE_LINSYS
 208 # check token HAVE_LRDF
 209 # check token HAVE_LV2
 210 # check token HAVE_MIMIC
 211   ['HAVE_MMAP', 'mmap'],
 212 # check token HAVE_MODPLUG
 213 # check token HAVE_MPEG2ENC
 214 # check token HAVE_MPG123
 215 # check token HAVE_MPLEX
 216 # check token HAVE_MUSEPACK
 217 # check token HAVE_MYTHTV
 218 # check token HAVE_NAS
 219 # check token HAVE_NEON
 220 # check token HAVE_NETTLE
 221 # check token HAVE_OFA
 222 # check token HAVE_OPENAL
 223 # check token HAVE_OPENCV
 224 # check token HAVE_OPENEXR
 225 # check token HAVE_OPENJPEG
 226 # check token HAVE_OPENJPEG_1
 227 # check token HAVE_OPENNI2
 228 # check token HAVE_OPENSLES
 229 # check token HAVE_OPUS
 230 # check token HAVE_ORC
 231 # check token HAVE_OSX_VIDEO
 232   ['HAVE_PIPE2', 'pipe2'],
 233 # check token HAVE_PNG
 234 # check token HAVE_PVR
 235 # check token HAVE_QUICKTIME
 236 # check token HAVE_RDTSC
 237 # check token HAVE_RESINDVD
 238 # check token HAVE_RSVG
 239 # check token HAVE_RSVG_2_36_2
 240 # check token HAVE_RTMP
 241 # check token HAVE_SBC
 242 # check token HAVE_SDL
 243 # check token HAVE_SHM
 244 # check token HAVE_SMOOTHSTREAMING
 245 # check token HAVE_SNDFILE
 246 # check token HAVE_SNDIO
 247 # check token HAVE_SOUNDTOUCH
 248 # check token HAVE_SOUNDTOUCH_1_4
 249 # check token HAVE_SPANDSP
 250 # check token HAVE_SPC
 251 # check token HAVE_SRTP
 252 # check token HAVE_SSH2
 253 # check token HAVE_TELETEXTDEC
 254 # check token HAVE_TIGER
 255 # check token HAVE_TIMIDITY
 256 # check token HAVE_UVCH264
 257 # check token HAVE_VALGRIND
 258 # check token HAVE_VCD
 259 # check token HAVE_VDPAU
 260 # check token HAVE_VIDEOTOOLBOX
 261 # check token HAVE_VOAACENC
 262 # check token HAVE_VOAMRWBENC
 263 # check token HAVE_WASAPI
 264 # check token HAVE_WAYLAND
 265 # check token HAVE_WEBP
 266 # check token HAVE_WILDMIDI
 267 # check token HAVE_WIN32
 268 # check token HAVE_WININET
 269 # check token HAVE_WINKS
 270 # check token HAVE_WINSCREENCAP
 271 # check token HAVE_XVID
 272 # check token HAVE_ZBAR
 273 ]
 274
 275 foreach f : check_functions
 276   if cc.has_function(f.get(1))
 277     cdata.set(f.get(0), 1)
 278   endif
 279 endforeach
 280
 281 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 282 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 283 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 284 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 285 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 286
 287 cdata.set_quoted('VERSION', gst_version)
 288 cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
 289 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 290 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 291 cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
 292 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
 293 cdata.set_quoted('GST_API_VERSION', api_version)
 294 cdata.set_quoted('GST_LICENSE', 'LGPL')
 295 cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
 296 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 297
 298 warning_flags = [
 299   '-Wmissing-declarations',
 300   '-Wredundant-decls',
 301   '-Wwrite-strings',
 302   '-Wformat',
 303   '-Wformat-security',
 304   '-Winit-self',
 305   '-Wmissing-include-dirs',
 306   '-Waddress',
 307   '-Wno-multichar',
 308   '-Wvla',
 309   '-Wpointer-arith',
 310 ]
 311
 312 warning_c_flags = [
 313   '-Wmissing-prototypes',
 314   '-Wdeclaration-after-statement',
 315   '-Wold-style-definition',
 316   '-Wnested-externs',
 317 ]
 318
 319 warning_cxx_flags = [
 320   '-Wformat-nonliteral',
 321 ]
 322
 323 foreach extra_arg : warning_c_flags
 324   if cc.has_argument (extra_arg)
 325     add_project_arguments([extra_arg], language: 'c')
 326   endif
 327 endforeach
 328
 329 foreach extra_arg : warning_cxx_flags
 330   if cxx.has_argument (extra_arg)
 331     add_project_arguments([extra_arg], language: 'cpp')
 332   endif
 333 endforeach
 334
 335 foreach extra_arg : warning_flags
 336   if cc.has_argument (extra_arg)
 337     add_project_arguments([extra_arg], language: 'c')
 338   endif
 339   if cxx.has_argument (extra_arg)
 340     add_project_arguments([extra_arg], language: 'cpp')
 341   endif
 342 endforeach
 343
 344 # GStreamer package name and origin url
 345 gst_package_name = get_option('package-name')
 346 if gst_package_name == ''
 347   if gst_version_nano == 0
 348     gst_package_name = 'GStreamer Bad Plug-ins source release'
 349   elif gst_version_nano == 1
 350     gst_package_name = 'GStreamer Bad Plug-ins git'
 351   else
 352     gst_package_name = 'GStreamer Bad Plug-ins prerelease'
 353   endif
 354 endif
 355 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 356 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 357
 358 # FIXME: This should be exposed as a configuration option
 359 host_system = host_machine.system()
 360 if host_system == 'linux'
 361   cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
 362 elif ['darwin', 'ios'].contains(host_system)
 363   cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
 364   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 365   # Yes, we set this for iOS too. Same as Autotools.
 366   cdata.set('HAVE_OSX', 1)
 367 else
 368   cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
 369 endif
 370
 371 # Mandatory GST deps
 372 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 373   fallback : ['gstreamer', 'gst_dep'])
 374 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 375   fallback : ['gstreamer', 'gst_base_dep'])
 376 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 377   fallback : ['gstreamer', 'gst_net_dep'])
 378 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 379   fallback : ['gstreamer', 'gst_controller_dep'])
 380
 381 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 382     fallback : ['gst-plugins-base', 'pbutils_dep'])
 383 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 384     fallback : ['gst-plugins-base', 'allocators_dep'])
 385 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 386     fallback : ['gst-plugins-base', 'app_dep'])
 387 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 388     fallback : ['gst-plugins-base', 'audio_dep'])
 389 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 390     fallback : ['gst-plugins-base', 'fft_dep'])
 391 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 392     fallback : ['gst-plugins-base', 'riff_dep'])
 393 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 394     fallback : ['gst-plugins-base', 'rtp_dep'])
 395 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 396     fallback : ['gst-plugins-base', 'rtsp_dep'])
 397 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 398     fallback : ['gst-plugins-base', 'sdp_dep'])
 399 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 400     fallback : ['gst-plugins-base', 'tag_dep'])
 401 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 402     fallback : ['gst-plugins-base', 'video_dep'])
 403 if host_machine.system() != 'windows'
 404   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 405     required : get_option('tests'),
 406     fallback : ['gstreamer', 'gst_check_dep'])
 407 endif
 408
 409 # GStreamer OpenGL
 410 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 411     fallback : ['gst-plugins-base', 'gstgl_dep'], required: get_option('gl'))
 412
 413 if gstgl_dep.found()
 414   if gstgl_dep.type_name() == 'pkgconfig'
 415     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 416     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 417     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 418   else
 419     gstbase = subproject('gst-plugins-base')
 420     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 421     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 422     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 423   endif
 424
 425   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 426   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 427   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 428
 429   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 430     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 431   endforeach
 432
 433   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 434     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 435   endforeach
 436
 437   foreach api : ['opengl', 'gles2']
 438     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 439   endforeach
 440 endif
 441
 442 libm = cc.find_library('m', required : false)
 443 glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
 444 gmodule_dep = dependency('gmodule-2.0', fallback: ['glib', 'libgmodule_dep'])
 445 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 446 # gio-unix-2.0 is used by sys/bluez
 447
 448 # Optional dep of ext/gl and gst/librfb
 449 x11_dep = dependency('x11', required : get_option('x11'))
 450 if x11_dep.found()
 451   cdata.set('HAVE_X11', 1)
 452 endif
 453
 454 if host_machine.system() == 'windows'
 455   winsock2 = [cc.find_library('ws2_32')]
 456 else
 457   winsock2 = []
 458 endif
 459
 460 if ['darwin', 'ios'].contains(host_system)
 461   add_languages('objc')
 462   if host_system == 'ios'
 463     cdata.set('HAVE_IOS', 1)
 464   endif
 465
 466   avfoundation_dep = dependency('AVFoundation', required : false)
 467   if avfoundation_dep.found()
 468       cdata.set('HAVE_AVFOUNDATION', 1)
 469   endif
 470
 471   videotoolbox_dep = dependency('VideoToolbox', required : false)
 472   if videotoolbox_dep.found()
 473       cdata.set('HAVE_VIDEOTOOLBOX', 1)
 474   endif
 475
 476 #  FIXME: framework.version() returns 'unknown'
 477 #  if videotoolbox_dep.version().version_compare('>=10.9.6')
 478 #    cdata.set('HAVE_VIDEOTOOLBOX_10_9_6', 1)
 479 #  endif
 480 endif
 481
 482 have_orcc = false
 483 orcc_args = []
 484 # Used by various libraries/elements that use Orc code
 485 orc_dep = dependency('orc-0.4', required : get_option('orc'))
 486 orcc = find_program('orcc', required : get_option('orc'))
 487 if orc_dep.found() and orcc.found()
 488   have_orcc = true
 489   orcc_args = [orcc, '--include', 'glib.h']
 490   cdata.set('HAVE_ORC', 1)
 491 else
 492   message('Orc Compiler not found or disabled, will use backup C code')
 493   cdata.set('DISABLE_ORC', 1)
 494 endif
 495
 496 if gst_dep.type_name() == 'internal'
 497   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 498 else
 499   # We can't check that in the case of subprojects as we won't
 500   # be able to build against an internal dependency (which is not built yet)
 501   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 502 endif
 503
 504 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 505   add_project_arguments('-Wno-unused', language: 'c')
 506 endif
 507
 508 gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
 509 configinc = include_directories('.')
 510 libsinc = include_directories('gst-libs')
 511
 512 python3 = import('python3').find_python()
 513
 514 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 515 gnome = import('gnome')
 516 build_gir = gir.found() and not meson.is_cross_build()
 517 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 518     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 519     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 520     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 521     'gst_init(NULL,NULL);' ]
 522
 523 pkgconfig = import('pkgconfig')
 524 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 525 if get_option('default_library') == 'shared'
 526   # If we don't build static plugins there is no need to generate pc files
 527   plugins_pkgconfig_install_dir = disabler()
 528 endif
 529
 530 subdir('gst-libs')
 531 subdir('gst')
 532 subdir('sys')
 533 subdir('ext')
 534 subdir('tests')
 535 subdir('pkgconfig')
 536
 537 # xgettext is optional (on Windows for instance)
 538 if find_program('xgettext', required : get_option('nls')).found()
 539   cdata.set('ENABLE_NLS', 1)
 540   subdir('po')
 541 endif
 542
 543 configure_file(output : 'config.h', configuration : cdata)
 544
 545 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')