meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.11.0.1',
   3   meson_version : '>= 0.33.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11
  12 libavfilter_dep = dependency('libavfilter', version: '>= 6.47.100')
  13 libavformat_dep = dependency('libavformat', version: '>= 57.41.100')
  14 libavcodec_dep = dependency('libavcodec', version: '>= 57.48.101')
  15 libavutil_dep = dependency('libavutil', version: '>= 55.28.100')
  16
  17 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  18
  19 cc = meson.get_compiler('c')
  20
  21 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  22 #if LIBAVCODEC_VERSION_MICRO >= 100
  23 /* FFmpeg uses 100+ as its micro version */
  24 #else
  25 #error libav provider should be FFmpeg
  26 #endif'''
  27
  28 if not cc.compiles(check_ffmpeg_src, name : 'libav is provided by FFmpeg')
  29     error('Uncompatible libavcodec found')
  30 endif
  31
  32 cdata = configuration_data()
  33 cdata.set('LIBAV_SOURCE', '"system install"')
  34 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  35 cdata.set('PACKAGE', '"gst-libav"')
  36
  37 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  38 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  39   fallback : ['gstreamer', 'gst_dep'])
  40 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  41   fallback : ['gstreamer', 'gst_base_dep'])
  42
  43 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  44     fallback : ['gst-plugins-base', 'video_dep'])
  45 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
  46     fallback : ['gst-plugins-base', 'audio_dep'])
  47 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  48     fallback : ['gst-plugins-base', 'pbutils_dep'])
  49 libm = cc.find_library('m', required : false)
  50
  51 configure_file(input : 'config.h.meson',
  52   output : 'config.h',
  53   configuration : cdata)
  54
  55 gst_libav_args = ['-DHAVE_CONFIG_H', '-Wno-deprecated-declarations']
  56 configinc = include_directories('.')
  57 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  58 subdir('ext/libav/')
  59
  60 python3 = find_program('python3')
  61 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')