meson.build

   1 project('gst-plugins-bad', 'c', 'cpp',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 glib_req = '>= 2.44.0'
  20 orc_req = '>= 0.4.17'
  21 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  22
  23 api_version = '1.0'
  24 soversion = 0
  25 # maintaining compatibility with the previous libtool versioning
  26 # current = minor * 100 + micro
  27 curversion = gst_version_minor * 100 + gst_version_micro
  28 libversion = '@0@.@1@.0'.format(soversion, curversion)
  29 osxversion = curversion + 1
  30
  31 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  32 plugins = []
  33
  34 cc = meson.get_compiler('c')
  35 cxx = meson.get_compiler('cpp')
  36
  37 have_objc = add_languages('objc', required : false)
  38
  39 cdata = configuration_data()
  40
  41 if cc.get_id() == 'msvc'
  42   # Ignore several spurious warnings for things gstreamer does very commonly
  43   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  44   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  45   # NOTE: Only add warnings here if you are sure they're spurious
  46   msvc_args = [
  47       '/wd4018', # implicit signed/unsigned conversion
  48       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  49       '/wd4244', # lossy type conversion (e.g. double -> int)
  50       '/wd4305', # truncating type conversion (e.g. double -> float)
  51       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  52   ]
  53   add_project_arguments(msvc_args, language : 'c')
  54   add_project_arguments(msvc_args, language : 'cpp')
  55   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  56   # are built with MinGW
  57   noseh_link_args = ['/SAFESEH:NO']
  58 else
  59   if cxx.has_argument('-Wno-non-virtual-dtor')
  60     add_project_arguments('-Wno-non-virtual-dtor', language: 'cpp')
  61   endif
  62
  63   noseh_link_args = []
  64 endif
  65
  66 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  67   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  68 endif
  69
  70 # Symbol visibility
  71 if cc.get_id() == 'msvc'
  72   export_define = '__declspec(dllexport) extern'
  73 elif cc.has_argument('-fvisibility=hidden')
  74   add_project_arguments('-fvisibility=hidden', language: 'c')
  75   add_project_arguments('-fvisibility=hidden', language: 'cpp')
  76   if have_objc
  77     add_project_arguments('-fvisibility=hidden', language: 'objc')
  78   endif
  79   export_define = 'extern __attribute__ ((visibility ("default")))'
  80 else
  81   export_define = 'extern'
  82 endif
  83
  84 # Passing this through the command line would be too messy
  85 cdata.set('GST_API_EXPORT', export_define)
  86
  87 # Disable strict aliasing
  88 if cc.has_argument('-fno-strict-aliasing')
  89   add_project_arguments('-fno-strict-aliasing', language: 'c')
  90 endif
  91 if cxx.has_argument('-fno-strict-aliasing')
  92   add_project_arguments('-fno-strict-aliasing', language: 'cpp')
  93 endif
  94
  95 # Define G_DISABLE_DEPRECATED for development versions
  96 if gst_version_is_dev
  97   message('Disabling deprecated GLib API')
  98   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  99 endif
 100
 101 cast_checks = get_option('gobject-cast-checks')
 102 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 103   message('Disabling GLib cast checks')
 104   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 105 endif
 106
 107 glib_asserts = get_option('glib-asserts')
 108 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 109   message('Disabling GLib asserts')
 110   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 111 endif
 112
 113 glib_checks = get_option('glib-checks')
 114 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 115   message('Disabling GLib checks')
 116   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 117 endif
 118
 119 check_headers = [
 120   ['HAVE_DLFCN_H', 'dlfcn.h'],
 121   ['HAVE_FCNTL_H', 'fcntl.h'],
 122   ['HAVE_INTTYPES_H', 'inttypes.h'],
 123   ['HAVE_MEMORY_H', 'memory.h'],
 124   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 125   ['HAVE_NETINET_IP_H', 'netinet/ip.h'],
 126   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 127   ['HAVE_PTHREAD_H', 'pthread.h'],
 128   ['HAVE_STDINT_H', 'stdint.h'],
 129   ['HAVE_STDLIB_H', 'stdlib.h'],
 130   ['HAVE_STRINGS_H', 'strings.h'],
 131   ['HAVE_STRING_H', 'string.h'],
 132   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 133   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 134   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 135   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 136   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 137   ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
 138   ['HAVE_UNISTD_H', 'unistd.h'],
 139   ['HAVE_WINDOWS_H', 'windows.h'],
 140   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 141   ['HAVE_WS2TCPIP_H', 'ws2tcpip.h'],
 142 ]
 143
 144 foreach h : check_headers
 145   if cc.has_header(h.get(1))
 146     cdata.set(h.get(0), 1)
 147   endif
 148 endforeach
 149
 150 check_functions = [
 151   ['HAVE_DCGETTEXT', 'dcgettext'],
 152   ['HAVE_GETPAGESIZE', 'getpagesize'],
 153   ['HAVE_GMTIME_R', 'gmtime_r'],
 154   ['HAVE_MMAP', 'mmap'],
 155   ['HAVE_PIPE2', 'pipe2'],
 156   ['HAVE_GETRUSAGE', 'getrusage', '#include<sys/resource.h>'],
 157 ]
 158
 159 foreach f : check_functions
 160   prefix = ''
 161   if f.length() == 3
 162     prefix = f.get(2)
 163   endif
 164   if cc.has_function(f.get(1), prefix: prefix)
 165     cdata.set(f.get(0), 1)
 166   endif
 167 endforeach
 168
 169 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 170 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 171 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 172 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 173 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 174
 175 cdata.set_quoted('VERSION', gst_version)
 176 cdata.set_quoted('PACKAGE', 'gst-plugins-bad')
 177 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 178 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 179 cdata.set_quoted('PACKAGE_NAME', 'GStreamer Bad Plug-ins')
 180 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-bad-1.0')
 181 cdata.set_quoted('GST_API_VERSION', api_version)
 182 cdata.set_quoted('GST_LICENSE', 'LGPL')
 183 cdata.set_quoted('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
 184 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 185
 186 warning_flags = [
 187   '-Wmissing-declarations',
 188   '-Wredundant-decls',
 189   '-Wwrite-strings',
 190   '-Wformat',
 191   '-Wformat-security',
 192   '-Winit-self',
 193   '-Wmissing-include-dirs',
 194   '-Waddress',
 195   '-Wno-multichar',
 196   '-Wvla',
 197   '-Wpointer-arith',
 198 ]
 199
 200 warning_c_flags = [
 201   '-Wmissing-prototypes',
 202   '-Wdeclaration-after-statement',
 203   '-Wold-style-definition',
 204 ]
 205
 206 warning_cxx_flags = [
 207   '-Wformat-nonliteral',
 208 ]
 209
 210 foreach extra_arg : warning_c_flags
 211   if cc.has_argument (extra_arg)
 212     add_project_arguments([extra_arg], language: 'c')
 213   endif
 214 endforeach
 215
 216 foreach extra_arg : warning_cxx_flags
 217   if cxx.has_argument (extra_arg)
 218     add_project_arguments([extra_arg], language: 'cpp')
 219   endif
 220 endforeach
 221
 222 foreach extra_arg : warning_flags
 223   if cc.has_argument (extra_arg)
 224     add_project_arguments([extra_arg], language: 'c')
 225   endif
 226   if cxx.has_argument (extra_arg)
 227     add_project_arguments([extra_arg], language: 'cpp')
 228   endif
 229 endforeach
 230
 231 # GStreamer package name and origin url
 232 gst_package_name = get_option('package-name')
 233 if gst_package_name == ''
 234   if gst_version_nano == 0
 235     gst_package_name = 'GStreamer Bad Plug-ins source release'
 236   elif gst_version_nano == 1
 237     gst_package_name = 'GStreamer Bad Plug-ins git'
 238   else
 239     gst_package_name = 'GStreamer Bad Plug-ins prerelease'
 240   endif
 241 endif
 242 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 243 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 244
 245 # FIXME: This should be exposed as a configuration option
 246 host_system = host_machine.system()
 247 if host_system == 'linux'
 248   cdata.set_quoted('DEFAULT_VIDEOSRC', 'v4l2src')
 249 elif ['darwin', 'ios'].contains(host_system)
 250   cdata.set_quoted('DEFAULT_VIDEOSRC', 'avfvideosrc')
 251   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 252   # Yes, we set this for iOS too. Same as Autotools.
 253   cdata.set('HAVE_OSX', 1)
 254 else
 255   cdata.set_quoted('DEFAULT_VIDEOSRC', 'videotestsrc')
 256 endif
 257
 258 # Mandatory GST deps
 259 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 260   fallback : ['gstreamer', 'gst_dep'])
 261 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 262   fallback : ['gstreamer', 'gst_base_dep'])
 263 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 264   fallback : ['gstreamer', 'gst_net_dep'])
 265 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 266   fallback : ['gstreamer', 'gst_controller_dep'])
 267
 268 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 269     fallback : ['gst-plugins-base', 'pbutils_dep'])
 270 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 271     fallback : ['gst-plugins-base', 'allocators_dep'])
 272 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 273     fallback : ['gst-plugins-base', 'app_dep'])
 274 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 275     fallback : ['gst-plugins-base', 'audio_dep'])
 276 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 277     fallback : ['gst-plugins-base', 'fft_dep'])
 278 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 279     fallback : ['gst-plugins-base', 'riff_dep'])
 280 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 281     fallback : ['gst-plugins-base', 'rtp_dep'])
 282 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 283     fallback : ['gst-plugins-base', 'rtsp_dep'])
 284 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 285     fallback : ['gst-plugins-base', 'sdp_dep'])
 286 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 287     fallback : ['gst-plugins-base', 'tag_dep'])
 288 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 289     fallback : ['gst-plugins-base', 'video_dep'])
 290 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 291     required : get_option('tests'),
 292     fallback : ['gstreamer', 'gst_check_dep'])
 293
 294 # GStreamer OpenGL
 295 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 296     fallback : ['gst-plugins-base', 'gstgl_dep'], required: get_option('gl'))
 297
 298 if gstgl_dep.found()
 299   if gstgl_dep.type_name() == 'pkgconfig'
 300     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 301     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 302     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 303   else
 304     gstbase = subproject('gst-plugins-base')
 305     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 306     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 307     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 308   endif
 309
 310   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 311   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 312   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 313
 314   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 315     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 316   endforeach
 317
 318   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 319     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 320   endforeach
 321
 322   foreach api : ['gl', 'gles2']
 323     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 324     # temporary backwards compat for older meson-generated .pc file with 'opengl' instead of 'gl'
 325     if gst_gl_apis.contains('opengl')
 326       gst_gl_have_api_gl = true
 327     endif
 328   endforeach
 329 endif
 330
 331 libm = cc.find_library('m', required : false)
 332 glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
 333 gmodule_dep = dependency('gmodule-2.0', fallback: ['glib', 'libgmodule_dep'])
 334 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 335 # gio-unix-2.0 is used by sys/bluez
 336
 337 # Optional dep of ext/gl and gst/librfb
 338 x11_dep = dependency('x11', required : get_option('x11'))
 339 if x11_dep.found()
 340   cdata.set('HAVE_X11', 1)
 341 endif
 342
 343 if host_machine.system() == 'windows'
 344   winsock2 = [cc.find_library('ws2_32')]
 345 else
 346   winsock2 = []
 347 endif
 348
 349 if ['darwin', 'ios'].contains(host_system)
 350   if not have_objc
 351     error('Building on MacOS/iOS/etc requires an ObjC compiler')
 352   endif
 353   if host_system == 'ios'
 354     cdata.set('HAVE_IOS', 1)
 355   endif
 356
 357   avfoundation_dep = dependency('AVFoundation', required : false)
 358   if avfoundation_dep.found()
 359       cdata.set('HAVE_AVFOUNDATION', 1)
 360   endif
 361
 362   videotoolbox_dep = dependency('VideoToolbox', required : false)
 363   if videotoolbox_dep.found()
 364       cdata.set('HAVE_VIDEOTOOLBOX', 1)
 365   endif
 366
 367 #  FIXME: framework.version() returns 'unknown'
 368 #  if videotoolbox_dep.version().version_compare('>=10.9.6')
 369 #    cdata.set('HAVE_VIDEOTOOLBOX_10_9_6', 1)
 370 #  endif
 371 endif
 372 have_objcpp = add_languages('objcpp', required : false)
 373
 374 have_orcc = false
 375 orcc_args = []
 376 # Used by various libraries/elements that use Orc code
 377 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 378     fallback : ['orc', 'orc_dep'])
 379 orcc = find_program('orcc', required : get_option('orc'))
 380 if orc_dep.found() and orcc.found()
 381   have_orcc = true
 382   orcc_args = [orcc, '--include', 'glib.h']
 383   cdata.set('HAVE_ORC', 1)
 384 else
 385   message('Orc Compiler not found or disabled, will use backup C code')
 386   cdata.set('DISABLE_ORC', 1)
 387 endif
 388 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 389
 390 gnustl_dep = declare_dependency()
 391 if host_system == 'android'
 392   gnustl_dep = dependency('gnustl', required : false)
 393 endif
 394
 395 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 396 if gst_dep.type_name() == 'internal'
 397   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 398 else
 399   # We can't check that in the case of subprojects as we won't
 400   # be able to build against an internal dependency (which is not built yet)
 401   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 402 endif
 403
 404 if gst_debug_disabled
 405   message('GStreamer debug system is disabled')
 406   if cc.has_argument('-Wno-unused')
 407     add_project_arguments('-Wno-unused', language: 'c')
 408   endif
 409   if cxx.has_argument ('-Wno-unused')
 410     add_project_arguments('-Wno-unused', language: 'cpp')
 411   endif
 412 else
 413   message('GStreamer debug system is enabled')
 414 endif
 415
 416 gst_plugins_bad_args = ['-DHAVE_CONFIG_H']
 417 configinc = include_directories('.')
 418 libsinc = include_directories('gst-libs')
 419
 420 python3 = import('python').find_installation()
 421
 422 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 423 gnome = import('gnome')
 424 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 425 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 426     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 427     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 428     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 429     'gst_init(NULL,NULL);', '--quiet']
 430
 431 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 432
 433 pkgconfig = import('pkgconfig')
 434 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 435 if get_option('default_library') == 'shared'
 436   # If we don't build static plugins there is no need to generate pc files
 437   plugins_pkgconfig_install_dir = disabler()
 438 endif
 439
 440 subdir('gst-libs')
 441 subdir('gst')
 442 subdir('sys')
 443 subdir('ext')
 444 subdir('tests')
 445 subdir('data')
 446 subdir('tools')
 447 subdir('pkgconfig')
 448
 449 # xgettext is optional (on Windows for instance)
 450 if find_program('xgettext', required : get_option('nls')).found()
 451   cdata.set('ENABLE_NLS', 1)
 452   subdir('po')
 453 endif
 454
 455 configure_file(output : 'config.h', configuration : cdata)
 456
 457 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 458
 459 subdir('docs')