meson.build

   1 project('gstreamer', 'c', 'cpp',
   2   version : '1.12.2',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('library_format')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48   # FIXME: Add FATAL_WARNINGS from configure.ac
  49 endif
  50
  51 cdata = configuration_data()
  52 cdata.set('GST_VERSION_MAJOR', gst_version_major)
  53 cdata.set('GST_VERSION_MINOR', gst_version_minor)
  54 cdata.set('GST_VERSION_MICRO', gst_version_micro)
  55 cdata.set('GST_VERSION_NANO', gst_version_nano)
  56 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  57 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  58 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  59 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  60 cdata.set('GST_API_VERSION', '"1.0"')
  61 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  62 cdata.set('GST_LICENSE', '"LGPL"')
  63 cdata.set('PACKAGE', '"gstreamer"')
  64 cdata.set('PACKAGE_NAME', '"GStreamer"')
  65 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  66 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  67 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  68 cdata.set('PACKAGE_URL', '""')
  69 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  70 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  71 cdata.set('VERSION', '"@0@"'.format(gst_version))
  72 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  73 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  74 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  75 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  76
  77 if gst_version_nano > 0
  78     # Have GST_ERROR message printed when running from git
  79     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  80 else
  81     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  82 endif
  83
  84 # GStreamer package name and origin url
  85 gst_package_name = get_option('with-package-name')
  86 if gst_package_name == ''
  87   if gst_version_nano == 0
  88     gst_package_name = 'GStreamer source release'
  89   elif gst_version_nano == 1
  90     gst_package_name = 'GStreamer git'
  91   else
  92     gst_package_name = 'GStreamer prerelease'
  93   endif
  94 endif
  95 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  96 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  97
  98 # These are only needed/used by the ABI tests
  99 host_defines = [
 100   [ 'x86', 'HAVE_CPU_I386' ],
 101   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 102   [ 'arm', 'HAVE_CPU_ARM' ],
 103   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 104   [ 'mips', 'HAVE_CPU_MIPS' ],
 105   [ 'powerpc', 'HAVE_CPU_PPC' ],
 106   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 107   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 108   [ 'sparc', 'HAVE_CPU_SPARC' ],
 109   [ 'ia64', 'HAVE_CPU_IA64' ],
 110   [ 'hppa', 'HAVE_CPU_HPPA' ],
 111   [ 'm68k', 'HAVE_CPU_M68K' ],
 112   [ 's390', 'HAVE_CPU_S390' ],
 113 ]
 114 foreach h : host_defines
 115   if h.get(0) == host_machine.cpu()
 116     cdata.set(h.get(1), 1)
 117   endif
 118 endforeach
 119 # FIXME: should really be called HOST_CPU or such
 120 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 121
 122 check_headers = [
 123   'dlfcn.h',
 124   'inttypes.h',
 125   'memory.h',
 126   'poll.h',
 127   'stdint.h',
 128   'stdio_ext.h',
 129   'strings.h',
 130   'string.h',
 131   'sys/param.h',
 132   'sys/poll.h',
 133   'sys/prctl.h',
 134   'sys/socket.h',
 135   'sys/stat.h',
 136   'sys/times.h',
 137   'sys/time.h',
 138   'sys/types.h',
 139   'sys/utsname.h',
 140   'sys/wait.h',
 141   'ucontext.h',
 142   'unistd.h',
 143   'valgrind/valgrind.h',
 144   'sys/resource.h',
 145 ]
 146
 147 if host_machine.system() == 'windows'
 148   check_headers += ['winsock2.h']
 149 endif
 150
 151 foreach h : check_headers
 152   if cc.has_header(h)
 153     define = 'HAVE_' + h.underscorify().to_upper()
 154     cdata.set(define, 1)
 155   endif
 156 endforeach
 157
 158 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 159   cdata.set('HAVE_TM_GMTOFF', 1)
 160 endif
 161
 162 check_functions = [
 163   'gmtime_r',
 164   'sigaction',
 165   'getrusage',
 166   'fseeko',
 167   'ftello',
 168   'poll',
 169   'ppoll',
 170   'pselect',
 171   'getpagesize',
 172   'clock_gettime',
 173   # These are needed by libcheck
 174   'getline',
 175   'mkstemp',
 176   'alarm',
 177   'gettimeofday',
 178 ]
 179
 180 foreach f : check_functions
 181   if cc.has_function(f)
 182     define = 'HAVE_' + f.underscorify().to_upper()
 183     cdata.set(define, 1)
 184   endif
 185 endforeach
 186
 187 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 188   cdata.set('HAVE_LOCALTIME_R', 1)
 189   # Needed by libcheck
 190   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 191 endif
 192
 193 if cc.links('''#include <pthread.h>
 194                                                          int main() {
 195                                                                  pthread_setname_np("example");
 196                                                          }''', name : 'pthread_setname_np(const char*)')
 197         cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 198 endif
 199
 200 # Check for posix timers and the monotonic clock
 201 time_prefix = '#include <time.h>\n'
 202 if cdata.has('HAVE_UNISTD_H')
 203   time_prefix += '#include <unistd.h>'
 204 endif
 205
 206 posix_timers_src = time_prefix + '''
 207 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 208 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 209 #endif
 210 '''
 211 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
 212   cdata.set('HAVE_POSIX_TIMERS', 1)
 213 endif
 214
 215 monotonic_clock_src = time_prefix + '''
 216 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 217 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 218 #endif
 219 '''
 220 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
 221   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 222 endif
 223
 224 # Check for __uint128_t (gcc) by checking for 128-bit division
 225 uint128_t_src = '''int main() {
 226 static __uint128_t v1 = 100;
 227 static __uint128_t v2 = 10;
 228 static __uint128_t u;
 229 u = v1 / v2;
 230 }'''
 231 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 232   cdata.set('HAVE_UINT128_T', 1)
 233 endif
 234
 235 # All supported platforms have long long now
 236 cdata.set('HAVE_LONG_LONG', 1)
 237
 238 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 239 # building with MSVC
 240 if cc.get_id() == 'msvc'
 241   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 242 else
 243   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 244 endif
 245
 246 # -------------------------------------------------------------------------------------
 247 # config.h things needed by libcheck
 248 # -------------------------------------------------------------------------------------
 249 if cc.has_function('getpid')
 250   cdata.set('HAVE_GETPID', 1)
 251 elif host_system == 'windows' and cc.has_function('_getpid')
 252   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 253   cdata.set('HAVE__GETPID', 1)
 254 endif
 255 if cc.has_function('strdup')
 256   cdata.set('HAVE_DECL_STRDUP', 1)
 257 elif host_system == 'windows' and cc.has_function('_strdup')
 258   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 259 endif
 260 if host_machine.system() != 'windows'
 261   cdata.set('HAVE_FORK', 1)
 262 else
 263   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 264   cdata.set('HAVE_FORK', 0)
 265 endif
 266 if cc.has_function('strsignal')
 267   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 268 endif
 269 # Check for availability of types
 270 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 271   cdata.set('clockid_t', 'int')
 272 endif
 273 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 274   cdata.set('timer_t', 'int')
 275 endif
 276 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 277                       prefix : '#include <time.h>')
 278   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 279 endif
 280 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 281                       prefix : '#include <time.h>')
 282   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 283 endif
 284
 285 # Platform deps; only ws2_32 and execinfo for now
 286 platform_deps = []
 287 if host_machine.system() == 'windows'
 288   platform_deps = [cc.find_library('ws2_32')]
 289 endif
 290
 291 backtrace_deps = []
 292 if not get_option('disable_libunwind')
 293   unwind_dep = dependency('libunwind', required : false)
 294   dw_dep = dependency('libdw', required: false)
 295   backtrace_deps = [unwind_dep, dw_dep]
 296   if unwind_dep.found()
 297     cdata.set('HAVE_UNWIND', 1)
 298     if dw_dep.found()
 299       cdata.set('HAVE_DW', 1)
 300     else
 301       message('Support for backtraces is partial only.')
 302     endif
 303   else
 304     if cc.has_function('backtrace')
 305       cdata.set('HAVE_BACKTRACE', 1)
 306     else
 307         message('NO backtraces support.')
 308     endif
 309   endif
 310 endif
 311
 312 if cc.has_header('execinfo.h')
 313   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 314     cdata.set('HAVE_BACKTRACE', 1)
 315   else
 316     execinfo_dep = cc.find_library('execinfo', required : false)
 317     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 318       cdata.set('HAVE_BACKTRACE', 1)
 319       platform_deps += execinfo_dep
 320     endif
 321   endif
 322 endif
 323
 324 disable_gst_debug = get_option('disable_gst_debug')
 325 if get_option('disable_gst_debug')
 326     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
 327   add_project_arguments(['-Wno-unused'], language: 'c')
 328 endif
 329
 330 # Used by the gstutils test
 331 gmp_dep = cc.find_library('gmp', required : false)
 332 cdata.set('HAVE_GMP', gmp_dep.found())
 333 gsl_dep = cc.find_library('gsl', required : false)
 334 gslcblas_dep = cc.find_library('gslcblas', required : false)
 335 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 336 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 337
 338 # Used by gstinfo.c
 339 dl_dep = cc.find_library('dl', required : false)
 340 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 341
 342 configure_file(input : 'config.h.meson',
 343   output : 'config.h',
 344   configuration : cdata)
 345
 346
 347 configinc = include_directories('.')
 348 libsinc = include_directories('libs')
 349 privinc = include_directories('gst')
 350
 351 # Find dependencies
 352 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
 353 gobject_dep = dependency('gobject-2.0')
 354 gmodule_dep = dependency('gmodule-2.0')
 355 if host_machine.system() == 'windows'
 356     gio_dep = dependency('gio-2.0')
 357 else
 358     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
 359 endif
 360
 361 mathlib = cc.find_library('m', required : false)
 362 # Needed for timer_create/settime/delete
 363 # Also provides clock_gettime in glibc < 2.17
 364 rt_lib = cc.find_library('rt', required : false)
 365
 366 gir = find_program('g-ir-scanner', required : false)
 367 gnome = import('gnome')
 368
 369 # Fixme, not very elegant.
 370 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 371
 372 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 373     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 374     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 375     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 376     'gst_init(NULL,NULL);' ]
 377 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 378
 379 # Used by the *_mkenum.py helper scripts
 380 glib_mkenums = find_program('glib-mkenums')
 381
 382 gst_c_args = ['-DHAVE_CONFIG_H']
 383 if libtype == 'static'
 384   gst_c_args += ['-DGST_STATIC_COMPILATION']
 385 endif
 386
 387 # Used in gst/parse/meson.build and below
 388 py3 = find_program('python3', required : false)
 389 if not py3.found()
 390   # Maybe 'python' is Python 3
 391   py3 = find_program('python')
 392 endif
 393
 394 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 395
 396 bashcomp_found = bashcomp_dep.found()
 397 bash_completions_dir = ''
 398 bash_helpers_dir = ''
 399
 400 if bashcomp_found
 401   # get_pkgconfig_variable() won't let us set the prefix
 402   pkgconfig = find_program('pkg-config')
 403
 404   runcmd = run_command(pkgconfig,
 405       '--define-variable=prefix="."',
 406       '--variable=completionsdir',
 407       'bash-completion')
 408
 409   if (runcmd.returncode() == 0)
 410     bash_completions_dir = runcmd.stdout().strip()
 411   else
 412     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 413     bashcomp_found = false
 414   endif
 415
 416   runcmd = run_command(pkgconfig,
 417       '--define-variable=prefix="."',
 418       '--variable=helpersdir',
 419       'bash-completion')
 420
 421   if (runcmd.returncode() == 0)
 422     bash_helpers_dir = runcmd.stdout().strip()
 423   else
 424     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 425     bashcomp_found = false
 426   endif
 427 endif
 428
 429 subdir('gst')
 430 subdir('libs')
 431 subdir('plugins')
 432 subdir('tools')
 433 subdir('pkgconfig')
 434 subdir('tests')
 435 subdir('po')
 436 subdir('data')
 437
 438 if build_machine.system() == 'windows'
 439   message('Disabling gtk-doc while building on Windows')
 440 elif get_option('disable_gtkdoc')
 441   message('gtk-doc is disabled via options')
 442 else
 443   if find_program('gtkdoc-scan', required : false).found()
 444     subdir('docs')
 445   else
 446     message('Not building documentation as gtk-doc was not found')
 447   endif
 448 endif
 449
 450 run_command(py3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')