meson.build

   1 project('gst-plugins-bad', 'c', 'cpp',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 glib_req = '>= 2.44.0'
  20 orc_req = '>= 0.4.17'
  21 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  22
  23 api_version = '1.0'
  24 soversion = 0
  25 # maintaining compatibility with the previous libtool versioning
  26 # current = minor * 100 + micro
  27 curversion = gst_version_minor * 100 + gst_version_micro
  28 libversion = '@0@.@1@.0'.format(soversion, curversion)
  29 osxversion = curversion + 1
  30
  31 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  32 plugins = []
  33
  34 cc = meson.get_compiler('c')
  35 cxx = meson.get_compiler('cpp')
  36
  37 cdata = configuration_data()
  38
  39 if cc.get_id() == 'msvc'
  40   # Ignore several spurious warnings for things gstreamer does very commonly
  41   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  42   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  43   # NOTE: Only add warnings here if you are sure they're spurious
  44   msvc_args = [
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50   ]
  51   add_project_arguments(msvc_args, language : 'c')
  52   add_project_arguments(msvc_args, language : 'cpp')
  53   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  54   # are built with MinGW
  55   noseh_link_args = ['/SAFESEH:NO']
  56 else
  57   if cxx.has_argument('-Wno-non-virtual-dtor')
  58     add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  59   endif
  60
  61   noseh_link_args = []
  62 endif
  63
  64 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  65   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  66 endif
  67
  68 # Symbol visibility
  69 if cc.get_id() == 'msvc'
  70   export_define = '__declspec(dllexport) extern'
  71 elif cc.has_argument('-fvisibility=hidden')
  72   add_project_arguments('-fvisibility=hidden', language: 'c')
  73   add_project_arguments('-fvisibility=hidden', language: 'cpp')
  74   export_define = 'extern __attribute__ ((visibility ("default")))'
  75 else
  76   export_define = 'extern'
  77 endif
  78
  79 # Passing this through the command line would be too messy
  80 cdata.set('GST_API_EXPORT', export_define)
  81
  82 # Disable strict aliasing
  83 if cc.has_argument('-fno-strict-aliasing')
  84   add_project_arguments('-fno-strict-aliasing', language: 'c')
  85 endif
  86 if cxx.has_argument('-fno-strict-aliasing')
  87   add_project_arguments('-fno-strict-aliasing', language: 'cpp')
  88 endif
  89
  90 # Define G_DISABLE_DEPRECATED for development versions
  91 if gst_version_is_dev
  92   message('Disabling deprecated GLib API')
  93   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  94 endif
  95
  96 cast_checks = get_option('gobject-cast-checks')
  97 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  98   message('Disabling GLib cast checks')
  99   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 100 endif
 101
 102 glib_asserts = get_option('glib-asserts')
 103 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 104   message('Disabling GLib asserts')
 105   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 106 endif
 107
 108 glib_checks = get_option('glib-checks')
 109 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 110   message('Disabling GLib checks')
 111   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 112 endif
 113
 114 check_headers = [
 115   ['HAVE_DLFCN_H', 'dlfcn.h'],
 116   ['HAVE_FCNTL_H', 'fcntl.h'],
 117   ['HAVE_INTTYPES_H', 'inttypes.h'],
 118   ['HAVE_MEMORY_H', 'memory.h'],
 119   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 120   ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
 121   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 122   ['HAVE_PTHREAD_H', 'pthread.h'],
 123   ['HAVE_STDINT_H', 'stdint.h'],
 124   ['HAVE_STDLIB_H', 'stdlib.h'],
 125   ['HAVE_STRINGS_H', 'strings.h'],
 126   ['HAVE_STRING_H', 'string.h'],
 127   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 128   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 129   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 130   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 131   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 132   ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
 133   ['HAVE_UNISTD_H', 'unistd.h'],
 134   ['HAVE_WINDOWS_H', 'windows.h'],
 135   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 136   ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
 137 ]
 138
 139 foreach h : check_headers
 140   if cc.has_header(h.get(1))
 141     cdata.set(h.get(0), 1)
 142   endif
 143 endforeach
 144
 145 check_functions = [
 146   ['HAVE_DCGETTEXT', 'dcgettext'],
 147   ['HAVE_GETPAGESIZE', 'getpagesize'],
 148   ['HAVE_GMTIME_R', 'gmtime_r'],
 149   ['HAVE_MMAP', 'mmap'],
 150   ['HAVE_PIPE2', 'pipe2'],
 151   ['HAVE_GETRUSAGE', 'getrusage', '#include<sys/resource.h>'],
 152 ]
 153
 154 foreach f : check_functions
 155   prefix = ''
 156   if f.length() == 3
 157     prefix = f.get(2)
 158   endif
 159   if cc.has_function(f.get(1), prefix: prefix)
 160     cdata.set(f.get(0), 1)
 161   endif
 162 endforeach
 163
 164 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 165 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 166 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 167 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 168 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 169
 170 cdata.set_quoted('VERSION', gst_version)
 171 cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
 172 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 173 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 174 cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
 175 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
 176 cdata.set_quoted('GST_API_VERSION', api_version)
 177 cdata.set_quoted('GST_LICENSE', 'LGPL')
 178 cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
 179 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 180
 181 warning_flags = [
 182   '-Wmissing-declarations',
 183   '-Wredundant-decls',
 184   '-Wwrite-strings',
 185   '-Wformat',
 186   '-Wformat-security',
 187   '-Winit-self',
 188   '-Wmissing-include-dirs',
 189   '-Waddress',
 190   '-Wno-multichar',
 191   '-Wvla',
 192   '-Wpointer-arith',
 193 ]
 194
 195 warning_c_flags = [
 196   '-Wmissing-prototypes',
 197   '-Wdeclaration-after-statement',
 198   '-Wold-style-definition',
 199 ]
 200
 201 warning_cxx_flags = [
 202   '-Wformat-nonliteral',
 203 ]
 204
 205 foreach extra_arg : warning_c_flags
 206   if cc.has_argument (extra_arg)
 207     add_project_arguments([extra_arg], language: 'c')
 208   endif
 209 endforeach
 210
 211 foreach extra_arg : warning_cxx_flags
 212   if cxx.has_argument (extra_arg)
 213     add_project_arguments([extra_arg], language: 'cpp')
 214   endif
 215 endforeach
 216
 217 foreach extra_arg : warning_flags
 218   if cc.has_argument (extra_arg)
 219     add_project_arguments([extra_arg], language: 'c')
 220   endif
 221   if cxx.has_argument (extra_arg)
 222     add_project_arguments([extra_arg], language: 'cpp')
 223   endif
 224 endforeach
 225
 226 # GStreamer package name and origin url
 227 gst_package_name = get_option('package-name')
 228 if gst_package_name == ''
 229   if gst_version_nano == 0
 230     gst_package_name = 'GStreamer Bad Plug-ins source release'
 231   elif gst_version_nano == 1
 232     gst_package_name = 'GStreamer Bad Plug-ins git'
 233   else
 234     gst_package_name = 'GStreamer Bad Plug-ins prerelease'
 235   endif
 236 endif
 237 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 238 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 239
 240 # FIXME: This should be exposed as a configuration option
 241 host_system = host_machine.system()
 242 if host_system == 'linux'
 243   cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
 244 elif ['darwin', 'ios'].contains(host_system)
 245   cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
 246   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 247   # Yes, we set this for iOS too. Same as Autotools.
 248   cdata.set('HAVE_OSX', 1)
 249 else
 250   cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
 251 endif
 252
 253 # Mandatory GST deps
 254 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 255   fallback : ['gstreamer', 'gst_dep'])
 256 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 257   fallback : ['gstreamer', 'gst_base_dep'])
 258 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 259   fallback : ['gstreamer', 'gst_net_dep'])
 260 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 261   fallback : ['gstreamer', 'gst_controller_dep'])
 262
 263 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 264     fallback : ['gst-plugins-base', 'pbutils_dep'])
 265 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 266     fallback : ['gst-plugins-base', 'allocators_dep'])
 267 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 268     fallback : ['gst-plugins-base', 'app_dep'])
 269 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 270     fallback : ['gst-plugins-base', 'audio_dep'])
 271 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 272     fallback : ['gst-plugins-base', 'fft_dep'])
 273 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 274     fallback : ['gst-plugins-base', 'riff_dep'])
 275 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 276     fallback : ['gst-plugins-base', 'rtp_dep'])
 277 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 278     fallback : ['gst-plugins-base', 'rtsp_dep'])
 279 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 280     fallback : ['gst-plugins-base', 'sdp_dep'])
 281 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 282     fallback : ['gst-plugins-base', 'tag_dep'])
 283 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 284     fallback : ['gst-plugins-base', 'video_dep'])
 285 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 286     required : get_option('tests'),
 287     fallback : ['gstreamer', 'gst_check_dep'])
 288
 289 # GStreamer OpenGL
 290 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 291     fallback : ['gst-plugins-base', 'gstgl_dep'], required: get_option('gl'))
 292
 293 if gstgl_dep.found()
 294   if gstgl_dep.type_name() == 'pkgconfig'
 295     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 296     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 297     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 298   else
 299     gstbase = subproject('gst-plugins-base')
 300     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 301     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 302     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 303   endif
 304
 305   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 306   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 307   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 308
 309   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 310     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 311   endforeach
 312
 313   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 314     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 315   endforeach
 316
 317   foreach api : ['gl', 'gles2']
 318     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 319     # temporary backwards compat for older meson-generated .pc file with 'opengl' instead of 'gl'
 320     if gst_gl_apis.contains('opengl')
 321       gst_gl_have_api_gl = true
 322     endif
 323   endforeach
 324 endif
 325
 326 libm = cc.find_library('m', required : false)
 327 glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
 328 gmodule_dep = dependency('gmodule-2.0', fallback: ['glib', 'libgmodule_dep'])
 329 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 330 # gio-unix-2.0 is used by sys/bluez
 331
 332 # Optional dep of ext/gl and gst/librfb
 333 x11_dep = dependency('x11', required : get_option('x11'))
 334 if x11_dep.found()
 335   cdata.set('HAVE_X11', 1)
 336 endif
 337
 338 if host_machine.system() == 'windows'
 339   winsock2 = [cc.find_library('ws2_32')]
 340 else
 341   winsock2 = []
 342 endif
 343
 344 if ['darwin', 'ios'].contains(host_system)
 345   add_languages('objc')
 346   if host_system == 'ios'
 347     cdata.set('HAVE_IOS', 1)
 348   endif
 349
 350   avfoundation_dep = dependency('AVFoundation', required : false)
 351   if avfoundation_dep.found()
 352       cdata.set('HAVE_AVFOUNDATION', 1)
 353   endif
 354
 355   videotoolbox_dep = dependency('VideoToolbox', required : false)
 356   if videotoolbox_dep.found()
 357       cdata.set('HAVE_VIDEOTOOLBOX', 1)
 358   endif
 359
 360 #  FIXME: framework.version() returns 'unknown'
 361 #  if videotoolbox_dep.version().version_compare('>=10.9.6')
 362 #    cdata.set('HAVE_VIDEOTOOLBOX_10_9_6', 1)
 363 #  endif
 364 endif
 365
 366 have_orcc = false
 367 orcc_args = []
 368 # Used by various libraries/elements that use Orc code
 369 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 370     fallback : ['orc', 'orc_dep'])
 371 orcc = find_program('orcc', required : get_option('orc'))
 372 if orc_dep.found() and orcc.found()
 373   have_orcc = true
 374   orcc_args = [orcc, '--include', 'glib.h']
 375   cdata.set('HAVE_ORC', 1)
 376 else
 377   message('Orc Compiler not found or disabled, will use backup C code')
 378   cdata.set('DISABLE_ORC', 1)
 379 endif
 380 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 381
 382 gnustl_dep = declare_dependency()
 383 if host_system == 'android'
 384   gnustl_dep = dependency('gnustl', required : false)
 385 endif
 386
 387 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 388 if gst_dep.type_name() == 'internal'
 389   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 390 else
 391   # We can't check that in the case of subprojects as we won't
 392   # be able to build against an internal dependency (which is not built yet)
 393   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 394 endif
 395
 396 if gst_debug_disabled
 397   message('GStreamer debug system is disabled')
 398   if cc.has_argument('-Wno-unused')
 399     add_project_arguments('-Wno-unused', language: 'c')
 400   endif
 401   if cxx.has_argument ('-Wno-unused')
 402     add_project_arguments('-Wno-unused', language: 'cpp')
 403   endif
 404 else
 405   message('GStreamer debug system is enabled')
 406 endif
 407
 408 gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
 409 configinc = include_directories('.')
 410 libsinc = include_directories('gst-libs')
 411
 412 python3 = import('python').find_installation()
 413
 414 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 415 gnome = import('gnome')
 416 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 417 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 418     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 419     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 420     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 421     'gst_init(NULL,NULL);', '--quiet']
 422
 423 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 424
 425 pkgconfig = import('pkgconfig')
 426 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 427 if get_option('default_library') == 'shared'
 428   # If we don't build static plugins there is no need to generate pc files
 429   plugins_pkgconfig_install_dir = disabler()
 430 endif
 431
 432 subdir('gst-libs')
 433 subdir('gst')
 434 subdir('sys')
 435 subdir('ext')
 436 subdir('tests')
 437 subdir('data')
 438 subdir('tools')
 439 subdir('pkgconfig')
 440
 441 # xgettext is optional (on Windows for instance)
 442 if find_program('xgettext', required : get_option('nls')).found()
 443   cdata.set('ENABLE_NLS', 1)
 444   subdir('po')
 445 endif
 446
 447 configure_file(output : 'config.h', configuration : cdata)
 448
 449 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 450
 451 subdir('docs')