meson.build

   1 project('gstreamer', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.40.1',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('library_format')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48   # FIXME: Add FATAL_WARNINGS from configure.ac
  49 endif
  50
  51 # Symbol visibility
  52 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  53 if have_visibility_hidden
  54   add_project_arguments('-fvisibility=hidden', language: 'c')
  55 endif
  56
  57 cdata = configuration_data()
  58 cdata.set_quoted('GST_API_VERSION', apiversion)
  59 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  60 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  61 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  62 cdata.set_quoted('GST_API_VERSION', '1.0')
  63 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  64 cdata.set_quoted('GST_LICENSE', 'LGPL')
  65 cdata.set_quoted('PACKAGE', 'gstreamer')
  66 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  67 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  68 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  69 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  70 cdata.set_quoted('PACKAGE_URL', '')
  71 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  72 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  73 cdata.set_quoted('VERSION', gst_version)
  74 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  75 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  76 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  77 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  78 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  79   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  80
  81 if gst_version_nano > 0
  82     # Have GST_ERROR message printed when running from git
  83     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  84 else
  85     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  86 endif
  87
  88 # GStreamer package name and origin url
  89 gst_package_name = get_option('with-package-name')
  90 if gst_package_name == ''
  91   if gst_version_nano == 0
  92     gst_package_name = 'GStreamer source release'
  93   elif gst_version_nano == 1
  94     gst_package_name = 'GStreamer git'
  95   else
  96     gst_package_name = 'GStreamer prerelease'
  97   endif
  98 endif
  99 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 100 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 101
 102 # These are only needed/used by the ABI tests
 103 host_defines = [
 104   [ 'x86', 'HAVE_CPU_I386' ],
 105   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 106   [ 'arm', 'HAVE_CPU_ARM' ],
 107   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 108   [ 'mips', 'HAVE_CPU_MIPS' ],
 109   [ 'powerpc', 'HAVE_CPU_PPC' ],
 110   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 111   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 112   [ 'sparc', 'HAVE_CPU_SPARC' ],
 113   [ 'ia64', 'HAVE_CPU_IA64' ],
 114   [ 'hppa', 'HAVE_CPU_HPPA' ],
 115   [ 'm68k', 'HAVE_CPU_M68K' ],
 116   [ 's390', 'HAVE_CPU_S390' ],
 117 ]
 118 foreach h : host_defines
 119   if h.get(0) == host_machine.cpu()
 120     cdata.set(h.get(1), 1)
 121   endif
 122 endforeach
 123 # FIXME: should really be called HOST_CPU or such
 124 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 125
 126 check_headers = [
 127   'dlfcn.h',
 128   'inttypes.h',
 129   'memory.h',
 130   'poll.h',
 131   'stdint.h',
 132   'stdio_ext.h',
 133   'strings.h',
 134   'string.h',
 135   'sys/param.h',
 136   'sys/poll.h',
 137   'sys/prctl.h',
 138   'sys/socket.h',
 139   'sys/stat.h',
 140   'sys/times.h',
 141   'sys/time.h',
 142   'sys/types.h',
 143   'sys/utsname.h',
 144   'sys/wait.h',
 145   'ucontext.h',
 146   'unistd.h',
 147   'valgrind/valgrind.h',
 148   'sys/resource.h',
 149 ]
 150
 151 if host_machine.system() == 'windows'
 152   check_headers += ['winsock2.h']
 153 endif
 154
 155 foreach h : check_headers
 156   if cc.has_header(h)
 157     define = 'HAVE_' + h.underscorify().to_upper()
 158     cdata.set(define, 1)
 159   endif
 160 endforeach
 161
 162 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 163   cdata.set('HAVE_TM_GMTOFF', 1)
 164 endif
 165
 166 check_functions = [
 167   'gmtime_r',
 168   'sigaction',
 169   'getrusage',
 170   'fseeko',
 171   'ftello',
 172   'poll',
 173   'ppoll',
 174   'pselect',
 175   'getpagesize',
 176   'clock_gettime',
 177   # These are needed by libcheck
 178   'getline',
 179   'mkstemp',
 180   'alarm',
 181   'gettimeofday',
 182 ]
 183
 184 foreach f : check_functions
 185   if cc.has_function(f)
 186     define = 'HAVE_' + f.underscorify().to_upper()
 187     cdata.set(define, 1)
 188   endif
 189 endforeach
 190
 191 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 192   cdata.set('HAVE_LOCALTIME_R', 1)
 193   # Needed by libcheck
 194   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 195 endif
 196
 197 if cc.links('''#include <pthread.h>
 198                int main() {
 199                  pthread_setname_np("example"); return 0;
 200                }''', name : 'pthread_setname_np(const char*)')
 201   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 202 endif
 203
 204 # Check for posix timers and the monotonic clock
 205 time_prefix = '#include <time.h>\n'
 206 if cdata.has('HAVE_UNISTD_H')
 207   time_prefix += '#include <unistd.h>'
 208 endif
 209
 210 posix_timers_src = time_prefix + '''
 211 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 212 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 213 #endif
 214 '''
 215 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
 216   cdata.set('HAVE_POSIX_TIMERS', 1)
 217 endif
 218
 219 monotonic_clock_src = time_prefix + '''
 220 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 221 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 222 #endif
 223 '''
 224 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
 225   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 226 endif
 227
 228 # Check for __uint128_t (gcc) by checking for 128-bit division
 229 uint128_t_src = '''int main() {
 230 static __uint128_t v1 = 100;
 231 static __uint128_t v2 = 10;
 232 static __uint128_t u;
 233 u = v1 / v2;
 234 }'''
 235 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 236   cdata.set('HAVE_UINT128_T', 1)
 237 endif
 238
 239 # All supported platforms have long long now
 240 cdata.set('HAVE_LONG_LONG', 1)
 241
 242 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 243 # building with MSVC
 244 if cc.get_id() == 'msvc'
 245   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 246 else
 247   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 248 endif
 249
 250 # -------------------------------------------------------------------------------------
 251 # config.h things needed by libcheck
 252 # -------------------------------------------------------------------------------------
 253 if cc.has_function('getpid')
 254   cdata.set('HAVE_GETPID', 1)
 255 elif host_system == 'windows' and cc.has_function('_getpid')
 256   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 257   cdata.set('HAVE__GETPID', 1)
 258 endif
 259 if cc.has_function('strdup')
 260   cdata.set('HAVE_DECL_STRDUP', 1)
 261 elif host_system == 'windows' and cc.has_function('_strdup')
 262   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 263 endif
 264 if host_machine.system() != 'windows'
 265   cdata.set('HAVE_FORK', 1)
 266 else
 267   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 268   cdata.set('HAVE_FORK', 0)
 269 endif
 270 if cc.has_function('strsignal')
 271   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 272 endif
 273 # Check for availability of types
 274 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 275   cdata.set('clockid_t', 'int')
 276 endif
 277 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 278   cdata.set('timer_t', 'int')
 279 endif
 280 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 281                       prefix : '#include <time.h>')
 282   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 283 endif
 284 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 285                       prefix : '#include <time.h>')
 286   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 287 endif
 288
 289 # Platform deps; only ws2_32 and execinfo for now
 290 platform_deps = []
 291 if host_machine.system() == 'windows'
 292   platform_deps = [cc.find_library('ws2_32')]
 293 endif
 294
 295 backtrace_deps = []
 296 if not get_option('disable_libunwind')
 297   unwind_dep = dependency('libunwind', required : false)
 298   dw_dep = dependency('libdw', required: false)
 299   backtrace_deps = [unwind_dep, dw_dep]
 300   if unwind_dep.found()
 301     cdata.set('HAVE_UNWIND', 1)
 302     if dw_dep.found()
 303       cdata.set('HAVE_DW', 1)
 304     else
 305       message('Support for backtraces is partial only.')
 306     endif
 307   else
 308     if cc.has_function('backtrace')
 309       cdata.set('HAVE_BACKTRACE', 1)
 310     else
 311         message('NO backtraces support.')
 312     endif
 313   endif
 314 endif
 315
 316 if cc.has_header('execinfo.h')
 317   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 318     cdata.set('HAVE_BACKTRACE', 1)
 319   else
 320     execinfo_dep = cc.find_library('execinfo', required : false)
 321     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 322       cdata.set('HAVE_BACKTRACE', 1)
 323       platform_deps += execinfo_dep
 324     endif
 325   endif
 326 endif
 327
 328 disable_gst_debug = get_option('disable_gst_debug')
 329 if disable_gst_debug
 330   add_project_arguments(['-Wno-unused'], language: 'c')
 331 endif
 332
 333 # Used by the gstutils test
 334 gmp_dep = cc.find_library('gmp', required : false)
 335 cdata.set('HAVE_GMP', gmp_dep.found())
 336 gsl_dep = cc.find_library('gsl', required : false)
 337 gslcblas_dep = cc.find_library('gslcblas', required : false)
 338 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 339 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 340
 341 # Used by gstinfo.c
 342 dl_dep = cc.find_library('dl', required : false)
 343 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 344
 345
 346 configinc = include_directories('.')
 347 libsinc = include_directories('libs')
 348 privinc = include_directories('gst')
 349
 350 # Find dependencies
 351 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 352   fallback: ['glib', 'libglib_dep'])
 353 gobject_dep = dependency('gobject-2.0',
 354   fallback: ['glib', 'libgobject_dep'])
 355 gmodule_dep = dependency('gmodule-2.0',
 356   fallback: ['glib', 'libgmodule_dep'])
 357 if host_machine.system() == 'windows'
 358     gio_dep = dependency('gio-2.0',
 359         fallback: ['glib', 'libgio_dep'])
 360 else
 361     gio_dep = [dependency('gio-2.0',
 362                   fallback: ['glib', 'libgio_dep']),
 363                dependency('gio-unix-2.0',
 364                   fallback: ['glib', 'libgio_dep'])]
 365 endif
 366
 367 mathlib = cc.find_library('m', required : false)
 368 # Needed for timer_create/settime/delete
 369 # Also provides clock_gettime in glibc < 2.17
 370 rt_lib = cc.find_library('rt', required : false)
 371
 372 gir = find_program('g-ir-scanner', required : false)
 373 gnome = import('gnome')
 374
 375 # Fixme, not very elegant.
 376 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 377
 378 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 379     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 380     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 381     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 382     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 383     'gst_init(NULL,NULL);' ]
 384 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 385
 386 # Used by the *_mkenum.py helper scripts
 387 glib_mkenums = find_program('glib-mkenums')
 388
 389 gst_c_args = ['-DHAVE_CONFIG_H']
 390 if libtype == 'static'
 391   gst_c_args += ['-DGST_STATIC_COMPILATION']
 392 endif
 393
 394 # Used in gst/parse/meson.build and below
 395 python3 = import('python3').find_python()
 396
 397 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 398
 399 bashcomp_found = bashcomp_dep.found()
 400 bash_completions_dir = ''
 401 bash_helpers_dir = ''
 402
 403 if bashcomp_found
 404   # get_pkgconfig_variable() won't let us set the prefix
 405   pkgconfig = find_program('pkg-config')
 406
 407   runcmd = run_command(pkgconfig,
 408       '--define-variable=prefix=.',
 409       '--variable=completionsdir',
 410       'bash-completion')
 411
 412   if (runcmd.returncode() == 0)
 413     bash_completions_dir = runcmd.stdout().strip()
 414   else
 415     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 416     bashcomp_found = false
 417   endif
 418
 419   runcmd = run_command(pkgconfig,
 420       '--define-variable=prefix=.',
 421       '--variable=helpersdir',
 422       'bash-completion')
 423
 424   if (runcmd.returncode() == 0)
 425     bash_helpers_dir = runcmd.stdout().strip()
 426   else
 427     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 428     bashcomp_found = false
 429   endif
 430 endif
 431
 432 subdir('gst')
 433 subdir('libs')
 434 subdir('plugins')
 435 subdir('tools')
 436 subdir('pkgconfig')
 437 subdir('tests')
 438 subdir('po')
 439 subdir('data')
 440
 441 configure_file(output : 'config.h', configuration : cdata)
 442
 443 if build_machine.system() == 'windows'
 444   message('Disabling gtk-doc while building on Windows')
 445 elif get_option('disable_gtkdoc')
 446   message('gtk-doc is disabled via options')
 447 else
 448   if find_program('gtkdoc-scan', required : false).found()
 449     subdir('docs')
 450   else
 451     message('Not building documentation as gtk-doc was not found')
 452   endif
 453 endif
 454
 455 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 456
 457 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))