meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.18.0',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', native: false, required: false)
  20
  21 glib_req = '>= 2.44.0'
  22 orc_req = '>= 0.4.17'
  23 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  24
  25 api_version = '1.0'
  26
  27 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  28 plugins = []
  29
  30 cc = meson.get_compiler('c')
  31 host_system = host_machine.system()
  32
  33 if cc.get_id() == 'msvc'
  34   # Ignore several spurious warnings for things gstreamer does very commonly
  35   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37   # NOTE: Only add warnings here if you are sure they're spurious
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  44       language : 'c')
  45   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  46   # are built with MinGW
  47   noseh_link_args = ['/SAFESEH:NO']
  48 else
  49   noseh_link_args = []
  50 endif
  51
  52 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  53   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  54 endif
  55
  56 # Symbol visibility
  57 if cc.has_argument('-fvisibility=hidden')
  58   add_project_arguments('-fvisibility=hidden', language: 'c')
  59 endif
  60
  61 # Disable strict aliasing
  62 if cc.has_argument('-fno-strict-aliasing')
  63   add_project_arguments('-fno-strict-aliasing', language: 'c')
  64 endif
  65
  66 # Define G_DISABLE_DEPRECATED for development versions
  67 if gst_version_is_dev
  68   message('Disabling deprecated GLib API')
  69   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  70 endif
  71
  72 cast_checks = get_option('gobject-cast-checks')
  73 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  74   message('Disabling GLib cast checks')
  75   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  76 endif
  77
  78 glib_asserts = get_option('glib-asserts')
  79 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  80   message('Disabling GLib asserts')
  81   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  82 endif
  83
  84 glib_checks = get_option('glib-checks')
  85 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  86   message('Disabling GLib checks')
  87   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  88 endif
  89
  90 cdata = configuration_data()
  91
  92 check_headers = [
  93   ['HAVE_DLFCN_H', 'dlfcn.h'],
  94   ['HAVE_FCNTL_H', 'fcntl.h'],
  95   ['HAVE_INTTYPES_H', 'inttypes.h'],
  96   ['HAVE_MEMORY_H', 'memory.h'],
  97   ['HAVE_PROCESS_H', 'process.h'],
  98   ['HAVE_STDINT_H', 'stdint.h'],
  99   ['HAVE_STDLIB_H', 'stdlib.h'],
 100   ['HAVE_STRINGS_H', 'strings.h'],
 101   ['HAVE_STRING_H', 'string.h'],
 102   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
 103   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 104   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 105   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 106   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 107   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 108   ['HAVE_UNISTD_H', 'unistd.h'],
 109 ]
 110
 111 foreach h : check_headers
 112   if cc.has_header(h.get(1))
 113     cdata.set(h.get(0), 1)
 114   endif
 115 endforeach
 116
 117 check_functions = [
 118   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
 119   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
 120   ['HAVE_COSH', 'cosh', '#include<math.h>'],
 121 # check token HAVE_CPU_ALPHA
 122 # check token HAVE_CPU_ARM
 123 # check token HAVE_CPU_CRIS
 124 # check token HAVE_CPU_CRISV32
 125 # check token HAVE_CPU_HPPA
 126 # check token HAVE_CPU_I386
 127 # check token HAVE_CPU_IA64
 128 # check token HAVE_CPU_M68K
 129 # check token HAVE_CPU_MIPS
 130 # check token HAVE_CPU_PPC
 131 # check token HAVE_CPU_PPC64
 132 # check token HAVE_CPU_S390
 133 # check token HAVE_CPU_SPARC
 134 # check token HAVE_CPU_X86_64
 135   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 136 # check token HAVE_DIRECTSOUND
 137 # check token HAVE_EXPERIMENTAL
 138 # check token HAVE_EXTERNAL
 139 # check token HAVE_FPCLASS
 140 # check token HAVE_GCC_ASM
 141   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 142 # check token HAVE_GETTEXT
 143 # check token HAVE_GST_V4L2
 144   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 145 # check token HAVE_LIBV4L2
 146   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 147   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 148 # check token HAVE_OSX_AUDIO
 149 # check token HAVE_OSX_VIDEO
 150 # check token HAVE_RDTSC
 151   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 152 # check token HAVE_WAVEFORM
 153   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 154 ]
 155
 156 libm = cc.find_library('m', required : false)
 157
 158 foreach f : check_functions
 159   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 160     cdata.set(f.get(0), 1)
 161   endif
 162 endforeach
 163
 164 cdata.set('HAVE_IOS', host_system == 'ios')
 165
 166 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 167 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 168 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 169 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 170 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 171 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 172
 173 # Here be fixmes.
 174 # FIXME: check if this is correct
 175 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 176 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 177 cdata.set_quoted('VERSION', gst_version)
 178 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 179 cdata.set_quoted('GST_LICENSE', 'LGPL')
 180 cdata.set_quoted('PACKAGE', 'gst-plugins-good')
 181 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-good-1.0')
 182 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 183
 184 warning_flags = [
 185   '-Wmissing-declarations',
 186   '-Wredundant-decls',
 187   '-Wwrite-strings',
 188   '-Winit-self',
 189   '-Wmissing-include-dirs',
 190   '-Wno-multichar',
 191   '-Wvla',
 192   '-Wpointer-arith',
 193 ]
 194
 195 warning_c_flags = [
 196   '-Wmissing-prototypes',
 197   '-Wdeclaration-after-statement',
 198   '-Wold-style-definition',
 199   '-Waggregate-return',
 200 ]
 201
 202 if have_cxx
 203   cxx = meson.get_compiler('cpp')
 204 endif
 205
 206 foreach extra_arg : warning_flags
 207   if cc.has_argument (extra_arg)
 208     add_project_arguments([extra_arg], language: 'c')
 209   endif
 210   if have_cxx and cxx.has_argument (extra_arg)
 211     add_project_arguments([extra_arg], language: 'cpp')
 212   endif
 213 endforeach
 214
 215 foreach extra_arg : warning_c_flags
 216   if cc.has_argument (extra_arg)
 217     add_project_arguments([extra_arg], language: 'c')
 218   endif
 219 endforeach
 220
 221 # GStreamer package name and origin url
 222 gst_package_name = get_option('package-name')
 223 if gst_package_name == ''
 224   if gst_version_nano == 0
 225     gst_package_name = 'GStreamer Good Plug-ins source release'
 226   elif gst_version_nano == 1
 227     gst_package_name = 'GStreamer Good Plug-ins git'
 228   else
 229     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 230   endif
 231 endif
 232 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 233 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 234
 235 # Mandatory GST deps
 236 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 237   fallback : ['gstreamer', 'gst_dep'])
 238 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 239   fallback : ['gstreamer', 'gst_base_dep'])
 240 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 241   fallback : ['gstreamer', 'gst_net_dep'])
 242 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 243   fallback : ['gstreamer', 'gst_controller_dep'])
 244 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 245   required : get_option('tests'),
 246   fallback : ['gstreamer', 'gst_check_dep'])
 247 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 248     fallback : ['gst-plugins-base', 'pbutils_dep'])
 249 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 250     fallback : ['gst-plugins-base', 'allocators_dep'])
 251 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 252     fallback : ['gst-plugins-base', 'app_dep'])
 253 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 254     fallback : ['gst-plugins-base', 'audio_dep'])
 255 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 256     fallback : ['gst-plugins-base', 'fft_dep'])
 257 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 258     fallback : ['gst-plugins-base', 'riff_dep'])
 259 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 260     fallback : ['gst-plugins-base', 'rtp_dep'])
 261 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 262     fallback : ['gst-plugins-base', 'rtsp_dep'])
 263 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 264     fallback : ['gst-plugins-base', 'sdp_dep'])
 265 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 266     fallback : ['gst-plugins-base', 'tag_dep'])
 267 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 268     fallback : ['gst-plugins-base', 'video_dep'])
 269
 270 # GStreamer OpenGL
 271 # FIXME: automagic
 272 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 273     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
 274 gstglproto_dep = dependency('', required : false)
 275 gstglx11_dep = dependency('', required : false)
 276 gstglwayland_dep = dependency('', required : false)
 277 gstglegl_dep = dependency('', required : false)
 278
 279 have_gstgl = gstgl_dep.found()
 280
 281 if have_gstgl
 282   if gstgl_dep.type_name() == 'pkgconfig'
 283     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 284     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 285     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 286   else
 287     gstbase = subproject('gst-plugins-base')
 288     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 289     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 290     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 291   endif
 292
 293   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 294   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 295   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 296
 297   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 298     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 299   endforeach
 300
 301   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 302     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 303   endforeach
 304
 305   foreach api : ['gl', 'gles2']
 306     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 307   endforeach
 308
 309   gstglproto_dep = dependency('gstreamer-gl-prototypes-1.0', version : gst_req,
 310       fallback : ['gst-plugins-base', 'gstglproto_dep'], required: true)
 311   # Behind specific checks because meson fails at optional dependencies with a
 312   # fallback to the same subproject.  On the first failure, meson will never
 313   # check the system again even if the fallback never existed.
 314   # Last checked with meson 0.54.3
 315   if gst_gl_have_window_x11
 316     gstglx11_dep = dependency('gstreamer-gl-x11-1.0', version : gst_req,
 317        fallback : ['gst-plugins-base', 'gstglx11_dep'], required: true)
 318   endif
 319   if gst_gl_have_window_wayland
 320     gstglwayland_dep = dependency('gstreamer-gl-wayland-1.0', version : gst_req,
 321         fallback : ['gst-plugins-base', 'gstglwayland_dep'], required: true)
 322   endif
 323   if gst_gl_have_platform_egl
 324     gstglegl_dep = dependency('gstreamer-gl-egl-1.0', version : gst_req,
 325         fallback : ['gst-plugins-base', 'gstglegl_dep'], required: true)
 326   endif
 327 endif
 328
 329 zlib_dep = dependency('zlib', required : false)
 330 if not zlib_dep.found()
 331   zlib_dep = cc.find_library('z', required : false)
 332   if not zlib_dep.found() or not cc.has_header('zlib.h')
 333     zlib_dep = subproject('zlib').get_variable('zlib_dep')
 334   endif
 335 endif
 336 cdata.set('HAVE_ZLIB', true)
 337
 338 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 339              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 340 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 341
 342 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 343 configinc = include_directories('.')
 344 libsinc = include_directories('gst-libs')
 345
 346 have_orcc = false
 347 orcc_args = []
 348 orc_targets = []
 349 # Used by various libraries/elements that use Orc code
 350 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 351     fallback : ['orc', 'orc_dep'])
 352 orcc = find_program('orcc', required : get_option('orc'))
 353 if orc_dep.found() and orcc.found()
 354   have_orcc = true
 355   orcc_args = [orcc, '--include', 'glib.h']
 356   cdata.set('HAVE_ORC', 1)
 357 else
 358   message('Orc Compiler not found, will use backup C code')
 359   cdata.set('DISABLE_ORC', 1)
 360 endif
 361
 362 have_nasm = false
 363 # FIXME: nasm path needs testing on non-Linux, esp. Windows
 364 host_cpu = host_machine.cpu_family()
 365 if host_cpu == 'x86_64'
 366   if cc.get_id() == 'msvc'
 367     message('Nasm disabled on MSVC')
 368   elif cc.get_define('__ILP32__') == '1'
 369     message('Nasm disabled on x32')
 370   else
 371     asm_option = get_option('asm')
 372     nasm = find_program('nasm', native: true, required: asm_option)
 373     if nasm.found()
 374       # We can't use the version: kwarg for find_program because old versions
 375       # of nasm don't support --version
 376       ret = run_command(nasm, '-v')
 377       if ret.returncode() == 0
 378         nasm_version = ret.stdout().strip().split()[2]
 379         nasm_req = '>=2.13'
 380         if nasm_version.version_compare(nasm_req)
 381           message('nasm found on x86-64')
 382           cdata.set('HAVE_NASM', 1)
 383           have_nasm = true
 384         else
 385           if asm_option.enabled()
 386             error('asm option is enabled, and nasm @0@ was found, but @1@ is required'.format(nasm_version, nasm_req))
 387           endif
 388           message('nasm @0@ was found, but @1@ is required'.format(nasm_version, nasm_req))
 389         endif
 390       else
 391         if asm_option.enabled()
 392           error('asm option is enabled, but nasm is not usable: @0@\n@1@'.format(ret.stdout(), ret.stderr()))
 393         endif
 394         message('nasm was found, but it\'s not usable')
 395       endif
 396       # Unset nasm to not be 'found'
 397       if not have_nasm
 398         nasm = disabler()
 399       endif
 400     endif
 401   endif
 402 endif
 403
 404 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 405 if gst_dep.type_name() == 'internal'
 406   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 407 else
 408   # We can't check that in the case of subprojects as we won't
 409   # be able to build against an internal dependency (which is not built yet)
 410   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 411 endif
 412
 413 if gst_debug_disabled
 414   message('GStreamer debug system is disabled')
 415   if cc.has_argument('-Wno-unused')
 416     add_project_arguments('-Wno-unused', language: 'c')
 417   endif
 418   if have_cxx and cxx.has_argument ('-Wno-unused')
 419     add_project_arguments('-Wno-unused', language: 'cpp')
 420   endif
 421 else
 422   message('GStreamer debug system is enabled')
 423 endif
 424
 425 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 426
 427 python3 = import('python').find_installation()
 428 pkgconfig = import('pkgconfig')
 429 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 430 if get_option('default_library') == 'shared'
 431   # If we don't build static plugins there is no need to generate pc files
 432   plugins_pkgconfig_install_dir = disabler()
 433 endif
 434
 435 subdir('gst')
 436 subdir('sys')
 437 subdir('ext')
 438 subdir('tests')
 439 subdir('docs')
 440
 441 if have_orcc and orc_targets.length() > 0
 442   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 443
 444   orc_update_targets = []
 445   foreach t : orc_targets
 446     orc_name = t.get('name')
 447     orc_file = t.get('orc-source')
 448     header = t.get('header')
 449     source = t.get('source')
 450     # alias_target() only works with build targets, so can't use run_target() here
 451     orc_update_targets += [
 452       custom_target('update-orc-@0@'.format(orc_name),
 453         input: [header, source],
 454         command: [update_orc_dist_files, orc_file, header, source],
 455         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 456     ]
 457   endforeach
 458
 459   if meson.version().version_compare('>= 0.52')
 460     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 461   endif
 462 endif
 463
 464 # xgettext is optional (on Windows for instance)
 465 if find_program('xgettext', required : get_option('nls')).found()
 466   cdata.set('ENABLE_NLS', 1)
 467   subdir('po')
 468 endif
 469
 470 subdir('scripts')
 471
 472 # Set release date
 473 if gst_version_nano == 0
 474   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 475   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-good.doap'))
 476   if run_result.returncode() == 0
 477     release_date = run_result.stdout().strip()
 478     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 479     message('Package release date: ' + release_date)
 480   else
 481     # Error out if our release can't be found in the .doap file
 482     error(run_result.stderr())
 483   endif
 484 endif
 485
 486 configure_file(output : 'config.h', configuration : cdata)
 487
 488 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 489
 490 if meson.version().version_compare('>= 0.54')
 491   plugin_names = []
 492   foreach plugin: plugins
 493     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 494     split = plugin.name().split('gst')
 495     if split.length() == 2
 496       plugin_names += [split[1]]
 497     else
 498       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 499       plugin_names += [plugin.name()]
 500     endif
 501   endforeach
 502   summary({'Plugins':plugin_names}, list_sep: ', ')
 503 endif