meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.2',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 libexecdir = get_option('libexecdir')
  32 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  33
  34 cc = meson.get_compiler('c')
  35
  36 cdata = configuration_data()
  37
  38 # Ignore several spurious warnings for things gstreamer does very commonly
  39 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  40 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  41 # NOTE: Only add warnings here if you are sure they're spurious
  42 if cc.get_id() == 'msvc'
  43   add_project_arguments(
  44       '/wd4018', # implicit signed/unsigned conversion
  45       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  46       '/wd4244', # lossy type conversion (e.g. double -> int)
  47       '/wd4305', # truncating type conversion (e.g. double -> float)
  48       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  49       language : 'c')
  50 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  51   # FIXME: Add an option for this if people ask for it
  52   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  53 endif
  54
  55 # Symbol visibility
  56 have_visibility_hidden = false
  57 if cc.get_id() == 'msvc'
  58   export_define = '__declspec(dllexport) extern'
  59 elif cc.has_argument('-fvisibility=hidden')
  60   add_project_arguments('-fvisibility=hidden', language: 'c')
  61   export_define = 'extern __attribute__ ((visibility ("default")))'
  62   have_visibility_hidden = true
  63 else
  64   export_define = 'extern'
  65 endif
  66
  67 # Passing this through the command line would be too messy
  68 cdata.set('GST_API_EXPORT', export_define)
  69
  70 # Disable strict aliasing
  71 if cc.has_argument('-fno-strict-aliasing')
  72   add_project_arguments('-fno-strict-aliasing', language: 'c')
  73 endif
  74
  75 # Define G_DISABLE_DEPRECATED for development versions
  76 if gst_version_is_dev
  77   message('Disabling deprecated GLib API')
  78   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  79 endif
  80
  81 cast_checks = get_option('gobject-cast-checks')
  82 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  83   message('Disabling GLib cast checks')
  84   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  85 endif
  86
  87 glib_asserts = get_option('glib-asserts')
  88 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  89   message('Disabling GLib asserts')
  90   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  91 endif
  92
  93 glib_checks = get_option('glib-checks')
  94 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  95   message('Disabling GLib checks')
  96   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  97 endif
  98
  99 cdata.set_quoted('GST_API_VERSION', apiversion)
 100 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
 101 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 102 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 103 cdata.set_quoted('GST_API_VERSION', '1.0')
 104 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 105 cdata.set_quoted('GST_LICENSE', 'LGPL')
 106 cdata.set_quoted('PACKAGE', 'gstreamer')
 107 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 108 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 109 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 110 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 111 cdata.set_quoted('PACKAGE_URL', '')
 112 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 113 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 114 cdata.set_quoted('VERSION', gst_version)
 115 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 116 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 117 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 118   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 119 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 120
 121 mem_align_opt = get_option('memory-alignment')
 122 if mem_align_opt == 'malloc'
 123   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 124 elif mem_align_opt == 'pagesize'
 125   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 126 else
 127   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 128 endif
 129
 130 if ['darwin', 'ios'].contains(host_system)
 131   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 132 endif
 133
 134 if gst_version_nano > 0
 135     # Have GST_ERROR message printed when running from git
 136     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 137 else
 138     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 139 endif
 140
 141 # GStreamer package name and origin url
 142 gst_package_name = get_option('package-name')
 143 if gst_package_name == ''
 144   if gst_version_nano == 0
 145     gst_package_name = 'GStreamer source release'
 146   elif gst_version_nano == 1
 147     gst_package_name = 'GStreamer git'
 148   else
 149     gst_package_name = 'GStreamer prerelease'
 150   endif
 151 endif
 152 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 153 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 154
 155 # These are only needed/used by the ABI tests
 156 host_defines = [
 157   [ 'x86', 'HAVE_CPU_I386' ],
 158   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 159   [ 'arm', 'HAVE_CPU_ARM' ],
 160   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 161   [ 'mips', 'HAVE_CPU_MIPS' ],
 162   [ 'powerpc', 'HAVE_CPU_PPC' ],
 163   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 164   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 165   [ 'sparc', 'HAVE_CPU_SPARC' ],
 166   [ 'ia64', 'HAVE_CPU_IA64' ],
 167   [ 'hppa', 'HAVE_CPU_HPPA' ],
 168   [ 'm68k', 'HAVE_CPU_M68K' ],
 169   [ 's390', 'HAVE_CPU_S390' ],
 170 ]
 171 foreach h : host_defines
 172   if h.get(0) == host_machine.cpu()
 173     cdata.set(h.get(1), 1)
 174   endif
 175 endforeach
 176 # FIXME: should really be called HOST_CPU or such
 177 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 178
 179 check_headers = [
 180   'dlfcn.h',
 181   'inttypes.h',
 182   'memory.h',
 183   'poll.h',
 184   'stdint.h',
 185   'stdio_ext.h',
 186   'strings.h',
 187   'string.h',
 188   'sys/param.h',
 189   'sys/poll.h',
 190   'sys/prctl.h',
 191   'sys/socket.h',
 192   'sys/stat.h',
 193   'sys/times.h',
 194   'sys/time.h',
 195   'sys/types.h',
 196   'sys/utsname.h',
 197   'sys/wait.h',
 198   'ucontext.h',
 199   'unistd.h',
 200   'valgrind/valgrind.h',
 201   'sys/resource.h',
 202 ]
 203
 204 if host_system == 'windows'
 205   check_headers += ['winsock2.h']
 206 endif
 207
 208 foreach h : check_headers
 209   if cc.has_header(h)
 210     define = 'HAVE_' + h.underscorify().to_upper()
 211     cdata.set(define, 1)
 212   endif
 213 endforeach
 214
 215 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 216   cdata.set('HAVE_TM_GMTOFF', 1)
 217 endif
 218
 219 check_functions = [
 220   'gmtime_r',
 221   'sigaction',
 222   'getrusage',
 223   'fseeko',
 224   'ftello',
 225   'poll',
 226   'ppoll',
 227   'pselect',
 228   'getpagesize',
 229   'clock_gettime',
 230   # These are needed by libcheck
 231   'getline',
 232   'mkstemp',
 233   'alarm',
 234   'gettimeofday',
 235 ]
 236
 237 foreach f : check_functions
 238   if cc.has_function(f)
 239     define = 'HAVE_' + f.underscorify().to_upper()
 240     cdata.set(define, 1)
 241   endif
 242 endforeach
 243
 244 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 245   cdata.set('HAVE_LOCALTIME_R', 1)
 246   # Needed by libcheck
 247   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 248 endif
 249
 250 if cc.links('''#include <pthread.h>
 251                int main() {
 252                  pthread_setname_np("example"); return 0;
 253                }''', name : 'pthread_setname_np(const char*)')
 254   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 255 endif
 256
 257 # Check for posix timers and the monotonic clock
 258 time_prefix = '#include <time.h>\n'
 259 if cdata.has('HAVE_UNISTD_H')
 260   time_prefix += '#include <unistd.h>'
 261 endif
 262
 263 posix_timers_src = time_prefix + '''
 264 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 265 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 266 #endif
 267 '''
 268 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 269   cdata.set('HAVE_POSIX_TIMERS', 1)
 270 endif
 271
 272 monotonic_clock_src = time_prefix + '''
 273 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 274 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 275 #endif
 276 '''
 277 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 278   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 279 endif
 280
 281 # Check for __uint128_t (gcc) by checking for 128-bit division
 282 uint128_t_src = '''int main() {
 283 static __uint128_t v1 = 100;
 284 static __uint128_t v2 = 10;
 285 static __uint128_t u;
 286 u = v1 / v2;
 287 }'''
 288 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 289   cdata.set('HAVE_UINT128_T', 1)
 290 endif
 291
 292 # All supported platforms have long long now
 293 cdata.set('HAVE_LONG_LONG', 1)
 294
 295 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 296 # building with MSVC
 297 if cc.get_id() == 'msvc'
 298   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 299 else
 300   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 301 endif
 302
 303 # -------------------------------------------------------------------------------------
 304 # config.h things needed by libcheck
 305 # -------------------------------------------------------------------------------------
 306 if cc.has_function('getpid')
 307   cdata.set('HAVE_GETPID', 1)
 308 elif host_system == 'windows' and cc.has_function('_getpid')
 309   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 310   cdata.set('HAVE__GETPID', 1)
 311 endif
 312 if cc.has_function('strdup')
 313   cdata.set('HAVE_DECL_STRDUP', 1)
 314 elif host_system == 'windows' and cc.has_function('_strdup')
 315   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 316 endif
 317 if host_system != 'windows'
 318   cdata.set('HAVE_FORK', 1)
 319 else
 320   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 321   cdata.set('HAVE_FORK', 0)
 322 endif
 323 if cc.has_function('strsignal')
 324   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 325 endif
 326 # Check for availability of types
 327 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 328   cdata.set('clockid_t', 'int')
 329 endif
 330 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 331   cdata.set('timer_t', 'int')
 332 endif
 333 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 334                       prefix : '#include <time.h>')
 335   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 336 endif
 337 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 338                       prefix : '#include <time.h>')
 339   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 340 endif
 341
 342 # Platform deps; only ws2_32 and execinfo for now
 343 platform_deps = []
 344 if host_system == 'windows'
 345   platform_deps = [cc.find_library('ws2_32')]
 346 endif
 347
 348 backtrace_deps = []
 349 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 350 dw_dep = dependency('libdw', required: get_option('libdw'))
 351 dbghelp_dep = dependency('DbgHelp', required : get_option('dbghelp'))
 352 backtrace_deps = [unwind_dep, dw_dep, dbghelp_dep]
 353 if unwind_dep.found()
 354   cdata.set('HAVE_UNWIND', 1)
 355   if dw_dep.found()
 356     cdata.set('HAVE_DW', 1)
 357   else
 358     message('Support for backtraces is partial only.')
 359   endif
 360 elif cc.has_function('backtrace')
 361   cdata.set('HAVE_BACKTRACE', 1)
 362 elif dbghelp_dep.found()
 363   cdata.set('HAVE_DBGHELP', 1)
 364 else
 365   message('NO backtraces support.')
 366 endif
 367
 368 if cc.has_header('execinfo.h')
 369   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 370     cdata.set('HAVE_BACKTRACE', 1)
 371   else
 372     execinfo_dep = cc.find_library('execinfo', required : false)
 373     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 374       cdata.set('HAVE_BACKTRACE', 1)
 375       platform_deps += execinfo_dep
 376     endif
 377   endif
 378 endif
 379
 380 gst_debug = get_option('gst_debug')
 381 if not gst_debug
 382   add_project_arguments(['-Wno-unused'], language: 'c')
 383 endif
 384
 385 warning_flags = [
 386   '-Wmissing-declarations',
 387   '-Wmissing-prototypes',
 388   '-Wredundant-decls',
 389   '-Wundef',
 390   '-Wwrite-strings',
 391   '-Wformat',
 392   '-Wformat-nonliteral',
 393   '-Wformat-security',
 394   '-Wold-style-definition',
 395   '-Winit-self',
 396   '-Wmissing-include-dirs',
 397   '-Waddress',
 398   '-Waggregate-return',
 399   '-Wno-multichar',
 400   '-Wnested-externs',
 401   '-Wdeclaration-after-statement',
 402   '-Wvla',
 403   '-Wpointer-arith',
 404 ]
 405
 406 foreach extra_arg : warning_flags
 407   if cc.has_argument (extra_arg)
 408     add_project_arguments([extra_arg], language: 'c')
 409   endif
 410 endforeach
 411
 412 # Used by the gstutils test
 413 gmp_dep = cc.find_library('gmp', required : false)
 414 cdata.set('HAVE_GMP', gmp_dep.found())
 415 gsl_dep = cc.find_library('gsl', required : false)
 416 gslcblas_dep = cc.find_library('gslcblas', required : false)
 417 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 418 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 419
 420 # Used by gstinfo.c
 421 dl_dep = cc.find_library('dl', required : false)
 422 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 423 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 424 cdata.set('USE_POISONING', get_option('poisoning'))
 425
 426 configinc = include_directories('.')
 427 libsinc = include_directories('libs')
 428 privinc = include_directories('gst')
 429
 430 # Find dependencies
 431 glib_dep = dependency('glib-2.0', version : '>=2.40.0',
 432   fallback: ['glib', 'libglib_dep'])
 433 gobject_dep = dependency('gobject-2.0',
 434   fallback: ['glib', 'libgobject_dep'])
 435 gmodule_dep = dependency('gmodule-2.0',
 436   fallback: ['glib', 'libgmodule_dep'])
 437 if host_system == 'windows'
 438     gio_dep = dependency('gio-2.0',
 439         fallback: ['glib', 'libgio_dep'])
 440 else
 441     gio_dep = [dependency('gio-2.0',
 442                   fallback: ['glib', 'libgio_dep']),
 443                dependency('gio-unix-2.0',
 444                   fallback: ['glib', 'libgio_dep'])]
 445 endif
 446
 447 mathlib = cc.find_library('m', required : false)
 448 # Needed for timer_create/settime/delete
 449 # Also provides clock_gettime in glibc < 2.17
 450 rt_lib = cc.find_library('rt', required : false)
 451
 452 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 453 gnome = import('gnome')
 454
 455 build_gir = gir.found() and not meson.is_cross_build()
 456
 457 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 458     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 459     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 460     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 461     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 462     'gst_init(NULL,NULL);' ]
 463
 464 gst_c_args = ['-DHAVE_CONFIG_H']
 465
 466 # FIXME: This is only needed on windows and probably breaks when
 467 # default_library = 'both'. We should add this flag to static_c_args instead
 468 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 469 if get_option('default_library') == 'static'
 470   gst_c_args += ['-DGST_STATIC_COMPILATION']
 471 endif
 472
 473 # Used in gst/parse/meson.build and below
 474 python3 = import('python').find_installation()
 475
 476 bashcomp_option = get_option('bash-completion')
 477 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 478 bash_completions_dir = ''
 479 bash_helpers_dir = ''
 480
 481 bashcomp_found = false
 482 if bashcomp_dep.found()
 483   bashcomp_found = true
 484   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 485   if bash_completions_dir == ''
 486     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 487     if bashcomp_option.enabled()
 488       error(msg)
 489     else
 490       message(msg)
 491     endif
 492     bashcomp_found = false
 493   endif
 494
 495   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 496   if bash_helpers_dir == ''
 497     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 498     if bashcomp_option.enabled()
 499       error(msg)
 500     else
 501       message(msg)
 502     endif
 503     bashcomp_found = false
 504   endif
 505 endif
 506
 507 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 508
 509 pkgconfig = import('pkgconfig')
 510 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 511 if get_option('default_library') == 'shared'
 512   # If we don't build static plugins there is no need to generate pc files
 513   plugins_pkgconfig_install_dir = disabler()
 514 endif
 515
 516 subdir('gst')
 517 subdir('libs')
 518 subdir('plugins')
 519 if not get_option('tools').disabled()
 520   subdir('tools')
 521 endif
 522 subdir('pkgconfig')
 523 subdir('tests')
 524 subdir('data')
 525
 526 # xgettext is optional (on Windows for instance)
 527 if find_program('xgettext', required : get_option('nls')).found()
 528   cdata.set('ENABLE_NLS', 1)
 529   subdir('po')
 530 endif
 531
 532 configure_file(output : 'config.h', configuration : cdata)
 533
 534 if build_machine.system() == 'windows'
 535   message('Disabling gtk-doc while building on Windows')
 536 else
 537   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 538     subdir('docs')
 539   else
 540     message('Not building documentation as gtk-doc was not found')
 541   endif
 542 endif
 543
 544 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 545
 546 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))