meson.build

   1 project('gst-rtsp-server', 'c',
   2   version : '1.11.0.1',
   3   meson_version : '>= 0.33.0',
   4   default_options : ['warning_level=1', 'buildtype=debugoptimized'])
   5
   6 gst_version = meson.project_version()
   7 version_arr = gst_version.split('.')
   8 gst_version_major = version_arr[0]
   9 gst_version_minor = version_arr[1]
  10 gst_version_micro = version_arr[2]
  11 if version_arr.length() == 4
  12   gst_version_nano = version_arr[3]
  13 else
  14   gst_version_nano = 0
  15 endif
  16
  17 glib_req = '>= 2.40.0'
  18 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  19
  20 api_version = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  27
  28 cdata = configuration_data()
  29 cdata.set('GETTEXT_PACKAGE', '"gst-rtsp-server-1.0"')
  30 cdata.set('PACKAGE', '"gst-rtsp-server"')
  31 cdata.set('VERSION', '"@0@"'.format(gst_version))
  32 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  33 cdata.set('GST_PACKAGE_NAME', '"GStreamer RTSP Server Library"')
  34 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  35 #cdata.set('GST_API_VERSION', '"@0@"'.format(api_version))
  36 cdata.set('GST_LICENSE', '"LGPL"')
  37
  38 configure_file(input : 'config.h.meson',
  39   output : 'config.h',
  40   configuration : cdata)
  41
  42 rtspserver_args = ['-DHAVE_CONFIG_H']
  43
  44 rtspserver_incs = include_directories('gst/rtsp-server', '.')
  45
  46 glib_dep = dependency('glib-2.0', version : glib_req)
  47 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  48   fallback : ['gstreamer', 'gst_dep'])
  49 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  50   fallback : ['gstreamer', 'gst_check_dep'])
  51 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
  52   fallback : ['gst-plugins-base', 'rtsp_dep'])
  53 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
  54   fallback : ['gst-plugins-base', 'rtp_dep'])
  55 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
  56   fallback : ['gst-plugins-base', 'sdp_dep'])
  57 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
  58   fallback : ['gst-plugins-base', 'app_dep'])
  59 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
  60   fallback : ['gstreamer', 'gst_net_dep'])
  61
  62 subdir('gst')
  63 subdir('tests')
  64 subdir('examples')
  65 subdir('pkgconfig')