meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19 have_objc = add_languages('objc', required : false)
  20
  21 glib_req = '>= 2.40.0'
  22 orc_req = '>= 0.4.24'
  23 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  24
  25 api_version = '1.0'
  26 soversion = 0
  27 # maintaining compatibility with the previous libtool versioning
  28 # current = minor * 100 + micro
  29 # FIXME: should be able to convert string to int somehow so we can just do maths
  30 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  31
  32 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  33
  34 cc = meson.get_compiler('c')
  35 host_system = host_machine.system()
  36
  37 if cc.get_id() == 'msvc'
  38   # Ignore several spurious warnings for things gstreamer does very commonly
  39   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  40   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  41   # NOTE: Only add warnings here if you are sure they're spurious
  42   add_project_arguments(
  43       '/wd4018', # implicit signed/unsigned conversion
  44       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  45       '/wd4244', # lossy type conversion (e.g. double -> int)
  46       '/wd4305', # truncating type conversion (e.g. double -> float)
  47       language : 'c')
  48   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  49   # are built with MinGW
  50   noseh_link_args = ['/SAFESEH:NO']
  51 else
  52   noseh_link_args = []
  53 endif
  54
  55 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  56   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  57 endif
  58
  59 # Symbol visibility
  60 if cc.has_argument('-fvisibility=hidden')
  61   add_project_arguments('-fvisibility=hidden', language: 'c')
  62 endif
  63
  64 # Disable strict aliasing
  65 if cc.has_argument('-fno-strict-aliasing')
  66   add_project_arguments('-fno-strict-aliasing', language: 'c')
  67 endif
  68
  69 core_conf = configuration_data()
  70 check_headers = [
  71   ['HAVE_DLFCN_H', 'dlfcn.h'],
  72   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  73   ['HAVE_INTTYPES_H', 'inttypes.h'],
  74   ['HAVE_MEMORY_H', 'memory.h'],
  75   ['HAVE_PROCESS_H', 'process.h'],
  76   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  77   ['HAVE_STDINT_H', 'stdint.h'],
  78   ['HAVE_STDLIB_H', 'stdlib.h'],
  79   ['HAVE_STRINGS_H', 'strings.h'],
  80   ['HAVE_STRING_H', 'string.h'],
  81   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  82   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  83   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  84   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  85   ['HAVE_UNISTD_H', 'unistd.h'],
  86   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  87   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  88   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
  89 ]
  90 foreach h : check_headers
  91   if cc.has_header(h.get(1))
  92     core_conf.set(h.get(0), 1)
  93   endif
  94 endforeach
  95
  96 check_functions = [
  97   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  98   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  99   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 100   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 101   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 102 ]
 103
 104 libm = cc.find_library('m', required : false)
 105 foreach f : check_functions
 106   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 107     core_conf.set(f.get(0), 1)
 108   endif
 109 endforeach
 110
 111 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 112 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 113 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 114 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 115 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 116
 117 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 118 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 119 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 120 core_conf.set_quoted('VERSION', gst_version)
 121 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 122 core_conf.set_quoted('GST_API_VERSION', api_version)
 123 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 124 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 125
 126 install_plugins_helper = get_option('install_plugins_helper')
 127 if install_plugins_helper == ''
 128   install_plugins_helper = join_paths(get_option('prefix'),
 129                                       get_option('libexecdir'),
 130                                       'gst-install-plugins-helper')
 131 endif
 132 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 133
 134 warning_flags = [
 135   '-Wmissing-declarations',
 136   '-Wredundant-decls',
 137   '-Wundef',
 138   '-Wwrite-strings',
 139   '-Wformat',
 140   '-Wformat-nonliteral',
 141   '-Wformat-security',
 142   '-Winit-self',
 143   '-Wmissing-include-dirs',
 144   '-Waddress',
 145   '-Wno-multichar',
 146   '-Wvla',
 147   '-Wpointer-arith',
 148 ]
 149
 150 warning_c_flags = [
 151   '-Wmissing-prototypes',
 152   '-Wdeclaration-after-statement',
 153 ]
 154
 155 warning_cxx_flags = [
 156   '-Waggregate-return',
 157 ]
 158
 159 if have_cxx
 160   cxx = meson.get_compiler('cpp')
 161   foreach extra_arg : warning_cxx_flags
 162     if cxx.has_argument (extra_arg)
 163       add_project_arguments([extra_arg], language: 'cpp')
 164     endif
 165   endforeach
 166 endif
 167
 168 foreach extra_arg : warning_flags
 169   if cc.has_argument (extra_arg)
 170     add_project_arguments([extra_arg], language: 'c')
 171   endif
 172   if have_cxx and cxx.has_argument (extra_arg)
 173     add_project_arguments([extra_arg], language: 'cpp')
 174   endif
 175 endforeach
 176
 177 foreach extra_arg : warning_c_flags
 178   if cc.has_argument (extra_arg)
 179     add_project_arguments([extra_arg], language: 'c')
 180   endif
 181 endforeach
 182
 183 # GStreamer package name and origin url
 184 gst_package_name = get_option('package-name')
 185 if gst_package_name == ''
 186   if gst_version_nano == 0
 187     gst_package_name = 'GStreamer Base Plug-ins source release'
 188   elif gst_version_nano == 1
 189     gst_package_name = 'GStreamer Base Plug-ins git'
 190   else
 191     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 192   endif
 193 endif
 194 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 195 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 196
 197 # FIXME: These should be configure options
 198 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 199 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 200
 201 # Set whether the audioresampling method should be detected at runtime
 202 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 203
 204 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 205 if get_option('default_library') == 'static'
 206   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 207 endif
 208
 209 # X11 checks are for sys/ and tests/
 210 x11_dep = dependency('x11', required : get_option('x11'))
 211 # GLib checks are for the entire project
 212 # Almost everything that uses glib also uses gobject
 213 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 214              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 215 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 216 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 217 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : host_system != 'windows',
 218                          fallback: ['glib', 'libgiounix_dep'])
 219
 220 # some of the examples can use gdk-pixbuf and GTK+3
 221 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 222 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 223 # TODO: https://github.com/mesonbuild/meson/issues/3941
 224 if not get_option('x11').disabled()
 225   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 226 else
 227   gtk_x11_dep = dependency('', required : false)
 228 endif
 229 # gtk+ quartz backend is only available on macOS
 230 if host_system == 'darwin'
 231   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 232 else
 233   gtk_quartz_dep = dependency('', required : false)
 234 endif
 235
 236 core_conf.set('HAVE_X', x11_dep.found())
 237 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 238
 239 if gio_dep.type_name() == 'pkgconfig'
 240     core_conf.set_quoted('GIO_MODULE_DIR',
 241         gio_dep.get_pkgconfig_variable('giomoduledir'))
 242     core_conf.set_quoted('GIO_LIBDIR',
 243         gio_dep.get_pkgconfig_variable('libdir'))
 244     core_conf.set_quoted('GIO_PREFIX',
 245         gio_dep.get_pkgconfig_variable('prefix'))
 246 else
 247     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 248       get_option('libdir'), 'gio/modules'))
 249     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 250       get_option('libdir')))
 251     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 252 endif
 253
 254 configinc = include_directories('.')
 255 libsinc = include_directories('gst-libs')
 256
 257 # To use the subproject make subprojects directory
 258 # and put gstreamer meson git there (symlinking is fine)
 259 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 260   fallback : ['gstreamer', 'gst_dep'])
 261 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 262   fallback : ['gstreamer', 'gst_base_dep'])
 263 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 264   fallback : ['gstreamer', 'gst_net_dep'])
 265 if host_system != 'windows'
 266   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 267     fallback : ['gstreamer', 'gst_check_dep'])
 268 endif
 269 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 270   fallback : ['gstreamer', 'gst_controller_dep'])
 271
 272 have_orcc = false
 273 orcc_args = []
 274 # Used by various libraries/elements that use Orc code
 275 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'))
 276 orcc = find_program('orcc', required : get_option('orc'))
 277 if orc_dep.found() and orcc.found()
 278   have_orcc = true
 279   orcc_args = [orcc, '--include', 'glib.h']
 280   core_conf.set('HAVE_ORC', 1)
 281 else
 282   message('Orc Compiler not found or disabled, will use backup C code')
 283   core_conf.set('DISABLE_ORC', 1)
 284 endif
 285
 286 # Used to build SSE* things in audio-resampler
 287 sse_args = '-msse'
 288 sse2_args = '-msse2'
 289 sse41_args = '-msse4.1'
 290
 291 have_sse = cc.has_argument(sse_args)
 292 have_sse2 = cc.has_argument(sse2_args)
 293 have_sse41 = cc.has_argument(sse41_args)
 294
 295 if gst_dep.type_name() == 'internal'
 296     gst_proj = subproject('gstreamer')
 297
 298     if not gst_proj.get_variable('gst_debug')
 299         message('GStreamer debug system is disabled')
 300         add_project_arguments('-Wno-unused', language: 'c')
 301     else
 302         message('GStreamer debug system is enabled')
 303     endif
 304 else
 305     # We can't check that in the case of subprojects as we won't
 306     # be able to build against an internal dependency (which is not built yet)
 307     if not cc.compiles('''
 308 #include <gst/gstconfig.h>
 309 #ifdef GST_DISABLE_GST_DEBUG
 310 #error "debugging disabled, make compiler fail"
 311 #endif''' , dependencies: gst_dep)
 312         message('GStreamer debug system is disabled')
 313         add_project_arguments('-Wno-unused', language: 'c')
 314     else
 315         message('GStreamer debug system is enabled')
 316     endif
 317 endif
 318
 319 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 320 gnome = import('gnome')
 321 build_gir = gir.found() and not meson.is_cross_build()
 322 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 323     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 324     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 325     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 326     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 327     'gst_init(NULL,NULL);' ]
 328
 329 pkgconfig = import('pkgconfig')
 330 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 331 if get_option('default_library') == 'shared'
 332   # If we don't build static plugins there is no need to generate pc files
 333   plugins_pkgconfig_install_dir = disabler()
 334 endif
 335
 336 subdir('gst-libs')
 337 subdir('gst')
 338 subdir('ext')
 339 subdir('sys')
 340 subdir('tools')
 341 subdir('tests')
 342 subdir('pkgconfig')
 343
 344 # xgettext is optional (on Windows for instance)
 345 if find_program('xgettext', required : get_option('nls')).found()
 346   core_conf.set('ENABLE_NLS', 1)
 347   subdir('po')
 348 endif
 349
 350 if build_machine.system() == 'windows'
 351   message('Disabling gtk-doc while building on Windows')
 352 else
 353   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 354     subdir('docs')
 355   else
 356     message('Not building documentation as gtk-doc was not found')
 357   endif
 358 endif
 359
 360 # Use core_conf after all subdirs have set values
 361 configure_file(output : 'config.h', configuration : core_conf)
 362
 363 python3 = import('python3').find_python()
 364 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')