meson.build

   1 project('gst-plugins-base', 'c', 'cpp',
   2   version : '1.9.90',
   3   meson_version : '>= 0.33.0',
   4   default_options : [ 'warning_level=1',
   5                       'c_std=gnu99',
   6                       'buildtype=debugoptimized' ])
   7
   8 gst_version = meson.project_version()
   9 version_arr = gst_version.split('.')
  10 gst_version_major = version_arr[0]
  11 gst_version_minor = version_arr[1]
  12 gst_version_micro = version_arr[2]
  13 if version_arr.length() == 4
  14   gst_version_nano = version_arr[3]
  15 else
  16   gst_version_nano = 0
  17 endif
  18
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 api_version = '1.0'
  23 soversion = 0
  24 # maintaining compatibility with the previous libtool versioning
  25 # current = minor * 100 + micro
  26 # FIXME: should be able to convert string to int somehow so we can just do maths
  27 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  28
  29 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  30
  31 cc = meson.get_compiler('c')
  32
  33 if cc.get_id() == 'msvc'
  34   # Ignore several spurious warnings for things gstreamer does very commonly
  35   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37   # NOTE: Only add warnings here if you are sure they're spurious
  38   add_global_arguments('/wd4018', '/wd4244', '/wd4996', language : 'c')
  39   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  40   # are built with MinGW
  41   noseh_link_args = ['/SAFESEH:NO']
  42 else
  43   noseh_link_args = []
  44 endif
  45
  46 core_conf = configuration_data()
  47 check_headers = [
  48   ['HAVE_DLFCN_H', 'dlfcn.h'],
  49   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  50   ['HAVE_INTTYPES_H', 'inttypes.h'],
  51   ['HAVE_MEMORY_H', 'memory.h'],
  52   ['HAVE_PROCESS_H', 'process.h'],
  53   ['HAVE_STDINT_H', 'stdint.h'],
  54   ['HAVE_STDLIB_H', 'stdlib.h'],
  55   ['HAVE_STRINGS_H', 'strings.h'],
  56   ['HAVE_STRING_H', 'string.h'],
  57   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  58   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  59   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  60   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  61   ['HAVE_UNISTD_H', 'unistd.h'],
  62   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  63   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  64 ]
  65 foreach h : check_headers
  66   if cc.has_header(h.get(1))
  67     core_conf.set(h.get(0), 1)
  68   endif
  69 endforeach
  70
  71 check_functions = [
  72   ['HAVE_DCGETTEXT', 'dcgettext'],
  73   ['HAVE_GMTIME_R', 'gmtime_r'],
  74   ['HAVE_LRINTF', 'lrintf'],
  75   ['HAVE_MMAP', 'mmap'],
  76 ]
  77
  78 foreach f : check_functions
  79   if cc.has_function(f.get(1))
  80     core_conf.set(f.get(0), 1)
  81   endif
  82 endforeach
  83
  84 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
  85 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
  86 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
  87 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
  88 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
  89
  90 core_conf.set('GETTEXT_PACKAGE', '"gst-plugins-base-1.0"')
  91 core_conf.set('PACKAGE', '"gst-plugins-base"')
  92 core_conf.set('VERSION', '"@0@"'.format(gst_version))
  93 core_conf.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  94 core_conf.set('GST_PACKAGE_NAME', '"GStreamer Base Plug-ins"')
  95 core_conf.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  96 core_conf.set('GST_API_VERSION', '"@0@"'.format(api_version))
  97 core_conf.set('GST_INSTALL_PLUGINS_HELPER', '"/FIXME"')
  98 core_conf.set('GST_DATADIR', '"/FIXME"')
  99 core_conf.set('GST_LICENSE', '"LGPL"')
 100 # FIXME: These should be configure options
 101 core_conf.set('DEFAULT_VIDEOSINK', '"autovideosink"')
 102 core_conf.set('DEFAULT_AUDIOSINK', '"autoaudiosink"')
 103
 104 # Set whether the audioresampling method should be detected at runtime
 105 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 106
 107 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 108 if get_option('default_library') == 'static'
 109   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 110 endif
 111
 112 libm = cc.find_library('m', required : false)
 113 # X11 checks are for sys/ and tests/
 114 x11_dep = dependency('x11', required : false)
 115 # GLib checks are for the entire project
 116 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 117 # Almost everything that uses glib also uses gobject
 118 glib_deps = [dependency('glib-2.0', version : glib_req),
 119              dependency('gobject-2.0', version : glib_req)]
 120 gio_dep = dependency('gio-2.0', version : glib_req)
 121
 122 core_conf.set('HAVE_X', x11_dep.found())
 123 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 124
 125 runcmd = run_command('pkg-config', '--variable=giomoduledir', 'gio-2.0')
 126 if runcmd.returncode() == 0
 127   core_conf.set('GIO_MODULE_DIR', '"@0@"'.format(runcmd.stdout().strip()))
 128 endif
 129 runcmd = run_command('pkg-config', '--variable=libdir', 'gio-2.0')
 130 if runcmd.returncode() == 0
 131   core_conf.set('GIO_LIBDIR', '"@0@"'.format(runcmd.stdout().strip()))
 132 endif
 133 runcmd = run_command('pkg-config', '--variable=prefix', 'gio-2.0')
 134 if runcmd.returncode() == 0
 135   core_conf.set('GIO_PREFIX', '"@0@"'.format(runcmd.stdout().strip()))
 136 endif
 137
 138 configinc = include_directories('.')
 139 libsinc = include_directories('gst-libs')
 140
 141 # To use the subproject make subprojects directory
 142 # and put gstreamer meson git there (symlinking is fine)
 143 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 144   fallback : ['gstreamer', 'gst_dep'])
 145 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 146   fallback : ['gstreamer', 'gst_base_dep'])
 147 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 148   fallback : ['gstreamer', 'gst_net_dep'])
 149 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 150   fallback : ['gstreamer', 'gst_check_dep'])
 151 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 152   fallback : ['gstreamer', 'gst_controller_dep'])
 153
 154 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 155
 156 # Used by the *_mkenum.py helper scripts
 157 glib_mkenums = find_program('glib-mkenums')
 158
 159 have_orcc = false
 160 orcc_args = []
 161 if get_option('use_orc') != 'no'
 162   need_orc = get_option('use_orc') == 'yes'
 163   # Used by various libraries/elements that use Orc code
 164   orc_dep = dependency('orc-0.4', version : '>= 0.4.17', required : need_orc)
 165   orcc = find_program('orcc', required : need_orc)
 166   if orc_dep.found() and orcc.found()
 167     have_orcc = true
 168     orcc_args = [orcc, '--include', 'glib.h']
 169     core_conf.set('HAVE_ORC', 1)
 170   else
 171     message('Orc Compiler not found, will use backup C code')
 172     core_conf.set('DISABLE_ORC', 1)
 173   endif
 174 else
 175   core_conf.set('DISABLE_ORC', 1)
 176 endif
 177
 178 subdir('gst-libs')
 179 subdir('gst')
 180 subdir('ext')
 181 subdir('sys')
 182 subdir('tools')
 183 subdir('tests')
 184 subdir('pkgconfig')
 185
 186 # Use core_conf after all subdirs have set values
 187 configure_file(input : 'config.h.meson',
 188   output : 'config.h',
 189   configuration : core_conf)
 190
 191 python3 = find_program('python3')
 192 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')