meson.build

   1 project('gst-rtsp-server', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.33.0',
   4   default_options : ['warning_level=1', 'buildtype=debugoptimized'])
   5
   6 gst_version = meson.project_version()
   7 version_arr = gst_version.split('.')
   8 gst_version_major = version_arr[0]
   9 gst_version_minor = version_arr[1]
  10 gst_version_micro = version_arr[2]
  11 if version_arr.length() == 4
  12   gst_version_nano = version_arr[3]
  13 else
  14   gst_version_nano = 0
  15 endif
  16
  17 glib_req = '>= 2.40.0'
  18 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  19
  20 api_version = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  27
  28 cdata = configuration_data()
  29 cdata.set('GETTEXT_PACKAGE', '"gst-rtsp-server-1.0"')
  30 cdata.set('PACKAGE', '"gst-rtsp-server"')
  31 cdata.set('VERSION', '"@0@"'.format(gst_version))
  32 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  33 #cdata.set('GST_API_VERSION', '"@0@"'.format(api_version))
  34 cdata.set('GST_LICENSE', '"LGPL"')
  35
  36 # GStreamer package name and origin url
  37 gst_package_name = get_option('with-package-name')
  38 if gst_package_name == ''
  39   if gst_version_nano == 0
  40     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer RTSP Server Library source release')
  41   elif gst_version_nano == 1
  42     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer RTSP Server Library git')
  43   else
  44     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer RTSP Server Library prerelease')
  45   endif
  46 endif
  47 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  48
  49 configure_file(input : 'config.h.meson',
  50   output : 'config.h',
  51   configuration : cdata)
  52
  53 rtspserver_args = ['-DHAVE_CONFIG_H']
  54
  55 rtspserver_incs = include_directories('gst/rtsp-server', '.')
  56
  57 glib_dep = dependency('glib-2.0', version : glib_req)
  58 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  59   fallback : ['gstreamer', 'gst_dep'])
  60 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
  61   fallback : ['gst-plugins-base', 'rtsp_dep'])
  62 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
  63   fallback : ['gst-plugins-base', 'rtp_dep'])
  64 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
  65   fallback : ['gst-plugins-base', 'sdp_dep'])
  66 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
  67   fallback : ['gst-plugins-base', 'app_dep'])
  68 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
  69   fallback : ['gstreamer', 'gst_net_dep'])
  70
  71 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
  72
  73 gir = find_program('g-ir-scanner', required : false)
  74 gnome = import('gnome')
  75 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
  76 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
  77     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
  78     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
  79     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
  80     'gst_init(NULL,NULL);' ]
  81
  82 subdir('gst')
  83 subdir('tests')
  84 subdir('examples')
  85 subdir('pkgconfig')