meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 libva_req = ['>= 0.30.4', '!= 0.99.0']
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 cc = meson.get_compiler('c')
  23
  24 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  25   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  26 endif
  27
  28 # Symbol visibility
  29 if cc.has_argument('-fvisibility=hidden')
  30   add_project_arguments('-fvisibility=hidden', language: 'c')
  31 endif
  32
  33 # Disable strict aliasing
  34 if cc.has_argument('-fno-strict-aliasing')
  35   add_project_arguments('-fno-strict-aliasing', language: 'c')
  36 endif
  37
  38 # Mandatory GST deps
  39 libm = cc.find_library('m', required : false)
  40 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  41   fallback : ['gstreamer', 'gst_dep'])
  42 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  43   fallback : ['gstreamer', 'gst_base_dep'])
  44 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  45     fallback : ['gst-plugins-base', 'pbutils_dep'])
  46 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  47     fallback : ['gst-plugins-base', 'allocators_dep'])
  48 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  49     fallback : ['gst-plugins-base', 'video_dep'])
  50 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  51     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  52 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  53     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
  54 gmodule_dep = dependency('gmodule-2.0', required: false)
  55 libva_dep = dependency('libva', version: libva_req)
  56
  57 libva_drm_dep = dependency('libva-drm', version: '>= 0.33.0', required: false)
  58 libva_wayland_dep = dependency('libva-wayland', version: '>= 0.33.0', required: false)
  59 libva_x11_dep = dependency('libva-x11', version: '>= 0.31.0', required: false)
  60 libdrm_dep = dependency('libdrm', required: false)
  61 libudev_dep = dependency('libudev', required: false)
  62 egl_dep = dependency('egl', required: false)
  63 gl_dep = dependency('gl', required: false)
  64 glesv2_dep = dependency('glesv2', required: false)
  65 libdl_dep = cc.find_library('dl', required: false)
  66 wayland_client_dep = dependency('wayland-client', required: false)
  67 x11_dep = dependency('x11', required: false)
  68 xrandr_dep = dependency('xrandr', required: false)
  69 xrender_dep = dependency('xrender', required: false)
  70
  71 # some of the examples can use GTK+-3
  72 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
  73
  74 GLES_VERSION_MASK = gl_dep.found() ? 1 : 0
  75 if glesv2_dep.found()
  76   if (cc.has_header('GLES2/gl2.h', dependencies: glesv2_dep) and
  77       cc.has_header('GLES2/gl2ext.h', dependencies: glesv2_dep))
  78     GLES_VERSION_MASK += 4
  79   endif
  80   if (cc.has_header('GLES3/gl3.h', dependencies: glesv2_dep) and
  81       cc.has_header('GLES3/gl3ext.h', dependencies: glesv2_dep) and
  82       cc.has_header('GLES2/gl2ext.h', dependencies: glesv2_dep))
  83     GLES_VERSION_MASK += 8
  84   endif
  85 endif
  86
  87 USE_ENCODERS = libva_dep.version().version_compare('>= 0.34.0') and get_option('with_encoders') != 'no'
  88 USE_H265_DECODER = cc.has_header('va/va_dec_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  89 USE_H265_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  90 USE_JPEG_DECODER = cc.has_header('va/va_dec_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  91 USE_JPEG_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  92 USE_VP8_DECODER = cc.has_header('va/va_dec_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  93 USE_VP8_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  94 USE_VP9_DECODER = cc.has_header('va/va_dec_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  95 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  96
  97 USE_VPP = cc.has_header('va/va_vpp.h', dependencies: libva_dep, prefix: '#include <va/va_vpp.h>')
  98
  99 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
 100 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
 101 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
 102 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and get_option('with_wayland') != 'no'
 103 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
 104
 105 driverdir = libva_dep.get_pkgconfig_variable('driverdir')
 106 if driverdir == ''
 107   driverdir = '@0@/@1@/@2@'.format(get_option('prefix'), get_option('libdir'), 'dri')
 108 endif
 109
 110 cdata = configuration_data()
 111 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
 112 cdata.set('PACKAGE', '"gstreamer-vaapi"')
 113 cdata.set('VERSION', '"@0@"'.format(gst_version))
 114 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 115 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
 116 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
 117 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
 118 cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(driverdir))
 119 cdata.set10('USE_DRM', USE_DRM)
 120 cdata.set10('USE_EGL', USE_EGL)
 121 cdata.set10('USE_ENCODERS', USE_ENCODERS)
 122 cdata.set10('USE_GLX', USE_GLX)
 123 cdata.set10('USE_H265_DECODER', USE_H265_DECODER)
 124 cdata.set10('USE_H265_ENCODER', USE_H265_ENCODER)
 125 cdata.set10('USE_JPEG_DECODER', USE_JPEG_DECODER)
 126 cdata.set10('USE_JPEG_ENCODER', USE_JPEG_ENCODER)
 127 cdata.set10('USE_VP8_DECODER', USE_VP8_DECODER)
 128 cdata.set10('USE_VP8_ENCODER', USE_VP8_ENCODER)
 129 cdata.set10('USE_VP9_DECODER', USE_VP9_DECODER)
 130 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
 131 cdata.set10('USE_WAYLAND', USE_WAYLAND)
 132 cdata.set10('USE_X11', USE_X11)
 133 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 134 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 135 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 136 cdata.set10('USE_VA_VPP', USE_VPP)
 137 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 138 cdata.set('USE_GLES_VERSION_MASK', GLES_VERSION_MASK)
 139
 140 if libva_dep.version().version_compare('< 0.38.0')
 141   check_headers = [
 142     [USE_H265_DECODER, 'HAVE_VA_VA_DEC_HEVC_H'],
 143     [USE_H265_ENCODER, 'HAVE_VA_VA_ENC_HEVC_H'],
 144     [USE_JPEG_DECODER, 'HAVE_VA_VA_DEC_JPEG_H'],
 145     [USE_JPEG_ENCODER, 'HAVE_VA_VA_ENC_JPEG_H'],
 146     [USE_VP8_DECODER, 'HAVE_VA_VA_DEC_VP8_H'],
 147     [USE_VP8_ENCODER, 'HAVE_VA_VA_ENC_VP8_H'],
 148     [USE_VP9_DECODER, 'HAVE_VA_VA_DEC_VP9_H'],
 149     [USE_VP9_ENCODER, 'HAVE_VA_VA_DEC_VP9_H'],
 150     [USE_VPP, 'HAVE_VA_VA_VPP_H'],
 151   ]
 152   foreach h : check_headers
 153     if h.get(0)
 154       cdata.set(h.get(1), 1)
 155     endif
 156   endforeach
 157
 158   if USE_ENCODERS
 159     check_headers = [
 160       ['HAVE_VA_VA_ENC_MPEG2_H', 'va/va_enc_mpeg2.h'],
 161       ['HAVE_VA_VA_ENC_H264_H', 'va/va_enc_h264.h'],
 162     ]
 163     foreach h : check_headers
 164       if cc.has_header(h.get(1), dependencies: libva_dep, prefix: '#include <va/va.h>')
 165         cdata.set(h.get(0), 1)
 166       endif
 167     endforeach
 168   endif
 169 endif
 170
 171 api_version = '1.0'
 172 soversion = 0
 173 # maintaining compatibility with the previous libtool versioning
 174 # current = minor * 100 + micro
 175 curversion = gst_version_minor * 100 + gst_version_micro
 176 libversion = '@0@.@1@.0'.format(soversion, curversion)
 177 osxversion = curversion + 1
 178
 179 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 180
 181 configure_file(configuration: cdata, output: 'config.h')
 182 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 183 configinc = include_directories('.')
 184 libsinc = include_directories('gst-libs')
 185
 186 subdir('gst-libs')
 187 subdir('gst')
 188 if not get_option('examples').disabled()
 189   subdir('tests')
 190 endif
 191
 192 python3 = import('python3').find_python()
 193 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')