meson.build

   1 project('gstreamer', 'c', 'cpp',
   2   version : '1.9.2.1',
   3   meson_version : '>= 0.33.0',
   4   default_options : [ 'warning_level=1',
   5                       'c_std=gnu99',
   6                       'buildtype=debugoptimized' ])
   7
   8 gst_version = meson.project_version()
   9 version_arr = gst_version.split('.')
  10 gst_version_major = version_arr[0]
  11 gst_version_minor = version_arr[1]
  12 gst_version_micro = version_arr[2]
  13 if version_arr.length() == 4
  14   gst_version_nano = version_arr[3]
  15 else
  16   gst_version_nano = 0
  17 endif
  18
  19 apiversion = '1.0'
  20 soversion = 0
  21 # maintaining compatibility with the previous libtool versioning
  22 # current = minor * 100 + micro
  23 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  24
  25 prefix = get_option('prefix')
  26 libtype = get_option('library_format')
  27
  28 libexecdir = get_option('libexecdir')
  29 helpers_install_dir = libexecdir + '/gstreamer-1.0/'
  30
  31 cc = meson.get_compiler('c')
  32
  33 # FIXME: Meson should have a way for portably adding -fPIC when needed for use
  34 # with static libraries that are linked into shared libraries. Or, it should
  35 # add it by default with an option to turn it off if needed.
  36 pic_args = ['-fPIC']
  37 if host_machine.system() == 'windows'
  38   pic_args = []
  39 endif
  40
  41 # Ignore several spurious warnings for things gstreamer does very commonly
  42 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44 # NOTE: Only add warnings here if you are sure they're spurious
  45 if cc.get_id() == 'msvc'
  46   add_global_arguments('/wd4018', '/wd4244', '/wd4996', language : 'c')
  47 endif
  48
  49 cdata = configuration_data()
  50 cdata.set('GST_VERSION_MAJOR', gst_version_major)
  51 cdata.set('GST_VERSION_MINOR', gst_version_minor)
  52 cdata.set('GST_VERSION_MICRO', gst_version_micro)
  53 cdata.set('GST_VERSION_NANO', gst_version_nano)
  54 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  55 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  56 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  57 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  58 cdata.set('GST_API_VERSION', '"1.0"')
  59 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  60 cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  61 cdata.set('GST_LICENSE', '"LGPL"')
  62 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  63 cdata.set('GST_PACKAGE_NAME', '"GStreamer source release"')
  64 cdata.set('PACKAGE', '"gstreamer"')
  65 cdata.set('PACKAGE_NAME', '"GStreamer"')
  66 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  67 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  68 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  69 cdata.set('PACKAGE_URL', '""')
  70 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  71 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  72 cdata.set('VERSION', '"@0@"'.format(gst_version))
  73 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  74 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  75 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  76 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  77
  78 # These are only needed/used by the ABI tests
  79 host_defines = [
  80   [ 'x86', 'HAVE_CPU_I386' ],
  81   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  82   [ 'arm', 'HAVE_CPU_ARM' ],
  83   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
  84   [ 'mips', 'HAVE_CPU_MIPS' ],
  85   [ 'powerpc', 'HAVE_CPU_PPC' ],
  86   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
  87   [ 'alpha', 'HAVE_CPU_ALPHA' ],
  88   [ 'sparc', 'HAVE_CPU_SPARC' ],
  89   [ 'ia64', 'HAVE_CPU_IA64' ],
  90   [ 'hppa', 'HAVE_CPU_HPPA' ],
  91   [ 'm68k', 'HAVE_CPU_M68K' ],
  92   [ 's390', 'HAVE_CPU_S390' ],
  93 ]
  94 foreach h : host_defines
  95   if h.get(0) == host_machine.cpu()
  96     cdata.set(h.get(1), 1)
  97   endif
  98 endforeach
  99 # FIXME: should really be called HOST_CPU or such
 100 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 101
 102 check_headers = [['dlfcn.h','HAVE_DLFCN_H'],
 103   ['inttypes.h', 'HAVE_INTTYPES_H'],
 104   ['memory.h', 'HAVE_MEMORY_H'],
 105   ['poll.h', 'HAVE_POLL_H'],
 106   ['stdint.h', 'HAVE_STDINT_H'],
 107   ['stdio_ext.h', 'HAVE_STDIO_EXT_H'],
 108   ['strings.h', 'HAVE_STRINGS_H'],
 109   ['string.h', 'HAVE_STRING_H'],
 110   ['sys/param.h', 'HAVE_SYS_PARAM_H'],
 111   ['sys/poll.h', 'HAVE_SYS_POLL_H'],
 112   ['sys/prctl.h', 'HAVE_SYS_PRCTL_H'],
 113   ['sys/socket.h', 'HAVE_SYS_SOCKET_H'],
 114   ['sys/stat.h', 'HAVE_SYS_STAT_H'],
 115   ['sys/times.h', 'HAVE_SYS_TIMES_H'],
 116   ['sys/time.h', 'HAVE_SYS_TIME_H'],
 117   ['sys/types.h', 'HAVE_SYS_TYPES_H'],
 118   ['sys/utsname.h', 'HAVE_SYS_UTSNAME_H'],
 119   ['sys/wait.h', 'HAVE_SYS_WAIT_H'],
 120   ['ucontext.h', 'HAVE_UCONTEXT_H'],
 121   ['unistd.h', 'HAVE_UNISTD_H'],
 122   ['valgrind/valgrind.h', 'HAVE_VALGRIND_VALGRIND_H'],
 123 ]
 124
 125 if host_machine.system() == 'windows'
 126   check_headers += [ ['winsock2.h', 'HAVE_WINSOCK2_H'] ]
 127 endif
 128
 129 foreach h : check_headers
 130   if cc.has_header(h.get(0))
 131     cdata.set(h.get(1), 1)
 132   endif
 133 endforeach
 134
 135 gmtoff_src = '''#include <time.h>
 136 int main(void) {
 137   struct tm t;
 138   t.tm_gmtoff = 0;
 139   return 0;
 140 }
 141 '''
 142
 143 if cc.compiles(gmtoff_src, name : 'tm_gmtoff from time.h')
 144   cdata.set('HAVE_TM_GMTOFF', 1)
 145 endif
 146
 147 if cc.has_function('gmtime_r', prefix : '#include<time.h>')
 148   cdata.set('HAVE_GMTIME_R', 1)
 149 endif
 150 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 151   cdata.set('HAVE_LOCALTIME_R', 1)
 152 endif
 153 if cc.has_function('sigaction', prefix : '#include<signal.h>')
 154   cdata.set('HAVE_SIGACTION', 1)
 155 endif
 156 if cc.has_function('fseeko', prefix : '#include<stdio.h>')
 157   cdata.set('HAVE_FSEEKO', 1)
 158 endif
 159 if cc.has_function('ftello', prefix : '#include<stdio.h>')
 160   cdata.set('HAVE_FTELLO', 1)
 161 endif
 162 if cc.has_function('fsetpos', prefix : '#include<stdio.h>')
 163   cdata.set('HAVE_FSETPOS', 1)
 164 endif
 165 if cc.has_function('fgetpos', prefix : '#include<stdio.h>')
 166   cdata.set('HAVE_FGETPOS', 1)
 167 endif
 168 if cc.has_function('poll', prefix : '#include<poll.h>')
 169   cdata.set('HAVE_POLL', 1)
 170 endif
 171 if cc.has_function('pselect', prefix : '#include<sys/select.h>')
 172   cdata.set('HAVE_PSELECT', 1)
 173 endif
 174 cdata.set('HAVE_MMAP', 1)
 175
 176 if cc.has_function('posix_memalign', prefix : '#include<stdlib.h>')
 177   cdata.set('HAVE_POSIX_MEMALIGN', 1)
 178 endif
 179 if cc.has_function('getpagesize', prefix : '#include<unistd.h>')
 180   cdata.set('HAVE_GETPAGESIZE', 1)
 181 endif
 182 if cc.has_function('clock_gettime', prefix : '#include <time.h>')
 183   cdata.set('HAVE_CLOCK_GETTIME', 1)
 184 endif
 185
 186 if cc.has_type('ptrdiff_t')
 187   cdata.set('HAVE_PTRDIFF_T')
 188 endif
 189
 190 # -------------------------------------------------------------------------------------
 191 # config.h things needed by libcheck (FIXME: move into the libcheck meson.build) (tpm)
 192 # -------------------------------------------------------------------------------------
 193 # FIXME: check if it is _getpid or getpid on windows (tpm)
 194 if cc.has_function('getpid', prefix : '#include <sys/types.h>\n#include <unistd.h>')
 195   cdata.set('HAVE_GETPID', 1)
 196 elif cc.has_function('_getpid', prefix : '#include <process.h>')
 197   cdata.set('HAVE__GETPID', 1)
 198 endif
 199 # FIXME: check for _strdup() but how/where and with what includes? (windows?) (tpm)
 200 if cc.has_function('strdup', prefix : '#include <string.h>')
 201   cdata.set('HAVE_DECL_STRDUP', 1)
 202 elif cc.has_function('_strdup', prefix : '#include <string.h>')
 203   cdata.set('HAVE__STRDUP', 1)
 204 endif
 205 if cc.has_function('mkstemp', prefix : '#include <stdlib.h>')
 206   cdata.set('HAVE_MKSTEMP', 1)
 207 endif
 208 if host_machine.system() != 'windows'
 209   cdata.set('HAVE_FORK', 1)
 210 else
 211   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 212   cdata.set('HAVE_FORK', 0)
 213 endif
 214 if cc.has_function('alarm', prefix : '#include <unistd.h>')
 215   cdata.set('HAVE_ALARM', 1)
 216 endif
 217 if cc.has_function('localtime_r', prefix : '#include <time.h>')
 218   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 219 endif
 220 if cc.has_function('strsignal', prefix : '#include <string.h>')
 221   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 222 endif
 223
 224 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 225 # building with MSVC
 226 if cc.get_id() == 'msvc'
 227   cdata.set('GSTCONFIG_USE_MSVC_DECLSPEC', 1)
 228 else
 229   cdata.set('GSTCONFIG_USE_MSVC_DECLSPEC', 0)
 230 endif
 231
 232 configure_file(input : 'config.h.meson',
 233   output : 'config.h',
 234   configuration : cdata)
 235
 236
 237 configinc = include_directories('.')
 238 libsinc = include_directories('libs')
 239 privinc = include_directories('gst')
 240
 241 # Find dependencies
 242 glib_dep = dependency('glib-2.0', version : '>=2.32.0')
 243 gobject_dep = dependency('gobject-2.0')
 244 gmodule_dep = dependency('gmodule-2.0')
 245 if host_machine.system() == 'windows'
 246     gio_dep = dependency('gio-2.0')
 247 else
 248     gio_dep = [dependency('gio-2.0'), dependency('gio-unix-2.0')]
 249 endif
 250 mathlib = cc.find_library('m', required : false)
 251 rt_lib = cc.find_library('rt', required : false) # clock_gettime
 252
 253 # Platform deps; only ws2_32 for now
 254 platform_deps = []
 255 if host_machine.system() == 'windows'
 256   platform_deps = [cc.find_library('ws2_32')]
 257 endif
 258
 259 gir = find_program('g-ir-scanner', required : false)
 260 gnome = import('gnome')
 261
 262 # Fixme, not very elegant.
 263 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 264
 265 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**); gst_init(NULL,NULL);' ]
 266 vs_module_defs_dir = meson.source_root() + '/win32/common/'
 267
 268 gst_c_args = ['-DHAVE_CONFIG_H']
 269 if libtype == 'static'
 270   gst_c_args += ['-DGST_STATIC_COMPILATION']
 271 endif
 272
 273 subdir('gst')
 274 subdir('libs')
 275 subdir('plugins')
 276 subdir('tools')
 277 subdir('pkgconfig')
 278 subdir('tests')
 279
 280 gtkdoc = find_program('gtkdoc-scan', required : false)
 281 if build_machine.system() != 'windows'
 282   if gtkdoc.found()
 283     subdir('docs')
 284   else
 285     message('Not building documentation as gtk-doc was not found')
 286   endif
 287 else
 288   message('Disabling gtk-doc while building on Windows')
 289 endif
 290 subdir('po')