meson.build

   1 project('gst-rtsp-server', 'c',
   2   version : '1.19.2',
   3   meson_version : '>= 0.54',
   4   default_options : ['warning_level=1', 'buildtype=debugoptimized'])
   5
   6 gst_version = meson.project_version()
   7 version_arr = gst_version.split('.')
   8 gst_version_major = version_arr[0].to_int()
   9 gst_version_minor = version_arr[1].to_int()
  10 gst_version_micro = version_arr[2].to_int()
  11  if version_arr.length() == 4
  12   gst_version_nano = version_arr[3].to_int()
  13 else
  14   gst_version_nano = 0
  15 endif
  16 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  17
  18 glib_req = '>= 2.56.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  30
  31 cc = meson.get_compiler('c')
  32
  33 cdata = configuration_data()
  34
  35 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  36   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  37 endif
  38
  39 # Symbol visibility
  40 if cc.get_id() == 'msvc'
  41   export_define = '__declspec(dllexport) extern'
  42 elif cc.has_argument('-fvisibility=hidden')
  43   add_project_arguments('-fvisibility=hidden', language: 'c')
  44   export_define = 'extern __attribute__ ((visibility ("default")))'
  45 else
  46   export_define = 'extern'
  47 endif
  48
  49 # Passing this through the command line would be too messy
  50 cdata.set('GST_API_EXPORT', export_define)
  51
  52 # Disable strict aliasing
  53 if cc.has_argument('-fno-strict-aliasing')
  54   add_project_arguments('-fno-strict-aliasing', language: 'c')
  55 endif
  56
  57 # Define G_DISABLE_DEPRECATED for development versions
  58 if gst_version_is_dev
  59   message('Disabling deprecated GLib API')
  60   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  61 endif
  62
  63 cast_checks = get_option('gobject-cast-checks')
  64 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  65   message('Disabling GLib cast checks')
  66   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  67 endif
  68
  69 glib_asserts = get_option('glib-asserts')
  70 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  71   message('Disabling GLib asserts')
  72   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  73 endif
  74
  75 glib_checks = get_option('glib-checks')
  76 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  77   message('Disabling GLib checks')
  78   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  79 endif
  80
  81 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-rtsp-server-1.0')
  82 cdata.set_quoted('PACKAGE', 'gst-rtsp-server')
  83 cdata.set_quoted('VERSION', gst_version)
  84 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  85 cdata.set_quoted('GST_API_VERSION', api_version)
  86 cdata.set_quoted('GST_LICENSE', 'LGPL')
  87
  88 # FIXME: ENABLE_NLS (currently also missing from autotools build)
  89 # cdata.set('ENABLE_NLS', true)
  90 # cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
  91
  92 # GStreamer package name and origin url
  93 gst_package_name = get_option('package-name')
  94 if gst_package_name == ''
  95   if gst_version_nano == 0
  96     gst_package_name = 'GStreamer RTSP Server Library source release'
  97   elif gst_version_nano == 1
  98     gst_package_name = 'GStreamer RTSP Server Library git'
  99   else
 100     gst_package_name = 'GStreamer RTSP Server Library prerelease'
 101   endif
 102 endif
 103 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 104 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 105
 106 rtspserver_args = ['-DHAVE_CONFIG_H']
 107
 108 warning_flags = [
 109   '-Wmissing-declarations',
 110   '-Wmissing-prototypes',
 111   '-Wredundant-decls',
 112   '-Wundef',
 113   '-Wwrite-strings',
 114   '-Wformat',
 115   '-Wformat-nonliteral',
 116   '-Wformat-security',
 117   '-Wold-style-definition',
 118   '-Waggregate-return',
 119   '-Winit-self',
 120   '-Wmissing-include-dirs',
 121   '-Waddress',
 122   '-Wno-multichar',
 123   '-Wdeclaration-after-statement',
 124   '-Wvla',
 125   '-Wpointer-arith',
 126 ]
 127
 128 foreach extra_arg : warning_flags
 129   if cc.has_argument (extra_arg)
 130     add_project_arguments([extra_arg], language: 'c')
 131   endif
 132 endforeach
 133
 134 rtspserver_incs = include_directories('gst/rtsp-server', '.')
 135
 136 glib_dep = dependency('glib-2.0', version : glib_req,
 137   fallback: ['glib', 'libglib_dep'])
 138 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 139   fallback : ['gstreamer', 'gst_dep'])
 140 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 141   fallback : ['gst-plugins-base', 'rtsp_dep'])
 142 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 143   fallback : ['gst-plugins-base', 'rtp_dep'])
 144 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 145   fallback : ['gst-plugins-base', 'sdp_dep'])
 146 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 147   fallback : ['gst-plugins-base', 'app_dep'])
 148 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 149   fallback : ['gstreamer', 'gst_net_dep'])
 150 if host_machine.system() != 'windows'
 151   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 152     required : get_option('tests'),
 153     fallback : ['gstreamer', 'gst_check_dep'])
 154 endif
 155
 156 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 157 if gst_dep.type_name() == 'internal'
 158   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 159 else
 160   # We can't check that in the case of subprojects as we won't
 161   # be able to build against an internal dependency (which is not built yet)
 162   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 163 endif
 164
 165 if gst_debug_disabled
 166   message('GStreamer debug system is disabled')
 167   add_project_arguments(cc.get_supported_arguments(['-Wno-unused']), language: 'c')
 168 else
 169   message('GStreamer debug system is enabled')
 170 endif
 171
 172 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 173 gnome = import('gnome')
 174 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 175 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 176     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 177     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 178     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 179     'gst_init(NULL,NULL);', '--quiet']
 180
 181 pkgconfig = import('pkgconfig')
 182 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 183 if get_option('default_library') == 'shared'
 184   # If we don't build static plugins there is no need to generate pc files
 185   plugins_pkgconfig_install_dir = disabler()
 186 endif
 187
 188 plugins = []
 189 pkgconfig_subdirs = ['gstreamer-1.0']
 190
 191 subdir('gst')
 192 if not get_option('tests').disabled()
 193   subdir('tests')
 194 endif
 195 if not get_option('examples').disabled()
 196   subdir('examples')
 197 endif
 198 subdir('docs')
 199
 200 # Set release date
 201 if gst_version_nano == 0
 202   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 203   run_result = run_command(extract_release_date, gst_version, files('gst-rtsp-server.doap'))
 204   if run_result.returncode() == 0
 205     release_date = run_result.stdout().strip()
 206     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 207     message('Package release date: ' + release_date)
 208   else
 209     # Error out if our release can't be found in the .doap file
 210     error(run_result.stderr())
 211   endif
 212 endif
 213
 214 configure_file(output: 'config.h', configuration: cdata)
 215
 216 python3 = import('python').find_installation()
 217 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')