meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 libva_req = ['>= 0.30.4', '!= 0.99.0']
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 cc = meson.get_compiler('c')
  23
  24 # Symbol visibility
  25 if cc.has_argument('-fvisibility=hidden')
  26   add_project_arguments('-fvisibility=hidden', language: 'c')
  27 endif
  28
  29 # Mandatory GST deps
  30 libm = cc.find_library('m', required : false)
  31 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  32   fallback : ['gstreamer', 'gst_dep'])
  33 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  34   fallback : ['gstreamer', 'gst_base_dep'])
  35 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  36     fallback : ['gst-plugins-base', 'pbutils_dep'])
  37 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  38     fallback : ['gst-plugins-base', 'allocators_dep'])
  39 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  40     fallback : ['gst-plugins-base', 'video_dep'])
  41 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  42     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  43 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  44     fallback : ['gst-plugins-bad', 'gstgl_dep'], required: false)
  45 gmodule_dep = dependency('gmodule-2.0', required: false)
  46
  47 libva_version = ''
  48 if get_option('with_libva') == 'auto'
  49   libva_dep = dependency('libva-2.0', required : false)
  50   if not libva_dep.found()
  51     libva_dep = dependency('libva', version: libva_req)
  52   else
  53     libva_version = '-2.0'
  54   endif
  55 else
  56   if get_option('with_libva') == '2'
  57     libva_dep = dependency('libva-2.0')
  58     libva_version = '-2.0'
  59   else
  60     libva_dep = dependency('libva', version: libva_req)
  61   endif
  62 endif
  63
  64 libva_drm_dep = dependency('libva-drm' + libva_version, version: '>= 0.33.0',
  65     required: false)
  66 libva_wayland_dep = dependency('libva-wayland' + libva_version,
  67     version: '>= 0.33.0', required: false)
  68 libva_x11_dep = dependency('libva-x11' + libva_version, version: '>= 0.31.0',
  69     required: false)
  70 libdrm_dep = dependency('libdrm', required: false)
  71 libudev_dep = dependency('libudev', required: false)
  72 egl_dep = dependency('egl', required: false)
  73 gl_dep = dependency('gl', required: false)
  74 glesv2_dep = dependency('glesv2', required: false)
  75 glesv3_dep = dependency('glesv3', required: false)
  76 libdl_dep = cc.find_library('dl', rqeuired: false)
  77 wayland_client_dep = dependency('wayland-client', required: false)
  78 x11_dep = dependency('x11', required: false)
  79 xrandr_dep = dependency('xrandr', required: false)
  80 xrender_dep = dependency('xrender', required: false)
  81
  82 GLES_VERSION_MASK = 0
  83 GLES_VERSION_MASK += gl_dep.found() ? 1 : 0
  84 GLES_VERSION_MASK += glesv2_dep.found() ? 4 : 0
  85 GLES_VERSION_MASK += glesv3_dep.found() ? 8 : 0
  86
  87 USE_ENCODERS = libva_dep.version().version_compare('>= 0.34.0') and get_option('with_encoders') != 'no'
  88 USE_H265_DECODER = cc.has_header('va/va_dec_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  89 USE_H265_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  90 USE_JPEG_DECODER = cc.has_header('va/va_dec_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  91 USE_JPEG_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  92 USE_VP8_DECODER = cc.has_header('va/va_dec_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  93 USE_VP8_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  94 USE_VP9_DECODER = cc.has_header('va/va_dec_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  95 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  96
  97 USE_VPP = cc.has_header('va/va_vpp.h', dependencies: libva_dep, prefix: '#include <va/va_vpp.h>')
  98
  99 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
 100 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
 101 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
 102 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and get_option('with_wayland') != 'no'
 103 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
 104
 105 cdata = configuration_data()
 106 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
 107 cdata.set('PACKAGE', '"gstreamer-vaapi"')
 108 cdata.set('VERSION', '"@0@"'.format(gst_version))
 109 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 110 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
 111 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
 112 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
 113 cdata.set10('USE_DRM', USE_DRM)
 114 cdata.set10('USE_EGL', USE_EGL)
 115 cdata.set10('USE_ENCODERS', USE_ENCODERS)
 116 cdata.set10('USE_GLX', USE_GLX)
 117 cdata.set10('USE_H265_DECODER', USE_H265_DECODER)
 118 cdata.set10('USE_H265_ENCODER', USE_H265_ENCODER)
 119 cdata.set10('USE_JPEG_DECODER', USE_JPEG_DECODER)
 120 cdata.set10('USE_JPEG_ENCODER', USE_JPEG_ENCODER)
 121 cdata.set10('USE_VP8_DECODER', USE_VP8_DECODER)
 122 cdata.set10('USE_VP8_ENCODER', USE_VP8_ENCODER)
 123 cdata.set10('USE_VP9_DECODER', USE_VP9_DECODER)
 124 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
 125 cdata.set10('USE_WAYLAND', USE_WAYLAND)
 126 cdata.set10('USE_X11', USE_X11)
 127 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 128 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 129 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 130 cdata.set10('USE_VA_VPP', USE_VPP)
 131 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 132 cdata.set('GLES_VERSION_MASK', GLES_VERSION_MASK)
 133 runcmd = run_command('pkg-config', '--variable=driverdir', 'libva')
 134 if runcmd.returncode() == 0
 135   cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(runcmd.stdout().strip()))
 136 endif
 137
 138 api_version = '1.0'
 139 soversion = 0
 140 # maintaining compatibility with the previous libtool versioning
 141 # current = minor * 100 + micro
 142 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
 143
 144 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 145
 146 configure_file(configuration: cdata, output: 'config.h')
 147 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 148 configinc = include_directories('.')
 149 libsinc = include_directories('gst-libs')
 150
 151 subdir('gst-libs')
 152 subdir('gst')
 153 #subdir('tests')
 154
 155 python3 = import('python3').find_python()
 156 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')