meson.build

   1 project('gstreamer', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.40.1',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('library_format')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48   # FIXME: Add FATAL_WARNINGS from configure.ac
  49 endif
  50
  51 cdata = configuration_data()
  52 cdata.set('GST_API_VERSION', '"@0@"'.format(apiversion))
  53 cdata.set('GST_DATADIR', '"@0@/@1@"'.format(prefix, get_option('datadir')))
  54 cdata.set('LOCALEDIR', '"@0@/@1@"'.format(prefix, get_option('localedir')))
  55 cdata.set('LIBDIR', '"@0@/@1@"'.format(prefix, get_option('libdir')))
  56 cdata.set('GST_API_VERSION', '"1.0"')
  57 cdata.set('GETTEXT_PACKAGE', '"gstreamer-1.0"')
  58 cdata.set('GST_LICENSE', '"LGPL"')
  59 cdata.set('PACKAGE', '"gstreamer"')
  60 cdata.set('PACKAGE_NAME', '"GStreamer"')
  61 cdata.set('PACKAGE_STRING', '"GStreamer @0@"'.format(gst_version))
  62 cdata.set('PACKAGE_TARNAME', '"gstreamer"')
  63 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  64 cdata.set('PACKAGE_URL', '""')
  65 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  66 cdata.set('PLUGINDIR', '"@0@/@1@/gstreamer-1.0"'.format(get_option('prefix'),get_option('libdir')))
  67 cdata.set('VERSION', '"@0@"'.format(gst_version))
  68 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  69 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  70 cdata.set('GST_PLUGIN_SCANNER_INSTALLED', '"@0@/@1@/gst-plugin-scanner"'.format(prefix, helpers_install_dir))
  71 cdata.set('GST_PTP_HELPER_INSTALLED', '"@0@/@1@/gst-ptp-helper"'.format(prefix, helpers_install_dir))
  72
  73 if gst_version_nano > 0
  74     # Have GST_ERROR message printed when running from git
  75     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  76 else
  77     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  78 endif
  79
  80 # GStreamer package name and origin url
  81 gst_package_name = get_option('with-package-name')
  82 if gst_package_name == ''
  83   if gst_version_nano == 0
  84     gst_package_name = 'GStreamer source release'
  85   elif gst_version_nano == 1
  86     gst_package_name = 'GStreamer git'
  87   else
  88     gst_package_name = 'GStreamer prerelease'
  89   endif
  90 endif
  91 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  92 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  93
  94 # These are only needed/used by the ABI tests
  95 host_defines = [
  96   [ 'x86', 'HAVE_CPU_I386' ],
  97   [ 'x86_64', 'HAVE_CPU_X86_64' ],
  98   [ 'arm', 'HAVE_CPU_ARM' ],
  99   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 100   [ 'mips', 'HAVE_CPU_MIPS' ],
 101   [ 'powerpc', 'HAVE_CPU_PPC' ],
 102   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 103   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 104   [ 'sparc', 'HAVE_CPU_SPARC' ],
 105   [ 'ia64', 'HAVE_CPU_IA64' ],
 106   [ 'hppa', 'HAVE_CPU_HPPA' ],
 107   [ 'm68k', 'HAVE_CPU_M68K' ],
 108   [ 's390', 'HAVE_CPU_S390' ],
 109 ]
 110 foreach h : host_defines
 111   if h.get(0) == host_machine.cpu()
 112     cdata.set(h.get(1), 1)
 113   endif
 114 endforeach
 115 # FIXME: should really be called HOST_CPU or such
 116 cdata.set('TARGET_CPU', '"@0@"'.format(host_machine.cpu()))
 117
 118 check_headers = [
 119   'dlfcn.h',
 120   'inttypes.h',
 121   'memory.h',
 122   'poll.h',
 123   'stdint.h',
 124   'stdio_ext.h',
 125   'strings.h',
 126   'string.h',
 127   'sys/param.h',
 128   'sys/poll.h',
 129   'sys/prctl.h',
 130   'sys/socket.h',
 131   'sys/stat.h',
 132   'sys/times.h',
 133   'sys/time.h',
 134   'sys/types.h',
 135   'sys/utsname.h',
 136   'sys/wait.h',
 137   'ucontext.h',
 138   'unistd.h',
 139   'valgrind/valgrind.h',
 140   'sys/resource.h',
 141 ]
 142
 143 if host_machine.system() == 'windows'
 144   check_headers += ['winsock2.h']
 145 endif
 146
 147 foreach h : check_headers
 148   if cc.has_header(h)
 149     define = 'HAVE_' + h.underscorify().to_upper()
 150     cdata.set(define, 1)
 151   endif
 152 endforeach
 153
 154 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 155   cdata.set('HAVE_TM_GMTOFF', 1)
 156 endif
 157
 158 check_functions = [
 159   'gmtime_r',
 160   'sigaction',
 161   'getrusage',
 162   'fseeko',
 163   'ftello',
 164   'poll',
 165   'ppoll',
 166   'pselect',
 167   'getpagesize',
 168   'clock_gettime',
 169   # These are needed by libcheck
 170   'getline',
 171   'mkstemp',
 172   'alarm',
 173   'gettimeofday',
 174 ]
 175
 176 foreach f : check_functions
 177   if cc.has_function(f)
 178     define = 'HAVE_' + f.underscorify().to_upper()
 179     cdata.set(define, 1)
 180   endif
 181 endforeach
 182
 183 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 184   cdata.set('HAVE_LOCALTIME_R', 1)
 185   # Needed by libcheck
 186   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 187 endif
 188
 189 if cc.links('''#include <pthread.h>
 190                int main() {
 191                  pthread_setname_np("example"); return 0;
 192                }''', name : 'pthread_setname_np(const char*)')
 193   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 194 endif
 195
 196 # Check for posix timers and the monotonic clock
 197 time_prefix = '#include <time.h>\n'
 198 if cdata.has('HAVE_UNISTD_H')
 199   time_prefix += '#include <unistd.h>'
 200 endif
 201
 202 posix_timers_src = time_prefix + '''
 203 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 204 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 205 #endif
 206 '''
 207 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
 208   cdata.set('HAVE_POSIX_TIMERS', 1)
 209 endif
 210
 211 monotonic_clock_src = time_prefix + '''
 212 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 213 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 214 #endif
 215 '''
 216 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
 217   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 218 endif
 219
 220 # Check for __uint128_t (gcc) by checking for 128-bit division
 221 uint128_t_src = '''int main() {
 222 static __uint128_t v1 = 100;
 223 static __uint128_t v2 = 10;
 224 static __uint128_t u;
 225 u = v1 / v2;
 226 }'''
 227 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 228   cdata.set('HAVE_UINT128_T', 1)
 229 endif
 230
 231 # All supported platforms have long long now
 232 cdata.set('HAVE_LONG_LONG', 1)
 233
 234 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 235 # building with MSVC
 236 if cc.get_id() == 'msvc'
 237   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 238 else
 239   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 240 endif
 241
 242 # -------------------------------------------------------------------------------------
 243 # config.h things needed by libcheck
 244 # -------------------------------------------------------------------------------------
 245 if cc.has_function('getpid')
 246   cdata.set('HAVE_GETPID', 1)
 247 elif host_system == 'windows' and cc.has_function('_getpid')
 248   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 249   cdata.set('HAVE__GETPID', 1)
 250 endif
 251 if cc.has_function('strdup')
 252   cdata.set('HAVE_DECL_STRDUP', 1)
 253 elif host_system == 'windows' and cc.has_function('_strdup')
 254   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 255 endif
 256 if host_machine.system() != 'windows'
 257   cdata.set('HAVE_FORK', 1)
 258 else
 259   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 260   cdata.set('HAVE_FORK', 0)
 261 endif
 262 if cc.has_function('strsignal')
 263   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 264 endif
 265 # Check for availability of types
 266 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 267   cdata.set('clockid_t', 'int')
 268 endif
 269 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 270   cdata.set('timer_t', 'int')
 271 endif
 272 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 273                       prefix : '#include <time.h>')
 274   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 275 endif
 276 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 277                       prefix : '#include <time.h>')
 278   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 279 endif
 280
 281 # Platform deps; only ws2_32 and execinfo for now
 282 platform_deps = []
 283 if host_machine.system() == 'windows'
 284   platform_deps = [cc.find_library('ws2_32')]
 285 endif
 286
 287 backtrace_deps = []
 288 if not get_option('disable_libunwind')
 289   unwind_dep = dependency('libunwind', required : false)
 290   dw_dep = dependency('libdw', required: false)
 291   backtrace_deps = [unwind_dep, dw_dep]
 292   if unwind_dep.found()
 293     cdata.set('HAVE_UNWIND', 1)
 294     if dw_dep.found()
 295       cdata.set('HAVE_DW', 1)
 296     else
 297       message('Support for backtraces is partial only.')
 298     endif
 299   else
 300     if cc.has_function('backtrace')
 301       cdata.set('HAVE_BACKTRACE', 1)
 302     else
 303         message('NO backtraces support.')
 304     endif
 305   endif
 306 endif
 307
 308 if cc.has_header('execinfo.h')
 309   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 310     cdata.set('HAVE_BACKTRACE', 1)
 311   else
 312     execinfo_dep = cc.find_library('execinfo', required : false)
 313     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 314       cdata.set('HAVE_BACKTRACE', 1)
 315       platform_deps += execinfo_dep
 316     endif
 317   endif
 318 endif
 319
 320 disable_gst_debug = get_option('disable_gst_debug')
 321 if get_option('disable_gst_debug')
 322     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
 323   add_project_arguments(['-Wno-unused'], language: 'c')
 324 endif
 325
 326 # Used by the gstutils test
 327 gmp_dep = cc.find_library('gmp', required : false)
 328 cdata.set('HAVE_GMP', gmp_dep.found())
 329 gsl_dep = cc.find_library('gsl', required : false)
 330 gslcblas_dep = cc.find_library('gslcblas', required : false)
 331 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 332 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 333
 334 # Used by gstinfo.c
 335 dl_dep = cc.find_library('dl', required : false)
 336 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 337
 338
 339 configinc = include_directories('.')
 340 libsinc = include_directories('libs')
 341 privinc = include_directories('gst')
 342
 343 # Find dependencies
 344 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 345   fallback: ['glib', 'libglib_dep'])
 346 gobject_dep = dependency('gobject-2.0',
 347   fallback: ['glib', 'libgobject_dep'])
 348 gmodule_dep = dependency('gmodule-2.0',
 349   fallback: ['glib', 'libgmodule_dep'])
 350 if host_machine.system() == 'windows'
 351     gio_dep = dependency('gio-2.0',
 352         fallback: ['glib', 'libgio_dep'])
 353 else
 354     gio_dep = [dependency('gio-2.0',
 355                   fallback: ['glib', 'libgio_dep']),
 356                dependency('gio-unix-2.0',
 357                   fallback: ['glib', 'libgio_dep'])]
 358 endif
 359
 360 mathlib = cc.find_library('m', required : false)
 361 # Needed for timer_create/settime/delete
 362 # Also provides clock_gettime in glibc < 2.17
 363 rt_lib = cc.find_library('rt', required : false)
 364
 365 gir = find_program('g-ir-scanner', required : false)
 366 gnome = import('gnome')
 367
 368 # Fixme, not very elegant.
 369 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 370
 371 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 372     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 373     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 374     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 375     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 376     'gst_init(NULL,NULL);' ]
 377 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 378
 379 # Used by the *_mkenum.py helper scripts
 380 glib_mkenums = find_program('glib-mkenums')
 381
 382 gst_c_args = ['-DHAVE_CONFIG_H']
 383 if libtype == 'static'
 384   gst_c_args += ['-DGST_STATIC_COMPILATION']
 385 endif
 386
 387 # Used in gst/parse/meson.build and below
 388 py3 = find_program('python3', required : false)
 389 if not py3.found()
 390   # Maybe 'python' is Python 3
 391   py3 = find_program('python')
 392 endif
 393
 394 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 395
 396 bashcomp_found = bashcomp_dep.found()
 397 bash_completions_dir = ''
 398 bash_helpers_dir = ''
 399
 400 if bashcomp_found
 401   # get_pkgconfig_variable() won't let us set the prefix
 402   pkgconfig = find_program('pkg-config')
 403
 404   runcmd = run_command(pkgconfig,
 405       '--define-variable=prefix="."',
 406       '--variable=completionsdir',
 407       'bash-completion')
 408
 409   if (runcmd.returncode() == 0)
 410     bash_completions_dir = runcmd.stdout().strip()
 411   else
 412     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 413     bashcomp_found = false
 414   endif
 415
 416   runcmd = run_command(pkgconfig,
 417       '--define-variable=prefix="."',
 418       '--variable=helpersdir',
 419       'bash-completion')
 420
 421   if (runcmd.returncode() == 0)
 422     bash_helpers_dir = runcmd.stdout().strip()
 423   else
 424     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 425     bashcomp_found = false
 426   endif
 427 endif
 428
 429 subdir('gst')
 430 subdir('libs')
 431 subdir('plugins')
 432 subdir('tools')
 433 subdir('pkgconfig')
 434 subdir('tests')
 435 subdir('po')
 436 subdir('data')
 437
 438 configure_file(output : 'config.h', configuration : cdata)
 439
 440 if build_machine.system() == 'windows'
 441   message('Disabling gtk-doc while building on Windows')
 442 elif get_option('disable_gtkdoc')
 443   message('gtk-doc is disabled via options')
 444 else
 445   if find_program('gtkdoc-scan', required : false).found()
 446     subdir('docs')
 447   else
 448     message('Not building documentation as gtk-doc was not found')
 449   endif
 450 endif
 451
 452 run_command(py3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 453
 454 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))