meson.build

   1 project('gst-plugins-bad', 'c', 'cpp',
   2   version : '1.13.90',
   3   meson_version : '>= 0.40.1',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  26
  27 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  28
  29 cc = meson.get_compiler('c')
  30 cxx = meson.get_compiler('cpp')
  31
  32 if cc.get_id() == 'msvc'
  33   # Ignore several spurious warnings for things gstreamer does very commonly
  34   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  35   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  36   # NOTE: Only add warnings here if you are sure they're spurious
  37   msvc_args = [
  38       '/wd4018', # implicit signed/unsigned conversion
  39       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  40       '/wd4244', # lossy type conversion (e.g. double -> int)
  41       '/wd4305', # truncating type conversion (e.g. double -> float)
  42   ]
  43   add_project_arguments(msvc_args, language : 'c')
  44   add_project_arguments(msvc_args, language : 'cpp')
  45   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  46   # are built with MinGW
  47   noseh_link_args = ['/SAFESEH:NO']
  48 else
  49   if cxx.has_argument('-Wno-non-virtual-dtor')
  50     add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  51   endif
  52
  53   noseh_link_args = []
  54 endif
  55
  56 # Symbol visibility
  57 if cc.has_argument('-fvisibility=hidden')
  58   add_project_arguments('-fvisibility=hidden', language: 'c')
  59 endif
  60 if cxx.has_argument('-fvisibility=hidden')
  61   add_project_arguments('-fvisibility=hidden', language: 'cpp')
  62 endif
  63
  64 # Disable strict aliasing
  65 if cc.has_argument('-fno-strict-aliasing')
  66   add_project_arguments('-fno-strict-aliasing', language: 'c')
  67 endif
  68 if cxx.has_argument('-fno-strict-aliasing')
  69   add_project_arguments('-fno-strict-aliasing', language: 'cpp')
  70 endif
  71
  72 cdata = configuration_data()
  73 check_headers = [
  74   ['HAVE_DLFCN_H', 'dlfcn.h'],
  75   ['HAVE_FCNTL_H', 'fcntl.h'],
  76   ['HAVE_HIGHGUI_H', 'highgui.h'],
  77   ['HAVE_INTTYPES_H', 'inttypes.h'],
  78   ['HAVE_MEMORY_H', 'memory.h'],
  79   ['HAVE_MSACM_H', 'msacm.h'],
  80   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
  81   ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
  82   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
  83   ['HAVE_OPENCV2_HIGHGUI_HIGHGUI_C_H', 'opencv2/highgui/highgui_c.h'],
  84   ['HAVE_PTHREAD_H', 'pthread.h'],
  85   ['HAVE_STDINT_H', 'stdint.h'],
  86   ['HAVE_STDLIB_H', 'stdlib.h'],
  87   ['HAVE_STRINGS_H', 'strings.h'],
  88   ['HAVE_STRING_H', 'string.h'],
  89   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  90   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  91   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  92   ['HAVE_SYS_TIME_H', 'sys/time.h'],
  93   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  94   ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
  95   ['HAVE_UNISTD_H', 'unistd.h'],
  96   ['HAVE_WINDOWS_H', 'windows.h'],
  97   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  98   ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
  99 ]
 100
 101 foreach h : check_headers
 102   if cc.has_header(h.get(1))
 103     cdata.set(h.get(0), 1)
 104   endif
 105 endforeach
 106
 107 check_functions = [
 108 # check token HAVE_ACM
 109 # check token HAVE_ANDROID_MEDIA
 110 # check token HAVE_APEXSINK
 111 # check token HAVE_APPLE_MEDIA
 112 # check token HAVE_ASSRENDER
 113 # check token HAVE_AVC
 114 # check token HAVE_AVFOUNDATION
 115 # check token HAVE_BLUEZ
 116 # check token HAVE_BZ2
 117 # check token HAVE_CFLOCALECOPYCURRENT
 118 # check token HAVE_CFPREFERENCESCOPYAPPVALUE
 119 # check token HAVE_CHROMAPRINT
 120 # check token HAVE_CPU_ALPHA
 121 # check token HAVE_CPU_ARM
 122 # check token HAVE_CPU_CRIS
 123 # check token HAVE_CPU_CRISV32
 124 # check token HAVE_CPU_HPPA
 125 # check token HAVE_CPU_I386
 126 # check token HAVE_CPU_IA64
 127 # check token HAVE_CPU_M68K
 128 # check token HAVE_CPU_MIPS
 129 # check token HAVE_CPU_PPC
 130 # check token HAVE_CPU_PPC64
 131 # check token HAVE_CPU_S390
 132 # check token HAVE_CPU_SPARC
 133 # check token HAVE_CPU_X86_64
 134 # check token HAVE_CURL
 135 # check token HAVE_DAALA
 136 # check token HAVE_DASH
 137 # check token HAVE_DC1394
 138   ['HAVE_DCGETTEXT', 'dcgettext'],
 139 # check token HAVE_DECKLINK
 140 # check token HAVE_DIRECT3D
 141 # check token HAVE_DIRECTDRAW
 142 # check token HAVE_DIRECTFB
 143 # check token HAVE_DIRECTSOUND
 144 # check token HAVE_DOWHILE_MACROS
 145 # check token HAVE_DTS
 146 # check token HAVE_DVB
 147 # check token HAVE_EXPERIMENTAL
 148 # check token HAVE_EXTERNAL
 149 # check token HAVE_FAAC
 150 # check token HAVE_FAAD
 151 # check token HAVE_FBDEV
 152 # check token HAVE_FLITE
 153 # check token HAVE_FLUIDSYNTH
 154   ['HAVE_GETPAGESIZE', 'getpagesize'],
 155 # check token HAVE_GETTEXT
 156 # check token HAVE_GL
 157 # check token HAVE_GLCHAR
 158 # check token HAVE_GLEGLIMAGEOES
 159 # check token HAVE_GLINTPTR
 160 # check token HAVE_GLSIZEIPTR
 161 # check token HAVE_GME
 162   ['HAVE_GMTIME_R', 'gmtime_r'],
 163 # check token HAVE_GRAPHENE
 164 # check token HAVE_GSETTINGS
 165 # check token HAVE_GSM
 166 # check token HAVE_GUDEV
 167 # check token HAVE_HLS
 168 # check token HAVE_ICONV
 169 # check token HAVE_IOS
 170 # check token HAVE_JPEG
 171 # check token HAVE_KATE
 172 # check token HAVE_LADSPA
 173 # check token HAVE_LIBGCRYPT
 174 # check token HAVE_LIBGME_ACCURACY
 175 # check token HAVE_LIBMMS
 176 # check token HAVE_LIBNSL
 177 # check token HAVE_LIBSOCKET
 178 # check token HAVE_LIBUSB
 179 # check token HAVE_LIBVISUAL
 180 # check token HAVE_LINSYS
 181 # check token HAVE_LRDF
 182 # check token HAVE_LV2
 183 # check token HAVE_MIMIC
 184   ['HAVE_MMAP', 'mmap'],
 185 # check token HAVE_MODPLUG
 186 # check token HAVE_MPEG2ENC
 187 # check token HAVE_MPG123
 188 # check token HAVE_MPLEX
 189 # check token HAVE_MUSEPACK
 190 # check token HAVE_MYTHTV
 191 # check token HAVE_NAS
 192 # check token HAVE_NEON
 193 # check token HAVE_NETTLE
 194 # check token HAVE_OFA
 195 # check token HAVE_OPENAL
 196 # check token HAVE_OPENCV
 197 # check token HAVE_OPENEXR
 198 # check token HAVE_OPENJPEG
 199 # check token HAVE_OPENJPEG_1
 200 # check token HAVE_OPENNI2
 201 # check token HAVE_OPENSLES
 202 # check token HAVE_OPUS
 203 # check token HAVE_ORC
 204 # check token HAVE_OSX
 205 # check token HAVE_OSX_VIDEO
 206   ['HAVE_PIPE2', 'pipe2'],
 207 # check token HAVE_PNG
 208 # check token HAVE_PVR
 209 # check token HAVE_QUICKTIME
 210 # check token HAVE_RDTSC
 211 # check token HAVE_RESINDVD
 212 # check token HAVE_RSVG
 213 # check token HAVE_RSVG_2_36_2
 214 # check token HAVE_RTMP
 215 # check token HAVE_SBC
 216 # check token HAVE_SDL
 217 # check token HAVE_SHM
 218 # check token HAVE_SMOOTHSTREAMING
 219 # check token HAVE_SNDFILE
 220 # check token HAVE_SNDIO
 221 # check token HAVE_SOUNDTOUCH
 222 # check token HAVE_SOUNDTOUCH_1_4
 223 # check token HAVE_SPANDSP
 224 # check token HAVE_SPC
 225 # check token HAVE_SRTP
 226 # check token HAVE_SSH2
 227 # check token HAVE_TELETEXTDEC
 228 # check token HAVE_TIGER
 229 # check token HAVE_TIMIDITY
 230 # check token HAVE_UVCH264
 231 # check token HAVE_VALGRIND
 232 # check token HAVE_VCD
 233 # check token HAVE_VDPAU
 234 # check token HAVE_VIDEOTOOLBOX
 235 # check token HAVE_VIDEOTOOLBOX_10_9_6
 236 # check token HAVE_VOAACENC
 237 # check token HAVE_VOAMRWBENC
 238 # check token HAVE_WASAPI
 239 # check token HAVE_WAYLAND
 240 # check token HAVE_WEBP
 241 # check token HAVE_WILDMIDI
 242 # check token HAVE_WIN32
 243 # check token HAVE_WININET
 244 # check token HAVE_WINKS
 245 # check token HAVE_WINSCREENCAP
 246 # check token HAVE_XVID
 247 # check token HAVE_ZBAR
 248 ]
 249
 250 foreach f : check_functions
 251   if cc.has_function(f.get(1))
 252     cdata.set(f.get(0), 1)
 253   endif
 254 endforeach
 255
 256 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 257 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 258 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 259 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 260 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 261
 262 cdata.set_quoted('VERSION', gst_version)
 263 cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
 264 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 265 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 266 cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
 267 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
 268 cdata.set_quoted('GST_API_VERSION', api_version)
 269 cdata.set_quoted('GST_LICENSE', 'LGPL')
 270 cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
 271
 272 warning_flags = [
 273   '-Wmissing-declarations',
 274   '-Wredundant-decls',
 275   '-Wwrite-strings',
 276   '-Wformat',
 277   '-Wformat-security',
 278   '-Winit-self',
 279   '-Wmissing-include-dirs',
 280   '-Waddress',
 281   '-Wno-multichar',
 282   '-Wvla',
 283   '-Wpointer-arith',
 284 ]
 285
 286 warning_c_flags = [
 287   '-Wmissing-prototypes',
 288   '-Wdeclaration-after-statement',
 289   '-Wold-style-definition',
 290   '-Wnested-externs',
 291 ]
 292
 293 warning_cxx_flags = [
 294   '-Wformat-nonliteral',
 295 ]
 296
 297 foreach extra_arg : warning_c_flags
 298   if cc.has_argument (extra_arg)
 299     add_project_arguments([extra_arg], language: 'c')
 300   endif
 301 endforeach
 302
 303 foreach extra_arg : warning_cxx_flags
 304   if cxx.has_argument (extra_arg)
 305     add_project_arguments([extra_arg], language: 'cpp')
 306   endif
 307 endforeach
 308
 309 foreach extra_arg : warning_flags
 310   if cc.has_argument (extra_arg)
 311     add_project_arguments([extra_arg], language: 'c')
 312   endif
 313   if cxx.has_argument (extra_arg)
 314     add_project_arguments([extra_arg], language: 'cpp')
 315   endif
 316 endforeach
 317
 318 # GStreamer package name and origin url
 319 gst_package_name = get_option('with-package-name')
 320 if gst_package_name == ''
 321   if gst_version_nano == 0
 322     gst_package_name = 'GStreamer Bad Plug-ins source release'
 323   elif gst_version_nano == 1
 324     gst_package_name = 'GStreamer Bad Plug-ins git'
 325   else
 326     gst_package_name = 'GStreamer Bad Plug-ins prerelease'
 327   endif
 328 endif
 329 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 330 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 331
 332 # FIXME: This should be exposed as a configuration option
 333 host_system = host_machine.system()
 334 if host_system == 'linux'
 335   cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
 336 elif host_system == 'osx'
 337   cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
 338 else
 339   cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
 340 endif
 341
 342 if host_system == 'darwin'
 343   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 344 endif
 345
 346 # Mandatory GST deps
 347 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 348   fallback : ['gstreamer', 'gst_dep'])
 349 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 350   fallback : ['gstreamer', 'gst_base_dep'])
 351 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 352   fallback : ['gstreamer', 'gst_net_dep'])
 353 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 354   fallback : ['gstreamer', 'gst_controller_dep'])
 355
 356 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 357     fallback : ['gst-plugins-base', 'pbutils_dep'])
 358 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 359     fallback : ['gst-plugins-base', 'allocators_dep'])
 360 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 361     fallback : ['gst-plugins-base', 'app_dep'])
 362 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 363     fallback : ['gst-plugins-base', 'audio_dep'])
 364 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 365     fallback : ['gst-plugins-base', 'fft_dep'])
 366 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 367     fallback : ['gst-plugins-base', 'riff_dep'])
 368 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 369     fallback : ['gst-plugins-base', 'rtp_dep'])
 370 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 371     fallback : ['gst-plugins-base', 'rtsp_dep'])
 372 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 373     fallback : ['gst-plugins-base', 'sdp_dep'])
 374 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 375     fallback : ['gst-plugins-base', 'tag_dep'])
 376 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 377     fallback : ['gst-plugins-base', 'video_dep'])
 378 if host_machine.system() != 'windows'
 379   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 380     fallback : ['gstreamer', 'gst_check_dep'])
 381 endif
 382
 383 # GStreamer OpenGL
 384 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 385     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
 386
 387 build_gstgl = gstgl_dep.found() # FIXME: add option?
 388
 389 if build_gstgl
 390   if gstgl_dep.type_name() == 'pkgconfig'
 391     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 392     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 393     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 394   else
 395     gstbase = subproject('gst-plugins-base')
 396     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 397     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 398     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 399   endif
 400
 401   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 402   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 403   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 404
 405   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 406     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 407   endforeach
 408
 409   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 410     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 411   endforeach
 412
 413   foreach api : ['opengl', 'gles2']
 414     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 415   endforeach
 416 endif
 417
 418 libm = cc.find_library('m', required : false)
 419 glib_dep = dependency('glib-2.0', version : glib_req,
 420   fallback: ['glib', 'libglib_dep'])
 421 gmodule_dep = dependency('gmodule-2.0',
 422   fallback: ['glib', 'libgmodule_dep'])
 423 gio_dep = dependency('gio-2.0',
 424   fallback: ['glib', 'libgio_dep'])
 425 x11_dep = dependency('x11', required : false)
 426
 427 # Used by dtls and hls
 428 openssl_dep = dependency('openssl', version : '>= 1.0.1', required : false)
 429
 430 # Used by mpeg2enc and mplex
 431 # mjpegtools upstream breaks API constantly and doesn't export the version in
 432 # a header anywhere. The configure file has a lot of logic to support old
 433 # versions, but it all seems untested and broken. Require 2.0.0. Can be changed
 434 # if someone complains.
 435 mjpegtools_dep = dependency('mjpegtools', version : '>=2.0.0', required : false)
 436 mjpegtools_api = '0'
 437 if mjpegtools_dep.found()
 438   mjpegtools_api = '20000'
 439 endif
 440
 441 if x11_dep.found()
 442   cdata.set('HAVE_X11', 1)
 443 endif
 444
 445 mathlib = cc.find_library('m', required : false)
 446
 447 if host_machine.system() == 'windows'
 448   winsock2 = [cc.find_library('ws2_32')]
 449 else
 450   winsock2 = []
 451 endif
 452
 453 have_orcc = false
 454 orcc_args = []
 455 if get_option('use_orc') != 'no'
 456   need_orc = get_option('use_orc') == 'yes'
 457   # Used by various libraries/elements that use Orc code
 458   orc_dep = dependency('orc-0.4', required : need_orc)
 459   orcc = find_program('orcc', required : need_orc)
 460   if orc_dep.found() and orcc.found()
 461     have_orcc = true
 462     orcc_args = [orcc, '--include', 'glib.h']
 463     cdata.set('HAVE_ORC', 1)
 464   else
 465     message('Orc Compiler not found, will use backup C code')
 466     cdata.set('DISABLE_ORC', 1)
 467   endif
 468 else
 469   cdata.set('DISABLE_ORC', 1)
 470 endif
 471
 472 if gst_dep.type_name() == 'internal'
 473   gst_debug_disabled = subproject('gstreamer').get_variable('disable_gst_debug')
 474 else
 475   # We can't check that in the case of subprojects as we won't
 476   # be able to build against an internal dependency (which is not built yet)
 477   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 478 endif
 479
 480 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 481   add_project_arguments('-Wno-unused', language: 'c')
 482 endif
 483
 484 gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
 485 configinc = include_directories('.')
 486 libsinc = include_directories('gst-libs')
 487
 488 # Used by the *_mkenum.py helper scripts
 489 glib_mkenums = find_program('glib-mkenums')
 490
 491 python3 = import('python3').find_python()
 492
 493 gir = find_program('g-ir-scanner', required : false)
 494 gnome = import('gnome')
 495 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 496 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 497     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 498     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 499     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 500     'gst_init(NULL,NULL);' ]
 501 subdir('gst-libs')
 502 subdir('gst')
 503 subdir('sys')
 504 subdir('ext')
 505 subdir('tests')
 506 subdir('pkgconfig')
 507
 508 configure_file(output : 'config.h', configuration : cdata)
 509
 510 # xgettext is optional (on Windows for instance)
 511 if find_program('xgettext', required : false).found()
 512   subdir('po')
 513 endif
 514
 515 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')