meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 libva_req = ['>= 0.39.0', '!= 0.99.0']
  19 glib_req = '>= 2.44.0'
  20 libwayland_req = '>= 1.11.0'
  21 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  22
  23 cc = meson.get_compiler('c')
  24
  25 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  26   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  27 endif
  28
  29 # Symbol visibility
  30 if cc.has_argument('-fvisibility=hidden')
  31   add_project_arguments('-fvisibility=hidden', language: 'c')
  32 endif
  33
  34 # Disable strict aliasing
  35 if cc.has_argument('-fno-strict-aliasing')
  36   add_project_arguments('-fno-strict-aliasing', language: 'c')
  37 endif
  38
  39 # Mandatory GST deps
  40 libm = cc.find_library('m', required : false)
  41 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  42   fallback : ['gstreamer', 'gst_dep'])
  43 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  44   fallback : ['gstreamer', 'gst_base_dep'])
  45 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  46     fallback : ['gst-plugins-base', 'pbutils_dep'])
  47 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  48     fallback : ['gst-plugins-base', 'allocators_dep'])
  49 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  50     fallback : ['gst-plugins-base', 'video_dep'])
  51 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  52     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  53 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  54     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
  55
  56 # Disable compiler warnings for unused variables and args if gst debug system is disabled
  57 if gst_dep.type_name() == 'internal'
  58   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
  59 else
  60   # We can't check that in the case of subprojects as we won't
  61   # be able to build against an internal dependency (which is not built yet)
  62   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
  63 endif
  64
  65 if gst_debug_disabled
  66   message('GStreamer debug system is disabled')
  67   add_project_arguments(cc.get_supported_arguments(['-Wno-unused']), language: 'c')
  68 else
  69   message('GStreamer debug system is enabled')
  70 endif
  71
  72 # Other deps
  73 gmodule_dep = dependency('gmodule-2.0', required: false)
  74 libva_dep = dependency('libva', version: libva_req)
  75
  76 libva_drm_dep = dependency('libva-drm', version: libva_req, required: false)
  77 libva_wayland_dep = dependency('libva-wayland', version: libva_req, required: false)
  78 libva_x11_dep = dependency('libva-x11', version: libva_req, required: false)
  79 libdrm_dep = dependency('libdrm', required: false)
  80 libudev_dep = dependency('libudev', required: false)
  81 egl_dep = dependency('egl', required: false)
  82 gl_dep = dependency('gl', required: false)
  83 glesv2_dep = dependency('glesv2', required: false)
  84 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  85   required : get_option('tests'),
  86   fallback : ['gstreamer', 'gst_check_dep'])
  87 libdl_dep = cc.find_library('dl', required: false)
  88 wayland_client_dep = dependency('wayland-client', version: libwayland_req, required: false)
  89 wayland_protocols_dep = dependency('wayland-protocols', version: '>= 1.15', required: false)
  90 wayland_scanner_bin = find_program('wayland-scanner', required: false)
  91 x11_dep = dependency('x11', required: false)
  92 xrandr_dep = dependency('xrandr', required: false)
  93 xrender_dep = dependency('xrender', required: false)
  94
  95 # some of the examples can use GTK+-3
  96 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
  97
  98 GLES_VERSION_MASK = gl_dep.found() ? 1 : 0
  99 if glesv2_dep.found()
 100   if (cc.has_header('GLES2/gl2.h', dependencies: glesv2_dep) and
 101       cc.has_header('GLES2/gl2ext.h', dependencies: glesv2_dep))
 102     GLES_VERSION_MASK += 4
 103   endif
 104   if (cc.has_header('GLES3/gl3.h', dependencies: glesv2_dep) and
 105       cc.has_header('GLES3/gl3ext.h', dependencies: glesv2_dep) and
 106       cc.has_header('GLES2/gl2ext.h', dependencies: glesv2_dep))
 107     GLES_VERSION_MASK += 8
 108   endif
 109 endif
 110
 111 USE_ENCODERS = get_option('with_encoders') != 'no'
 112 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
 113 USE_H264_FEI_ENCODER = USE_ENCODERS and cc.has_header('va/va_fei_h264.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
 114
 115 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
 116 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
 117 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
 118 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and wayland_protocols_dep.found() and wayland_scanner_bin.found() and get_option('with_wayland') != 'no'
 119 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
 120
 121 if not (USE_DRM or USE_X11 or USE_EGL or USE_GLX or USE_WAYLAND)
 122   error('No renderer API found (it is requried either DRM, X11 and/or WAYLAND)')
 123 endif
 124
 125 driverdir = libva_dep.get_pkgconfig_variable('driverdir')
 126 if driverdir == ''
 127   driverdir = '@0@/@1@/@2@'.format(get_option('prefix'), get_option('libdir'), 'dri')
 128 endif
 129
 130 cdata = configuration_data()
 131 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
 132 cdata.set('PACKAGE', '"gstreamer-vaapi"')
 133 cdata.set('VERSION', '"@0@"'.format(gst_version))
 134 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 135 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
 136 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
 137 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
 138 cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(driverdir))
 139 cdata.set10('USE_DRM', USE_DRM)
 140 cdata.set10('USE_EGL', USE_EGL)
 141 cdata.set10('USE_ENCODERS', USE_ENCODERS)
 142 cdata.set10('USE_GLX', USE_GLX)
 143 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
 144 cdata.set10('USE_H264_FEI_ENCODER', USE_H264_FEI_ENCODER)
 145 cdata.set10('USE_WAYLAND', USE_WAYLAND)
 146 cdata.set10('USE_X11', USE_X11)
 147 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 148 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 149 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 150 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 151 cdata.set('USE_GLES_VERSION_MASK', GLES_VERSION_MASK)
 152
 153 api_version = '1.0'
 154 soversion = 0
 155 # maintaining compatibility with the previous libtool versioning
 156 # current = minor * 100 + micro
 157 curversion = gst_version_minor * 100 + gst_version_micro
 158 libversion = '@0@.@1@.0'.format(soversion, curversion)
 159 osxversion = curversion + 1
 160
 161 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 162
 163 configure_file(configuration: cdata, output: 'config.h')
 164 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 165 configinc = include_directories('.')
 166 libsinc = include_directories('gst-libs')
 167
 168 subdir('gst-libs')
 169 subdir('gst')
 170 subdir('tests')
 171 subdir('docs')
 172
 173 python3 = import('python').find_installation()
 174 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')