utils: Fix leak in failed case of regression overflow checking
[platform/upstream/gstreamer.git] / meson.build
1 project('gstreamer', 'c',
2   version : '1.13.0.1',
3   meson_version : '>= 0.40.1',
4   default_options : [ 'warning_level=1',
5                       'buildtype=debugoptimized' ])
6
7 gst_version = meson.project_version()
8 version_arr = gst_version.split('.')
9 gst_version_major = version_arr[0]
10 gst_version_minor = version_arr[1]
11 gst_version_micro = version_arr[2]
12 if version_arr.length() == 4
13   gst_version_nano = version_arr[3].to_int()
14 else
15   gst_version_nano = 0
16 endif
17
18 host_system = host_machine.system()
19
20 apiversion = '1.0'
21 soversion = 0
22 # maintaining compatibility with the previous libtool versioning
23 # current = minor * 100 + micro
24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
25
26 prefix = get_option('prefix')
27 libtype = get_option('library_format')
28
29 libexecdir = get_option('libexecdir')
30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
31
32 cc = meson.get_compiler('c')
33
34 # Ignore several spurious warnings for things gstreamer does very commonly
35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
37 # NOTE: Only add warnings here if you are sure they're spurious
38 if cc.get_id() == 'msvc'
39   add_project_arguments(
40       '/wd4018', # implicit signed/unsigned conversion
41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
42       '/wd4244', # lossy type conversion (e.g. double -> int)
43       '/wd4305', # truncating type conversion (e.g. double -> float)
44       language : 'c')
45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
46   # FIXME: Add an option for this if people ask for it
47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
48   # FIXME: Add FATAL_WARNINGS from configure.ac
49 endif
50
51 cdata = configuration_data()
52 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
53 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
54 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
55 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
56 cdata.set('GST_API_VERSION', '"1.0"')
57 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
58 cdata.set('GST_LICENSE', '"LGPL"')
59 cdata.set('PACKAGE', '"gstreamer"')
60 cdata.set('PACKAGE_NAME', '"GStreamer"')
61 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
62 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
64 cdata.set('PACKAGE_URL', '""')
65 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
66 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
67 cdata.set('VERSION', '"@0@"'.format(gst_version))
68 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
69 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
70 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
71 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
72
73 if gst_version_nano > 0
74     # Have GST_ERROR message printed when running from git
75     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
76 else
77     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
78 endif
79
80 # GStreamer package name and origin url
81 gst_package_name = get_option('with-package-name')
82 if gst_package_name == ''
83   if gst_version_nano == 0
84     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer source release')
85   elif gst_version_nano == 1
86     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer git')
87   else
88     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer prerelease')
89   endif
90 endif
91 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
92
93 # These are only needed/used by the ABI tests
94 host_defines = [
95   [ 'x86', 'HAVE_CPU_I386' ],
96   [ 'x86_64', 'HAVE_CPU_X86_64' ],
97   [ 'arm', 'HAVE_CPU_ARM' ],
98   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
99   [ 'mips', 'HAVE_CPU_MIPS' ],
100   [ 'powerpc', 'HAVE_CPU_PPC' ],
101   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
102   [ 'alpha', 'HAVE_CPU_ALPHA' ],
103   [ 'sparc', 'HAVE_CPU_SPARC' ],
104   [ 'ia64', 'HAVE_CPU_IA64' ],
105   [ 'hppa', 'HAVE_CPU_HPPA' ],
106   [ 'm68k', 'HAVE_CPU_M68K' ],
107   [ 's390', 'HAVE_CPU_S390' ],
108 ]
109 foreach h : host_defines
110   if h.get(0) == host_machine.cpu()
111     cdata.set(h.get(1), 1)
112   endif
113 endforeach
114 # FIXME: should really be called HOST_CPU or such
115 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
116
117 check_headers = [
118   'dlfcn.h',
119   'inttypes.h',
120   'memory.h',
121   'poll.h',
122   'stdint.h',
123   'stdio_ext.h',
124   'strings.h',
125   'string.h',
126   'sys/param.h',
127   'sys/poll.h',
128   'sys/prctl.h',
129   'sys/socket.h',
130   'sys/stat.h',
131   'sys/times.h',
132   'sys/time.h',
133   'sys/types.h',
134   'sys/utsname.h',
135   'sys/wait.h',
136   'ucontext.h',
137   'unistd.h',
138   'valgrind/valgrind.h',
139   'sys/resource.h',
140 ]
141
142 if host_machine.system() == 'windows'
143   check_headers += ['winsock2.h']
144 endif
145
146 foreach h : check_headers
147   if cc.has_header(h)
148     define = 'HAVE_' + h.underscorify().to_upper()
149     cdata.set(define, 1)
150   endif
151 endforeach
152
153 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
154   cdata.set('HAVE_TM_GMTOFF', 1)
155 endif
156
157 check_functions = [
158   'gmtime_r',
159   'sigaction',
160   'getrusage',
161   'fseeko',
162   'ftello',
163   'poll',
164   'pselect',
165   'getpagesize',
166   'clock_gettime',
167   # These are needed by libcheck
168   'getline',
169   'mkstemp',
170   'alarm',
171   'gettimeofday',
172 ]
173
174 foreach f : check_functions
175   if cc.has_function(f)
176     define = 'HAVE_' + f.underscorify().to_upper()
177     cdata.set(define, 1)
178   endif
179 endforeach
180
181 if cc.has_function('localtime_r', prefix : '#include<time.h>')
182   cdata.set('HAVE_LOCALTIME_R', 1)
183   # Needed by libcheck
184   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
185 endif
186
187 if cc.links('''#include <pthread.h>
188                int main() {
189                  pthread_setname_np("example"); return 0;
190                }''', name : 'pthread_setname_np(const char*)')
191   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
192 endif
193
194 # Check for posix timers and the monotonic clock
195 time_prefix = '#include <time.h>\n'
196 if cdata.has('HAVE_UNISTD_H')
197   time_prefix += '#include <unistd.h>'
198 endif
199
200 posix_timers_src = time_prefix + '''
201 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
202 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
203 #endif
204 '''
205 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
206   cdata.set('HAVE_POSIX_TIMERS', 1)
207 endif
208
209 monotonic_clock_src = time_prefix + '''
210 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
211 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
212 #endif
213 '''
214 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
215   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
216 endif
217
218 # Check for __uint128_t (gcc) by checking for 128-bit division
219 uint128_t_src = '''int main() {
220 static __uint128_t v1 = 100;
221 static __uint128_t v2 = 10;
222 static __uint128_t u;
223 u = v1 / v2;
224 }'''
225 if cc.compiles(uint128_t_src, name : '__uint128_t available')
226   cdata.set('HAVE_UINT128_T', 1)
227 endif
228
229 # All supported platforms have long long now
230 cdata.set('HAVE_LONG_LONG', 1)
231
232 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
233 # building with MSVC
234 if cc.get_id() == 'msvc'
235   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
236 else
237   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
238 endif
239
240 # -------------------------------------------------------------------------------------
241 # config.h things needed by libcheck
242 # -------------------------------------------------------------------------------------
243 if cc.has_function('getpid')
244   cdata.set('HAVE_GETPID', 1)
245 elif host_system == 'windows' and cc.has_function('_getpid')
246   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
247   cdata.set('HAVE__GETPID', 1)
248 endif
249 if cc.has_function('strdup')
250   cdata.set('HAVE_DECL_STRDUP', 1)
251 elif host_system == 'windows' and cc.has_function('_strdup')
252   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
253 endif
254 if host_machine.system() != 'windows'
255   cdata.set('HAVE_FORK', 1)
256 else
257   # libcheck requires HAVE_FORK to be 0 when fork() is not available
258   cdata.set('HAVE_FORK', 0)
259 endif
260 if cc.has_function('strsignal')
261   cdata.set('HAVE_DECL_STRSIGNAL', 1)
262 endif
263 # Check for availability of types
264 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
265   cdata.set('clockid_t', 'int')
266 endif
267 if not cc.has_type('timer_t', prefix : '#include <time.h>')
268   cdata.set('timer_t', 'int')
269 endif
270 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
271                       prefix : '#include <time.h>')
272   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
273 endif
274 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
275                       prefix : '#include <time.h>')
276   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
277 endif
278
279 # Platform deps; only ws2_32 and execinfo for now
280 platform_deps = []
281 if host_machine.system() == 'windows'
282   platform_deps = [cc.find_library('ws2_32')]
283 endif
284
285 backtrace_deps = []
286 if not get_option('disable_libunwind')
287   unwind_dep = dependency('libunwind', required : false)
288   dw_dep = dependency('libdw', required: false)
289   backtrace_deps = [unwind_dep, dw_dep]
290   if unwind_dep.found()
291     cdata.set('HAVE_UNWIND', 1)
292     if dw_dep.found()
293       cdata.set('HAVE_DW', 1)
294     else
295       message('Support for backtraces is partial only.')
296     endif
297   else
298     if cc.has_function('backtrace')
299       cdata.set('HAVE_BACKTRACE', 1)
300     else
301         message('NO backtraces support.')
302     endif
303   endif
304 endif
305
306 if cc.has_header('execinfo.h')
307   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
308     cdata.set('HAVE_BACKTRACE', 1)
309   else
310     execinfo_dep = cc.find_library('execinfo', required : false)
311     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
312       cdata.set('HAVE_BACKTRACE', 1)
313       platform_deps += execinfo_dep
314     endif
315   endif
316 endif
317
318 disable_gst_debug = get_option('disable_gst_debug')
319 if get_option('disable_gst_debug')
320     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
321   add_project_arguments(['-Wno-unused'], language: 'c')
322 endif
323
324 # Used by the gstutils test
325 gmp_dep = cc.find_library('gmp', required : false)
326 cdata.set('HAVE_GMP', gmp_dep.found())
327 gsl_dep = cc.find_library('gsl', required : false)
328 gslcblas_dep = cc.find_library('gslcblas', required : false)
329 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
330 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
331
332 # Used by gstinfo.c
333 dl_dep = cc.find_library('dl', required : false)
334 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
335
336
337 configinc = include_directories('.')
338 libsinc = include_directories('libs')
339 privinc = include_directories('gst')
340
341 # Find dependencies
342 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
343 gobject_dep = dependency('gobject-2.0')
344 gmodule_dep = dependency('gmodule-2.0')
345 if host_machine.system() == 'windows'
346     gio_dep = dependency('gio-2.0')
347 else
348     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
349 endif
350
351 mathlib = cc.find_library('m', required : false)
352 # Needed for timer_create/settime/delete
353 # Also provides clock_gettime in glibc < 2.17
354 rt_lib = cc.find_library('rt', required : false)
355
356 gir = find_program('g-ir-scanner', required : false)
357 gnome = import('gnome')
358
359 # Fixme, not very elegant.
360 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
361
362 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
363     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
364     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
365     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
366     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
367     'gst_init(NULL,NULL);' ]
368 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
369
370 # Used by the *_mkenum.py helper scripts
371 glib_mkenums = find_program('glib-mkenums')
372
373 gst_c_args = ['-DHAVE_CONFIG_H']
374 if libtype == 'static'
375   gst_c_args += ['-DGST_STATIC_COMPILATION']
376 endif
377
378 # Used in gst/parse/meson.build and below
379 py3 = find_program('python3', required : false)
380 if not py3.found()
381   # Maybe 'python' is Python 3
382   py3 = find_program('python')
383 endif
384
385 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
386
387 bashcomp_found = bashcomp_dep.found()
388 bash_completions_dir = ''
389 bash_helpers_dir = ''
390
391 if bashcomp_found
392   # get_pkgconfig_variable() won't let us set the prefix
393   pkgconfig = find_program('pkg-config')
394
395   runcmd = run_command(pkgconfig,
396       '--define-variable=prefix="."',
397       '--variable=completionsdir',
398       'bash-completion')
399
400   if (runcmd.returncode() == 0)
401     bash_completions_dir = runcmd.stdout().strip()
402   else
403     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
404     bashcomp_found = false
405   endif
406
407   runcmd = run_command(pkgconfig,
408       '--define-variable=prefix="."',
409       '--variable=helpersdir',
410       'bash-completion')
411
412   if (runcmd.returncode() == 0)
413     bash_helpers_dir = runcmd.stdout().strip()
414   else
415     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
416     bashcomp_found = false
417   endif
418 endif
419
420 subdir('gst')
421 subdir('libs')
422 subdir('plugins')
423 subdir('tools')
424 subdir('pkgconfig')
425 subdir('tests')
426 subdir('po')
427 subdir('data')
428
429 configure_file(output : 'config.h', configuration : cdata)
430
431 if build_machine.system() == 'windows'
432   message('Disabling gtk-doc while building on Windows')
433 elif get_option('disable_gtkdoc')
434   message('gtk-doc is disabled via options')
435 else
436   if find_program('gtkdoc-scan', required : false).found()
437     subdir('docs')
438   else
439     message('Not building documentation as gtk-doc was not found')
440   endif
441 endif
442
443 run_command(py3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
444
445 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))