meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 api_version = '1.0'
  22
  23 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  24
  25 cc = meson.get_compiler('c')
  26
  27 if cc.get_id() == 'msvc'
  28   # Ignore several spurious warnings for things gstreamer does very commonly
  29   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31   # NOTE: Only add warnings here if you are sure they're spurious
  32   add_project_arguments(
  33       '/wd4018', # implicit signed/unsigned conversion
  34       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  35       '/wd4244', # lossy type conversion (e.g. double -> int)
  36       '/wd4305', # truncating type conversion (e.g. double -> float)
  37       language : 'c')
  38   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  39   # are built with MinGW
  40   noseh_link_args = ['/SAFESEH:NO']
  41 else
  42   noseh_link_args = []
  43 endif
  44
  45 cdata = configuration_data()
  46 check_headers = [
  47   ['HAVE_DLFCN_H', 'dlfcn.h'],
  48   ['HAVE_INTTYPES_H', 'inttypes.h'],
  49   ['HAVE_MALLOC_H', 'malloc.h'],
  50   ['HAVE_MEMORY_H', 'memory.h'],
  51   ['HAVE_STDINT_H', 'stdint.h'],
  52   ['HAVE_STDLIB_H', 'stdlib.h'],
  53   ['HAVE_STRINGS_H', 'strings.h'],
  54   ['HAVE_STRING_H', 'string.h'],
  55   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  56   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  57   ['HAVE_UNISTD_H', 'unistd.h'],
  58   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  59 ]
  60
  61 foreach h : check_headers
  62   if cc.has_header(h.get(1))
  63     cdata.set(h.get(0), 1)
  64   endif
  65 endforeach
  66
  67 check_functions = [
  68 # check token HAVE_CPU_ALPHA
  69 # check token HAVE_CPU_ARM
  70 # check token HAVE_CPU_CRIS
  71 # check token HAVE_CPU_CRISV32
  72 # check token HAVE_CPU_HPPA
  73 # check token HAVE_CPU_I386
  74 # check token HAVE_CPU_IA64
  75 # check token HAVE_CPU_M68K
  76 # check token HAVE_CPU_MIPS
  77 # check token HAVE_CPU_PPC
  78 # check token HAVE_CPU_PPC64
  79 # check token HAVE_CPU_S390
  80 # check token HAVE_CPU_SPARC
  81 # check token HAVE_CPU_X86_64
  82   ['HAVE_DCGETTEXT', 'dcgettext'],
  83 # check token HAVE_EXPERIMENTAL
  84 # check token HAVE_EXTERNAL
  85 # check token HAVE_GETTEXT
  86 # check token HAVE_VALGRIND
  87 ]
  88
  89 foreach f : check_functions
  90   if cc.has_function(f.get(1))
  91     cdata.set(f.get(0), 1)
  92   endif
  93 endforeach
  94
  95 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
  96 cdata.set('SIZEOF_INT', cc.sizeof('int'))
  97 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
  98 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
  99 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 100
 101 cdata.set('VERSION', '"@0@"'.format(gst_version))
 102 cdata.set('PACKAGE', '"gst-plugins-ugly"')
 103 cdata.set('GETTEXT_PACKAGE', '"gst-plugins-ugly-1.0"')
 104 cdata.set('GST_LICENSE', '"LGPL"')
 105
 106 # GStreamer package name and origin url
 107 gst_package_name = get_option('with-package-name')
 108 if gst_package_name == ''
 109   if gst_version_nano == 0
 110     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer Ugly Plug-ins source release')
 111   elif gst_version_nano == 1
 112     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer Ugly Plug-ins git')
 113   else
 114     cdata.set_quoted('GST_PACKAGE_NAME', 'GStreamer Ugly Plug-ins prerelease')
 115   endif
 116 endif
 117 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 118
 119 # Mandatory GST deps
 120 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 121     fallback : ['gstreamer', 'gst_dep'])
 122 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 123     fallback : ['gst-plugins-base', 'app_dep'])
 124 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 125     fallback : ['gst-plugins-base', 'video_dep'])
 126 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 127     fallback : ['gst-plugins-base', 'pbutils_dep'])
 128 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 129     fallback : ['gst-plugins-base', 'tag_dep'])
 130 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 131     fallback : ['gst-plugins-base', 'fft_dep'])
 132 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 133     fallback : ['gst-plugins-base', 'audio_dep'])
 134 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 135   fallback : ['gstreamer', 'gst_base_dep'])
 136 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 137     fallback : ['gst-plugins-base', 'riff_dep'])
 138 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 139     fallback : ['gst-plugins-base', 'rtp_dep'])
 140 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 141   fallback : ['gstreamer', 'gst_net_dep'])
 142 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 143     fallback : ['gst-plugins-base', 'sdp_dep'])
 144 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 145     fallback : ['gst-plugins-base', 'rtsp_dep'])
 146 if host_machine.system() != 'windows'
 147   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 148     fallback : ['gstreamer', 'gst_check_dep'])
 149 endif
 150 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 151   fallback : ['gstreamer', 'gst_controller_dep'])
 152
 153 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : false)
 154 if orc_dep.found()
 155   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 156 else
 157   cdata.set('DISABLE_ORC', 1)
 158 endif
 159
 160 configure_file(input : 'config.h.meson',
 161   output : 'config.h',
 162   configuration : cdata)
 163
 164 ugly_args = ['-DHAVE_CONFIG_H']
 165 configinc = include_directories('.')
 166 libsinc = include_directories('gst-libs')
 167
 168 if gst_dep.type_name() == 'internal'
 169     gst_proj = subproject('gstreamer')
 170
 171     if gst_proj.get_variable('disable_gst_debug')
 172         message('GStreamer debug system is disabled')
 173         add_project_arguments('-Wno-unused', language: 'c')
 174     else
 175         message('GStreamer debug system is enabled')
 176     endif
 177 else
 178     # We can't check that in the case of subprojects as we won't
 179     # be able to build against an internal dependency (which is not built yet)
 180     if not cc.compiles('''
 181 #include <gst/gstconfig.h>
 182 #ifdef GST_DISABLE_GST_DEBUG
 183 #error "debugging disabled, make compiler fail"
 184 #endif''' , dependencies: gst_dep)
 185         message('GStreamer debug system is disabled')
 186         add_global_arguments('-Wno-unused', language: 'c')
 187     else
 188         message('GStreamer debug system is enabled')
 189     endif
 190 endif
 191
 192 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 193 subdir('gst')
 194 subdir('ext')
 195 subdir('tests')
 196 subdir('po')
 197
 198 python3 = find_program('python3')
 199 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')