meson.build

   1 project('gstreamer', 'c',
   2   version : '1.17.90',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 datadir = join_paths(prefix, get_option('datadir'))
  32 libexecdir = get_option('libexecdir')
  33 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  34
  35 cc = meson.get_compiler('c')
  36
  37 cdata = configuration_data()
  38
  39 # Ignore several spurious warnings for things gstreamer does very commonly
  40 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  41 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  42 # NOTE: Only add warnings here if you are sure they're spurious
  43 if cc.get_id() == 'msvc'
  44   add_project_arguments(
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50       language : 'c')
  51 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  52   # FIXME: Add an option for this if people ask for it
  53   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  54 endif
  55
  56 # Symbol visibility
  57 have_visibility_hidden = false
  58 if cc.get_id() == 'msvc'
  59   export_define = '__declspec(dllexport) extern'
  60 elif cc.has_argument('-fvisibility=hidden')
  61   add_project_arguments('-fvisibility=hidden', language: 'c')
  62   export_define = 'extern __attribute__ ((visibility ("default")))'
  63   have_visibility_hidden = true
  64 else
  65   export_define = 'extern'
  66 endif
  67
  68 # Passing this through the command line would be too messy
  69 cdata.set('GST_API_EXPORT', export_define)
  70
  71 # Disable strict aliasing
  72 if cc.has_argument('-fno-strict-aliasing')
  73   add_project_arguments('-fno-strict-aliasing', language: 'c')
  74 endif
  75
  76 # Define G_DISABLE_DEPRECATED for development versions
  77 if gst_version_is_dev
  78   message('Disabling deprecated GLib API')
  79   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  80 endif
  81
  82 cast_checks = get_option('gobject-cast-checks')
  83 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  84   message('Disabling GLib cast checks')
  85   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  86 endif
  87
  88 glib_asserts = get_option('glib-asserts')
  89 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  90   message('Disabling GLib asserts')
  91   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  92 endif
  93
  94 glib_checks = get_option('glib-checks')
  95 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  96   message('Disabling GLib checks')
  97   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  98 endif
  99
 100 cdata.set_quoted('GST_API_VERSION', apiversion)
 101 cdata.set_quoted('GST_DATADIR', datadir)
 102 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 103 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 104 cdata.set_quoted('GST_API_VERSION', '1.0')
 105 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 106 cdata.set_quoted('GST_LICENSE', 'LGPL')
 107 cdata.set_quoted('PACKAGE', 'gstreamer')
 108 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 109 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 110 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 111 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 112 cdata.set_quoted('PACKAGE_URL', '')
 113 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 114 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 115 cdata.set_quoted('VERSION', gst_version)
 116 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 117 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 118 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 119   description: 'plugin directory path component, used to find plugins on relocatable builds on windows')
 120 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 121   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 122 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 123
 124 mem_align_opt = get_option('memory-alignment')
 125 if mem_align_opt == 'malloc'
 126   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 127 elif mem_align_opt == 'pagesize'
 128   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 129 else
 130   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 131 endif
 132
 133 if ['darwin', 'ios'].contains(host_system)
 134   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 135 endif
 136
 137 if gst_version_nano > 0
 138     # Have GST_ERROR message printed when running from git
 139     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 140 else
 141     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 142 endif
 143
 144 # GStreamer package name and origin url
 145 gst_package_name = get_option('package-name')
 146 if gst_package_name == ''
 147   if gst_version_nano == 0
 148     gst_package_name = 'GStreamer source release'
 149   elif gst_version_nano == 1
 150     gst_package_name = 'GStreamer git'
 151   else
 152     gst_package_name = 'GStreamer prerelease'
 153   endif
 154 endif
 155 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 156 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 157
 158 # These are only needed/used by the ABI tests
 159 host_defines = [
 160   [ 'x86', 'HAVE_CPU_I386' ],
 161   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 162   [ 'arm', 'HAVE_CPU_ARM' ],
 163   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 164   [ 'mips', 'HAVE_CPU_MIPS' ],
 165   [ 'powerpc', 'HAVE_CPU_PPC' ],
 166   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 167   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 168   [ 'sparc', 'HAVE_CPU_SPARC' ],
 169   [ 'ia64', 'HAVE_CPU_IA64' ],
 170   [ 'hppa', 'HAVE_CPU_HPPA' ],
 171   [ 'm68k', 'HAVE_CPU_M68K' ],
 172   [ 's390', 'HAVE_CPU_S390' ],
 173 ]
 174 foreach h : host_defines
 175   if h.get(0) == host_machine.cpu()
 176     cdata.set(h.get(1), 1)
 177   endif
 178 endforeach
 179 # FIXME: should really be called HOST_CPU or such
 180 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 181
 182 check_headers = [
 183   'dlfcn.h',
 184   'inttypes.h',
 185   'memory.h',
 186   'poll.h',
 187   'stdint.h',
 188   'stdio_ext.h',
 189   'strings.h',
 190   'string.h',
 191   'sys/param.h',
 192   'sys/poll.h',
 193   'sys/prctl.h',
 194   'sys/socket.h',
 195   'sys/stat.h',
 196   'sys/times.h',
 197   'sys/time.h',
 198   'sys/types.h',
 199   'sys/utsname.h',
 200   'sys/wait.h',
 201   'ucontext.h',
 202   'unistd.h',
 203   'valgrind/valgrind.h',
 204   'sys/resource.h',
 205   'sys/uio.h',
 206 ]
 207
 208 if host_system == 'windows'
 209   check_headers += ['winsock2.h']
 210 endif
 211
 212 foreach h : check_headers
 213   if cc.has_header(h)
 214     define = 'HAVE_' + h.underscorify().to_upper()
 215     cdata.set(define, 1)
 216   endif
 217 endforeach
 218
 219 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 220   cdata.set('HAVE_TM_GMTOFF', 1)
 221 endif
 222
 223 check_functions = [
 224   'gmtime_r',
 225   'sigaction',
 226   'getrusage',
 227   'fseeko',
 228   'ftello',
 229   'poll',
 230   'ppoll',
 231   'pselect',
 232   'getpagesize',
 233   'clock_gettime',
 234   'strnlen',
 235   # These are needed by libcheck
 236   'getline',
 237   'mkstemp',
 238   'alarm',
 239   'gettimeofday',
 240 ]
 241
 242 foreach f : check_functions
 243   if cc.has_function(f)
 244     define = 'HAVE_' + f.underscorify().to_upper()
 245     cdata.set(define, 1)
 246   endif
 247 endforeach
 248
 249 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 250   cdata.set('HAVE_LOCALTIME_R', 1)
 251   # Needed by libcheck
 252   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 253 endif
 254
 255 if cc.links('''#include <pthread.h>
 256                int main() {
 257                  pthread_setname_np("example"); return 0;
 258                }''', name : 'pthread_setname_np(const char*)')
 259   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 260 endif
 261 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 262   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 263 endif
 264 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 265   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 266 endif
 267
 268 # Check for futex(2)
 269 if cc.links('''#include <linux/futex.h>
 270                #include <sys/syscall.h>
 271                #include <unistd.h>
 272                int main (int argc, char ** argv) {
 273                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 274                  return 0;
 275                }''', name : 'futex(2) system call')
 276   cdata.set('HAVE_FUTEX', 1)
 277 endif
 278
 279 # Check for posix timers and monotonic clock
 280 time_prefix = '#include <time.h>\n'
 281 if cdata.has('HAVE_UNISTD_H')
 282   time_prefix += '#include <unistd.h>'
 283 endif
 284
 285 posix_timers_src = time_prefix + '''
 286 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 287 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 288 #endif
 289 '''
 290 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 291   cdata.set('HAVE_POSIX_TIMERS', 1)
 292 endif
 293
 294 monotonic_clock_src = time_prefix + '''
 295 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 296 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 297 #endif
 298 '''
 299 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 300   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 301 endif
 302
 303 # Check for __uint128_t (gcc) by checking for 128-bit division
 304 uint128_t_src = '''int main() {
 305 static __uint128_t v1 = 100;
 306 static __uint128_t v2 = 10;
 307 static __uint128_t u;
 308 u = v1 / v2;
 309 }'''
 310 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 311   cdata.set('HAVE_UINT128_T', 1)
 312 endif
 313
 314 # All supported platforms have long long now
 315 cdata.set('HAVE_LONG_LONG', 1)
 316
 317 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 318 # building with MSVC
 319 if cc.get_id() == 'msvc'
 320   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 321 else
 322   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 323 endif
 324
 325 # -------------------------------------------------------------------------------------
 326 # config.h things needed by libcheck
 327 # -------------------------------------------------------------------------------------
 328 if cc.has_function('getpid')
 329   cdata.set('HAVE_GETPID', 1)
 330 elif host_system == 'windows' and cc.has_function('_getpid')
 331   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 332   cdata.set('HAVE__GETPID', 1)
 333 endif
 334 if cc.has_function('strdup')
 335   cdata.set('HAVE_DECL_STRDUP', 1)
 336 elif host_system == 'windows' and cc.has_function('_strdup')
 337   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 338 endif
 339 if host_system != 'windows'
 340   cdata.set('HAVE_FORK', 1)
 341 else
 342   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 343   cdata.set('HAVE_FORK', 0)
 344 endif
 345 if cc.has_function('strsignal')
 346   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 347 endif
 348 # Check for availability of types
 349 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 350   cdata.set('clockid_t', 'int')
 351 endif
 352 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 353   cdata.set('timer_t', 'int')
 354 endif
 355 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 356                       prefix : '#include <time.h>')
 357   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 358 endif
 359 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 360                       prefix : '#include <time.h>')
 361   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 362 endif
 363
 364 # Platform deps; only ws2_32 and execinfo for now
 365 platform_deps = []
 366 if host_system == 'windows'
 367   platform_deps = [cc.find_library('ws2_32')]
 368 endif
 369
 370 backtrace_deps = []
 371 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 372 dw_dep = dependency('libdw', required: get_option('libdw'))
 373 dbghelp_dep = dependency('DbgHelp', required : get_option('dbghelp'))
 374 backtrace_deps = [unwind_dep, dw_dep, dbghelp_dep]
 375 backtrace_source_info = false
 376 backtrace_minimal = false
 377 # MSVC debug stack trace support
 378 if host_system == 'windows' and dbghelp_dep.found()
 379   cdata.set('HAVE_DBGHELP', 1)
 380   backtrace_source_info = true
 381 # DWARF stack trace support with libunwind and elf-utils
 382 elif unwind_dep.found()
 383   cdata.set('HAVE_UNWIND', 1)
 384   if dw_dep.found()
 385     cdata.set('HAVE_DW', 1)
 386     backtrace_source_info = true
 387   endif
 388   backtrace_minimal = true
 389 # Basic backtrace() stack trace support
 390 elif cc.has_function('backtrace')
 391   cdata.set('HAVE_BACKTRACE', 1)
 392   backtrace_minimal = true
 393 endif
 394 # Print messages about what was enabled
 395 if not backtrace_source_info
 396   if not backtrace_minimal
 397     message('NO support for stack traces.')
 398   else
 399     message('Minimal support for stack traces, no source info.')
 400   endif
 401 endif
 402
 403 if cc.has_header('execinfo.h')
 404   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 405     cdata.set('HAVE_BACKTRACE', 1)
 406   else
 407     execinfo_dep = cc.find_library('execinfo', required : false)
 408     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 409       cdata.set('HAVE_BACKTRACE', 1)
 410       platform_deps += execinfo_dep
 411     endif
 412   endif
 413 endif
 414
 415 gst_debug = get_option('gst_debug')
 416 if not gst_debug
 417   add_project_arguments(['-Wno-unused'], language: 'c')
 418 endif
 419
 420 warning_flags = [
 421   '-Wmissing-declarations',
 422   '-Wmissing-prototypes',
 423   '-Wredundant-decls',
 424   '-Wundef',
 425   '-Wwrite-strings',
 426   '-Wformat',
 427   '-Wformat-nonliteral',
 428   '-Wformat-security',
 429   '-Wold-style-definition',
 430   '-Winit-self',
 431   '-Wmissing-include-dirs',
 432   '-Waddress',
 433   '-Waggregate-return',
 434   '-Wno-multichar',
 435   '-Wdeclaration-after-statement',
 436   '-Wvla',
 437   '-Wpointer-arith',
 438 ]
 439
 440 foreach extra_arg : warning_flags
 441   if cc.has_argument (extra_arg)
 442     add_project_arguments([extra_arg], language: 'c')
 443   endif
 444 endforeach
 445
 446 # Used by the gstutils test
 447 gmp_dep = cc.find_library('gmp', required : false)
 448 cdata.set('HAVE_GMP', gmp_dep.found())
 449 gsl_dep = cc.find_library('gsl', required : false)
 450 gslcblas_dep = cc.find_library('gslcblas', required : false)
 451 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 452 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 453
 454 # Used by gstinfo.c
 455 dl_dep = cc.find_library('dl', required : false)
 456 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 457 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 458 cdata.set('USE_POISONING', get_option('poisoning'))
 459
 460 configinc = include_directories('.')
 461 libsinc = include_directories('libs')
 462 privinc = include_directories('gst')
 463
 464 # Find dependencies
 465 glib_dep = dependency('glib-2.0', version : '>=2.44.0',
 466   fallback: ['glib', 'libglib_dep'])
 467 gobject_dep = dependency('gobject-2.0',
 468   fallback: ['glib', 'libgobject_dep'])
 469 gmodule_dep = dependency('gmodule-2.0',
 470   fallback: ['glib', 'libgmodule_dep'])
 471 if host_system == 'windows'
 472     gio_dep = dependency('gio-2.0',
 473         fallback: ['glib', 'libgio_dep'])
 474 else
 475     gio_dep = [dependency('gio-2.0',
 476                   fallback: ['glib', 'libgio_dep']),
 477                dependency('gio-unix-2.0',
 478                   fallback: ['glib', 'libgio_dep'])]
 479 endif
 480
 481 mathlib = cc.find_library('m', required : false)
 482 # Needed for timer_create/settime/delete
 483 # Also provides clock_gettime in glibc < 2.17
 484 rt_lib = cc.find_library('rt', required : false)
 485
 486 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 487 gnome = import('gnome')
 488
 489 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 490
 491 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 492     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 493     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 494     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 495     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 496     'gst_init(NULL,NULL);', '--quiet']
 497
 498 gst_c_args = ['-DHAVE_CONFIG_H']
 499
 500 # FIXME: This is only needed on windows and probably breaks when
 501 # default_library = 'both'. We should add this flag to static_c_args instead
 502 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 503 if get_option('default_library') == 'static'
 504   gst_c_args += ['-DGST_STATIC_COMPILATION']
 505 endif
 506
 507 # Used in gst/parse/meson.build and below
 508 python3 = import('python').find_installation()
 509
 510 bashcomp_option = get_option('bash-completion')
 511 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 512 bash_completions_dir = ''
 513 bash_helpers_dir = ''
 514
 515 bashcomp_found = false
 516 if bashcomp_dep.found()
 517   bashcomp_found = true
 518   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 519   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: bashcomp_dir_override)
 520   if bash_completions_dir == ''
 521     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 522     if bashcomp_option.enabled()
 523       error(msg)
 524     else
 525       message(msg)
 526     endif
 527     bashcomp_found = false
 528   endif
 529
 530   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: bashcomp_dir_override)
 531   if bash_helpers_dir == ''
 532     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 533     if bashcomp_option.enabled()
 534       error(msg)
 535     else
 536       message(msg)
 537     endif
 538     bashcomp_found = false
 539   endif
 540 endif
 541
 542 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 543
 544 pkgconfig = import('pkgconfig')
 545 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 546 if get_option('default_library') == 'shared'
 547   # If we don't build static plugins there is no need to generate pc files
 548   plugins_pkgconfig_install_dir = disabler()
 549 endif
 550
 551 subdir('gst')
 552 subdir('libs')
 553 subdir('plugins')
 554 if not get_option('tools').disabled()
 555   subdir('tools')
 556 endif
 557 subdir('pkgconfig')
 558 subdir('tests')
 559 subdir('data')
 560 subdir('docs')
 561
 562 # xgettext is optional (on Windows for instance)
 563 if find_program('xgettext', required : get_option('nls')).found()
 564   cdata.set('ENABLE_NLS', 1)
 565   subdir('po')
 566 endif
 567
 568 subdir('scripts')
 569
 570 # Set release date
 571 if gst_version_nano == 0
 572   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 573   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'))
 574   if run_result.returncode() == 0
 575     release_date = run_result.stdout().strip()
 576     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 577     message('Package release date: ' + release_date)
 578   else
 579     # Error out if our release can't be found in the .doap file
 580     error(run_result.stderr())
 581   endif
 582 endif
 583
 584 configure_file(output : 'config.h', configuration : cdata)
 585 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 586 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 587
 588 if meson.version().version_compare('>= 0.54')
 589   plugin_names = []
 590   foreach plugin: plugins
 591     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 592     split = plugin.name().split('gst')
 593     if split.length() == 2
 594       plugin_names += [split[1]]
 595     else
 596       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 597       plugin_names += [plugin.name()]
 598     endif
 599   endforeach
 600   summary({'Plugins':plugin_names}, list_sep: ', ')
 601 endif