meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', required : false)
  20 have_objc = add_languages('objc', required : false)
  21
  22 glib_req = '>= 2.40.0'
  23 orc_req = '>= 0.4.24'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27 soversion = 0
  28 # maintaining compatibility with the previous libtool versioning
  29 # current = minor * 100 + micro
  30 curversion = gst_version_minor * 100 + gst_version_micro
  31 libversion = '@0@.@1@.0'.format(soversion, curversion)
  32 osxversion = curversion + 1
  33
  34 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  35 plugins = []
  36
  37 cc = meson.get_compiler('c')
  38 host_system = host_machine.system()
  39
  40 if cc.get_id() == 'msvc'
  41   # Ignore several spurious warnings for things gstreamer does very commonly
  42   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44   # NOTE: Only add warnings here if you are sure they're spurious
  45   add_project_arguments(
  46       '/wd4018', # implicit signed/unsigned conversion
  47       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  48       '/wd4244', # lossy type conversion (e.g. double -> int)
  49       '/wd4305', # truncating type conversion (e.g. double -> float)
  50       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  51       language : 'c')
  52   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  53   # are built with MinGW
  54   noseh_link_args = ['/SAFESEH:NO']
  55 else
  56   noseh_link_args = []
  57 endif
  58
  59 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  60   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  61 endif
  62
  63 core_conf = configuration_data()
  64
  65 # Symbol visibility
  66 if cc.get_id() == 'msvc'
  67   export_define = '__declspec(dllexport) extern'
  68 elif cc.has_argument('-fvisibility=hidden')
  69   add_project_arguments('-fvisibility=hidden', language: 'c')
  70   export_define = 'extern __attribute__ ((visibility ("default")))'
  71 else
  72   export_define = 'extern'
  73 endif
  74
  75 # Passing this through the command line would be too messy
  76 core_conf.set('GST_API_EXPORT', export_define)
  77
  78 # Disable strict aliasing
  79 if cc.has_argument('-fno-strict-aliasing')
  80   add_project_arguments('-fno-strict-aliasing', language: 'c')
  81 endif
  82
  83 # Define G_DISABLE_DEPRECATED for development versions
  84 if gst_version_is_dev
  85   message('Disabling deprecated GLib API')
  86   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  87 endif
  88
  89 cast_checks = get_option('gobject-cast-checks')
  90 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  91   message('Disabling GLib cast checks')
  92   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  93 endif
  94
  95 glib_asserts = get_option('glib-asserts')
  96 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  97   message('Disabling GLib asserts')
  98   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  99 endif
 100
 101 glib_checks = get_option('glib-checks')
 102 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 103   message('Disabling GLib checks')
 104   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 105 endif
 106
 107 check_headers = [
 108   ['HAVE_DLFCN_H', 'dlfcn.h'],
 109   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 110   ['HAVE_INTTYPES_H', 'inttypes.h'],
 111   ['HAVE_MEMORY_H', 'memory.h'],
 112   ['HAVE_PROCESS_H', 'process.h'],
 113   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 114   ['HAVE_STDINT_H', 'stdint.h'],
 115   ['HAVE_STDLIB_H', 'stdlib.h'],
 116   ['HAVE_STRINGS_H', 'strings.h'],
 117   ['HAVE_STRING_H', 'string.h'],
 118   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 119   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 120   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 121   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 122   ['HAVE_UNISTD_H', 'unistd.h'],
 123   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 124   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 125   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 126 ]
 127 foreach h : check_headers
 128   if cc.has_header(h.get(1))
 129     core_conf.set(h.get(0), 1)
 130   endif
 131 endforeach
 132
 133 check_functions = [
 134   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 135   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 136   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 137   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 138   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 139 ]
 140
 141 libm = cc.find_library('m', required : false)
 142 foreach f : check_functions
 143   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 144     core_conf.set(f.get(0), 1)
 145   endif
 146 endforeach
 147
 148 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 149 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 150 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 151 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 152 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 153
 154 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 155 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 156 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 157 core_conf.set_quoted('VERSION', gst_version)
 158 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 159 core_conf.set_quoted('GST_API_VERSION', api_version)
 160 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 161 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 162
 163 install_plugins_helper = get_option('install_plugins_helper')
 164 if install_plugins_helper == ''
 165   install_plugins_helper = join_paths(get_option('prefix'),
 166                                       get_option('libexecdir'),
 167                                       'gst-install-plugins-helper')
 168 endif
 169 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 170
 171 warning_flags = [
 172   '-Wmissing-declarations',
 173   '-Wredundant-decls',
 174   '-Wundef',
 175   '-Wwrite-strings',
 176   '-Wformat',
 177   '-Wformat-nonliteral',
 178   '-Wformat-security',
 179   '-Winit-self',
 180   '-Wmissing-include-dirs',
 181   '-Waddress',
 182   '-Wno-multichar',
 183   '-Wvla',
 184   '-Wpointer-arith',
 185 ]
 186
 187 warning_c_flags = [
 188   '-Wmissing-prototypes',
 189   '-Wdeclaration-after-statement',
 190 ]
 191
 192 warning_cxx_flags = [
 193   '-Waggregate-return',
 194 ]
 195
 196 if have_cxx
 197   cxx = meson.get_compiler('cpp')
 198   foreach extra_arg : warning_cxx_flags
 199     if cxx.has_argument (extra_arg)
 200       add_project_arguments([extra_arg], language: 'cpp')
 201     endif
 202   endforeach
 203 endif
 204
 205 foreach extra_arg : warning_flags
 206   if cc.has_argument (extra_arg)
 207     add_project_arguments([extra_arg], language: 'c')
 208   endif
 209   if have_cxx and cxx.has_argument (extra_arg)
 210     add_project_arguments([extra_arg], language: 'cpp')
 211   endif
 212 endforeach
 213
 214 foreach extra_arg : warning_c_flags
 215   if cc.has_argument (extra_arg)
 216     add_project_arguments([extra_arg], language: 'c')
 217   endif
 218 endforeach
 219
 220 # GStreamer package name and origin url
 221 gst_package_name = get_option('package-name')
 222 if gst_package_name == ''
 223   if gst_version_nano == 0
 224     gst_package_name = 'GStreamer Base Plug-ins source release'
 225   elif gst_version_nano == 1
 226     gst_package_name = 'GStreamer Base Plug-ins git'
 227   else
 228     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 229   endif
 230 endif
 231 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 232 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 233
 234 # FIXME: These should be configure options
 235 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 236 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 237
 238 # Set whether the audioresampling method should be detected at runtime
 239 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 240
 241 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 242 if get_option('default_library') == 'static'
 243   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 244 endif
 245
 246 # X11 checks are for sys/ and tests/
 247 x11_dep = dependency('x11', required : get_option('x11'))
 248 # GLib checks are for the entire project
 249 # Almost everything that uses glib also uses gobject
 250 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 251              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 252 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 253 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 254 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : host_system != 'windows',
 255                          fallback: ['glib', 'libgiounix_dep'])
 256 gmodule_dep = dependency('gmodule-no-export-2.0',
 257                          fallback: ['glib', 'libgmodule_dep'])
 258
 259 # some of the examples can use gdk-pixbuf and GTK+3
 260 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 261 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 262 # TODO: https://github.com/mesonbuild/meson/issues/3941
 263 if not get_option('x11').disabled()
 264   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 265 else
 266   gtk_x11_dep = dependency('', required : false)
 267 endif
 268 # gtk+ quartz backend is only available on macOS
 269 if host_system == 'darwin'
 270   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 271 else
 272   gtk_quartz_dep = dependency('', required : false)
 273 endif
 274
 275 core_conf.set('HAVE_X', x11_dep.found())
 276 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 277
 278 if gio_dep.type_name() == 'pkgconfig'
 279     core_conf.set_quoted('GIO_MODULE_DIR',
 280         gio_dep.get_pkgconfig_variable('giomoduledir'))
 281     core_conf.set_quoted('GIO_LIBDIR',
 282         gio_dep.get_pkgconfig_variable('libdir'))
 283     core_conf.set_quoted('GIO_PREFIX',
 284         gio_dep.get_pkgconfig_variable('prefix'))
 285 else
 286     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 287       get_option('libdir'), 'gio/modules'))
 288     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 289       get_option('libdir')))
 290     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 291 endif
 292
 293 configinc = include_directories('.')
 294 libsinc = include_directories('gst-libs')
 295
 296 # To use the subproject make subprojects directory
 297 # and put gstreamer meson git there (symlinking is fine)
 298 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 299   fallback : ['gstreamer', 'gst_dep'])
 300 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 301   fallback : ['gstreamer', 'gst_base_dep'])
 302 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 303   fallback : ['gstreamer', 'gst_net_dep'])
 304 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 305   required : get_option('tests'),
 306   fallback : ['gstreamer', 'gst_check_dep'])
 307 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 308   fallback : ['gstreamer', 'gst_controller_dep'])
 309
 310 have_orcc = false
 311 orcc_args = []
 312 # Used by various libraries/elements that use Orc code
 313 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 314     fallback : ['orc', 'orc_dep'])
 315 orcc = find_program('orcc', required : get_option('orc'))
 316 if orc_dep.found() and orcc.found()
 317   have_orcc = true
 318   orcc_args = [orcc, '--include', 'glib.h']
 319   core_conf.set('HAVE_ORC', 1)
 320 else
 321   message('Orc Compiler not found or disabled, will use backup C code')
 322   core_conf.set('DISABLE_ORC', 1)
 323 endif
 324
 325 # Used to build SSE* things in audio-resampler
 326 sse_args = '-msse'
 327 sse2_args = '-msse2'
 328 sse41_args = '-msse4.1'
 329
 330 have_sse = cc.has_argument(sse_args)
 331 have_sse2 = cc.has_argument(sse2_args)
 332 have_sse41 = cc.has_argument(sse41_args)
 333
 334 if gst_dep.type_name() == 'internal'
 335     gst_proj = subproject('gstreamer')
 336
 337     if not gst_proj.get_variable('gst_debug')
 338         message('GStreamer debug system is disabled')
 339         add_project_arguments('-Wno-unused', language: 'c')
 340     else
 341         message('GStreamer debug system is enabled')
 342     endif
 343 else
 344     # We can't check that in the case of subprojects as we won't
 345     # be able to build against an internal dependency (which is not built yet)
 346     if not cc.compiles('''
 347 #include <gst/gstconfig.h>
 348 #ifdef GST_DISABLE_GST_DEBUG
 349 #error "debugging disabled, make compiler fail"
 350 #endif''' , dependencies: gst_dep)
 351         message('GStreamer debug system is disabled')
 352         add_project_arguments('-Wno-unused', language: 'c')
 353     else
 354         message('GStreamer debug system is enabled')
 355     endif
 356 endif
 357
 358 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 359 gnome = import('gnome')
 360 build_gir = gir.found() and not meson.is_cross_build()
 361 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 362     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 363     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 364     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 365     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 366     'gst_init(NULL,NULL);', '--quiet']
 367
 368 pkgconfig = import('pkgconfig')
 369 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 370 if get_option('default_library') == 'shared'
 371   # If we don't build static plugins there is no need to generate pc files
 372   plugins_pkgconfig_install_dir = disabler()
 373 endif
 374
 375 python3 = import('python').find_installation()
 376 subdir('gst-libs')
 377 subdir('gst')
 378 subdir('ext')
 379 subdir('sys')
 380 if not get_option('tools').disabled()
 381   subdir('tools')
 382 endif
 383 subdir('tests')
 384 subdir('pkgconfig')
 385 # xgettext is optional (on Windows for instance)
 386 if find_program('xgettext', required : get_option('nls')).found()
 387   core_conf.set('ENABLE_NLS', 1)
 388   subdir('po')
 389 endif
 390 subdir('docs')
 391
 392 # Use core_conf after all subdirs have set values
 393 configure_file(output : 'config.h', configuration : core_conf)
 394
 395 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')