meson.build

   1 project('gstreamer', 'c',
   2   version : '1.13.1',
   3   meson_version : '>= 0.40.1',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('library_format')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48   # FIXME: Add FATAL_WARNINGS from configure.ac
  49 endif
  50
  51 # Symbol visibility
  52 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  53 if have_visibility_hidden
  54   add_project_arguments('-fvisibility=hidden', language: 'c')
  55 endif
  56
  57 # Disable strict aliasing
  58 if cc.has_argument('-fno-strict-aliasing')
  59   add_project_arguments('-fno-strict-aliasing', language: 'c')
  60 endif
  61
  62 cdata = configuration_data()
  63 cdata.set_quoted('GST_API_VERSION', apiversion)
  64 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  65 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  66 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  67 cdata.set_quoted('GST_API_VERSION', '1.0')
  68 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  69 cdata.set_quoted('GST_LICENSE', 'LGPL')
  70 cdata.set_quoted('PACKAGE', 'gstreamer')
  71 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  72 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  73 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  74 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  75 cdata.set_quoted('PACKAGE_URL', '')
  76 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  77 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  78 cdata.set_quoted('VERSION', gst_version)
  79 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  80 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  81 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  82 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  83 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  84   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  85
  86 if gst_version_nano > 0
  87     # Have GST_ERROR message printed when running from git
  88     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  89 else
  90     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  91 endif
  92
  93 # GStreamer package name and origin url
  94 gst_package_name = get_option('with-package-name')
  95 if gst_package_name == ''
  96   if gst_version_nano == 0
  97     gst_package_name = 'GStreamer source release'
  98   elif gst_version_nano == 1
  99     gst_package_name = 'GStreamer git'
 100   else
 101     gst_package_name = 'GStreamer prerelease'
 102   endif
 103 endif
 104 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 105 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 106
 107 # These are only needed/used by the ABI tests
 108 host_defines = [
 109   [ 'x86', 'HAVE_CPU_I386' ],
 110   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 111   [ 'arm', 'HAVE_CPU_ARM' ],
 112   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 113   [ 'mips', 'HAVE_CPU_MIPS' ],
 114   [ 'powerpc', 'HAVE_CPU_PPC' ],
 115   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 116   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 117   [ 'sparc', 'HAVE_CPU_SPARC' ],
 118   [ 'ia64', 'HAVE_CPU_IA64' ],
 119   [ 'hppa', 'HAVE_CPU_HPPA' ],
 120   [ 'm68k', 'HAVE_CPU_M68K' ],
 121   [ 's390', 'HAVE_CPU_S390' ],
 122 ]
 123 foreach h : host_defines
 124   if h.get(0) == host_machine.cpu()
 125     cdata.set(h.get(1), 1)
 126   endif
 127 endforeach
 128 # FIXME: should really be called HOST_CPU or such
 129 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 130
 131 check_headers = [
 132   'dlfcn.h',
 133   'inttypes.h',
 134   'memory.h',
 135   'poll.h',
 136   'stdint.h',
 137   'stdio_ext.h',
 138   'strings.h',
 139   'string.h',
 140   'sys/param.h',
 141   'sys/poll.h',
 142   'sys/prctl.h',
 143   'sys/socket.h',
 144   'sys/stat.h',
 145   'sys/times.h',
 146   'sys/time.h',
 147   'sys/types.h',
 148   'sys/utsname.h',
 149   'sys/wait.h',
 150   'ucontext.h',
 151   'unistd.h',
 152   'valgrind/valgrind.h',
 153   'sys/resource.h',
 154 ]
 155
 156 if host_machine.system() == 'windows'
 157   check_headers += ['winsock2.h']
 158 endif
 159
 160 foreach h : check_headers
 161   if cc.has_header(h)
 162     define = 'HAVE_' + h.underscorify().to_upper()
 163     cdata.set(define, 1)
 164   endif
 165 endforeach
 166
 167 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 168   cdata.set('HAVE_TM_GMTOFF', 1)
 169 endif
 170
 171 check_functions = [
 172   'gmtime_r',
 173   'sigaction',
 174   'getrusage',
 175   'fseeko',
 176   'ftello',
 177   'poll',
 178   'ppoll',
 179   'pselect',
 180   'getpagesize',
 181   'clock_gettime',
 182   # These are needed by libcheck
 183   'getline',
 184   'mkstemp',
 185   'alarm',
 186   'gettimeofday',
 187 ]
 188
 189 foreach f : check_functions
 190   if cc.has_function(f)
 191     define = 'HAVE_' + f.underscorify().to_upper()
 192     cdata.set(define, 1)
 193   endif
 194 endforeach
 195
 196 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 197   cdata.set('HAVE_LOCALTIME_R', 1)
 198   # Needed by libcheck
 199   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 200 endif
 201
 202 if cc.links('''#include <pthread.h>
 203                int main() {
 204                  pthread_setname_np("example"); return 0;
 205                }''', name : 'pthread_setname_np(const char*)')
 206   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 207 endif
 208
 209 # Check for posix timers and the monotonic clock
 210 time_prefix = '#include <time.h>\n'
 211 if cdata.has('HAVE_UNISTD_H')
 212   time_prefix += '#include <unistd.h>'
 213 endif
 214
 215 posix_timers_src = time_prefix + '''
 216 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 217 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 218 #endif
 219 '''
 220 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
 221   cdata.set('HAVE_POSIX_TIMERS', 1)
 222 endif
 223
 224 monotonic_clock_src = time_prefix + '''
 225 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 226 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 227 #endif
 228 '''
 229 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
 230   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 231 endif
 232
 233 # Check for __uint128_t (gcc) by checking for 128-bit division
 234 uint128_t_src = '''int main() {
 235 static __uint128_t v1 = 100;
 236 static __uint128_t v2 = 10;
 237 static __uint128_t u;
 238 u = v1 / v2;
 239 }'''
 240 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 241   cdata.set('HAVE_UINT128_T', 1)
 242 endif
 243
 244 # All supported platforms have long long now
 245 cdata.set('HAVE_LONG_LONG', 1)
 246
 247 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 248 # building with MSVC
 249 if cc.get_id() == 'msvc'
 250   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 251 else
 252   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 253 endif
 254
 255 # -------------------------------------------------------------------------------------
 256 # config.h things needed by libcheck
 257 # -------------------------------------------------------------------------------------
 258 if cc.has_function('getpid')
 259   cdata.set('HAVE_GETPID', 1)
 260 elif host_system == 'windows' and cc.has_function('_getpid')
 261   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 262   cdata.set('HAVE__GETPID', 1)
 263 endif
 264 if cc.has_function('strdup')
 265   cdata.set('HAVE_DECL_STRDUP', 1)
 266 elif host_system == 'windows' and cc.has_function('_strdup')
 267   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 268 endif
 269 if host_machine.system() != 'windows'
 270   cdata.set('HAVE_FORK', 1)
 271 else
 272   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 273   cdata.set('HAVE_FORK', 0)
 274 endif
 275 if cc.has_function('strsignal')
 276   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 277 endif
 278 # Check for availability of types
 279 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 280   cdata.set('clockid_t', 'int')
 281 endif
 282 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 283   cdata.set('timer_t', 'int')
 284 endif
 285 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 286                       prefix : '#include <time.h>')
 287   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 288 endif
 289 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 290                       prefix : '#include <time.h>')
 291   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 292 endif
 293
 294 # Platform deps; only ws2_32 and execinfo for now
 295 platform_deps = []
 296 if host_machine.system() == 'windows'
 297   platform_deps = [cc.find_library('ws2_32')]
 298 endif
 299
 300 backtrace_deps = []
 301 if not get_option('disable_libunwind')
 302   unwind_dep = dependency('libunwind', required : false)
 303   dw_dep = dependency('libdw', required: false)
 304   backtrace_deps = [unwind_dep, dw_dep]
 305   if unwind_dep.found()
 306     cdata.set('HAVE_UNWIND', 1)
 307     if dw_dep.found()
 308       cdata.set('HAVE_DW', 1)
 309     else
 310       message('Support for backtraces is partial only.')
 311     endif
 312   else
 313     if cc.has_function('backtrace')
 314       cdata.set('HAVE_BACKTRACE', 1)
 315     else
 316         message('NO backtraces support.')
 317     endif
 318   endif
 319 endif
 320
 321 if cc.has_header('execinfo.h')
 322   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 323     cdata.set('HAVE_BACKTRACE', 1)
 324   else
 325     execinfo_dep = cc.find_library('execinfo', required : false)
 326     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 327       cdata.set('HAVE_BACKTRACE', 1)
 328       platform_deps += execinfo_dep
 329     endif
 330   endif
 331 endif
 332
 333 disable_gst_debug = get_option('disable_gst_debug')
 334 if disable_gst_debug
 335   add_project_arguments(['-Wno-unused'], language: 'c')
 336 endif
 337
 338 # Used by the gstutils test
 339 gmp_dep = cc.find_library('gmp', required : false)
 340 cdata.set('HAVE_GMP', gmp_dep.found())
 341 gsl_dep = cc.find_library('gsl', required : false)
 342 gslcblas_dep = cc.find_library('gslcblas', required : false)
 343 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 344 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 345
 346 # Used by gstinfo.c
 347 dl_dep = cc.find_library('dl', required : false)
 348 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 349
 350
 351 configinc = include_directories('.')
 352 libsinc = include_directories('libs')
 353 privinc = include_directories('gst')
 354
 355 # Find dependencies
 356 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 357   fallback: ['glib', 'libglib_dep'])
 358 gobject_dep = dependency('gobject-2.0',
 359   fallback: ['glib', 'libgobject_dep'])
 360 gmodule_dep = dependency('gmodule-2.0',
 361   fallback: ['glib', 'libgmodule_dep'])
 362 if host_machine.system() == 'windows'
 363     gio_dep = dependency('gio-2.0',
 364         fallback: ['glib', 'libgio_dep'])
 365 else
 366     gio_dep = [dependency('gio-2.0',
 367                   fallback: ['glib', 'libgio_dep']),
 368                dependency('gio-unix-2.0',
 369                   fallback: ['glib', 'libgio_dep'])]
 370 endif
 371
 372 mathlib = cc.find_library('m', required : false)
 373 # Needed for timer_create/settime/delete
 374 # Also provides clock_gettime in glibc < 2.17
 375 rt_lib = cc.find_library('rt', required : false)
 376
 377 gir = find_program('g-ir-scanner', required : false)
 378 gnome = import('gnome')
 379
 380 # Fixme, not very elegant.
 381 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 382
 383 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 384     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 385     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 386     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 387     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 388     'gst_init(NULL,NULL);' ]
 389
 390 # Used by the *_mkenum.py helper scripts
 391 glib_mkenums = find_program('glib-mkenums')
 392
 393 gst_c_args = ['-DHAVE_CONFIG_H']
 394 if libtype == 'static'
 395   gst_c_args += ['-DGST_STATIC_COMPILATION']
 396 endif
 397
 398 # Used in gst/parse/meson.build and below
 399 python3 = import('python3').find_python()
 400
 401 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 402
 403 bashcomp_found = bashcomp_dep.found()
 404 bash_completions_dir = ''
 405 bash_helpers_dir = ''
 406
 407 if bashcomp_found
 408   # get_pkgconfig_variable() won't let us set the prefix
 409   pkgconfig = find_program('pkg-config')
 410
 411   runcmd = run_command(pkgconfig,
 412       '--define-variable=prefix=.',
 413       '--variable=completionsdir',
 414       'bash-completion')
 415
 416   if (runcmd.returncode() == 0)
 417     bash_completions_dir = runcmd.stdout().strip()
 418   else
 419     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 420     bashcomp_found = false
 421   endif
 422
 423   runcmd = run_command(pkgconfig,
 424       '--define-variable=prefix=.',
 425       '--variable=helpersdir',
 426       'bash-completion')
 427
 428   if (runcmd.returncode() == 0)
 429     bash_helpers_dir = runcmd.stdout().strip()
 430   else
 431     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 432     bashcomp_found = false
 433   endif
 434 endif
 435
 436 subdir('gst')
 437 subdir('libs')
 438 subdir('plugins')
 439 subdir('tools')
 440 subdir('pkgconfig')
 441 subdir('tests')
 442 subdir('data')
 443
 444 # xgettext is optional (on Windows for instance)
 445 if find_program('xgettext', required : false).found()
 446   subdir('po')
 447 endif
 448
 449 configure_file(output : 'config.h', configuration : cdata)
 450
 451 if build_machine.system() == 'windows'
 452   message('Disabling gtk-doc while building on Windows')
 453 elif get_option('disable_gtkdoc')
 454   message('gtk-doc is disabled via options')
 455 else
 456   if find_program('gtkdoc-scan', required : false).found()
 457     subdir('docs')
 458   else
 459     message('Not building documentation as gtk-doc was not found')
 460   endif
 461 endif
 462
 463 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 464
 465 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))