meson.build

   1 project('gstreamer-full', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60.0',
   4   default_options : ['buildtype=debugoptimized',
   5                      # Needed due to https://github.com/mesonbuild/meson/issues/1889,
   6                      # but this can cause problems in the future. Remove it
   7                      # when it's no longer necessary.
   8                      'cpp_std=c++14'])
   9
  10 apiversion = '1.0'
  11 gst_version = '>= @0@'.format(meson.project_version())
  12
  13 build_system = build_machine.system()
  14 cc = meson.get_compiler('c')
  15
  16 fs = import('fs')
  17 gnome = import('gnome')
  18 pkgconfig = import('pkgconfig')
  19 python3 = import('python').find_installation()
  20 # Ensure that we're not being run from inside the development environment
  21 # because that will confuse meson, and it might find the already-built
  22 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  23 # reconfigure because ninja doesn't care about the env.
  24 ensure_not_devenv = '''
  25 import os
  26 assert('GST_ENV' not in os.environ)
  27 '''
  28 cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
  29 if cmdres.returncode() != 0
  30   error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
  31 endif
  32
  33 # Install gst-indent pre-commit hook
  34 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
  35
  36 # Ensure that the user does not have Strawberry Perl in PATH, since it ships
  37 # with a pkg-config.bat and broken pkgconfig files for libffi and zlib. Will
  38 # cause a build error, such as in
  39 # https://gitlab.freedesktop.org/gstreamer/gst-build/-/issues/41
  40 ensure_no_strawberry_perl = '''
  41 import os
  42 assert(r'Strawberry\perl\bin' not in os.environ['PATH'])
  43 '''
  44 if build_system == 'windows' and meson.version().version_compare('<0.60.0')
  45   cmdres = run_command(python3, '-c', ensure_no_strawberry_perl, check: false)
  46   if cmdres.returncode() != 0
  47     error('You have Strawberry Perl in PATH which is known to cause build issues with Meson < 0.60.0. Please remove it from PATH, uninstall it, or upgrade Meson.')
  48   endif
  49 endif
  50
  51 documented_projects = ''
  52 # Make it possible to use msys2 built zlib which fails
  53 # when not using the mingw toolchain as it uses unistd.h
  54 if not meson.is_subproject() and cc.get_id() == 'msvc'
  55   uname = find_program('uname', required: false)
  56   if uname.found()
  57     ret = run_command(uname, '-o', check: false)
  58     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  59       ret = run_command(uname, '-r', check: false)
  60       # The kernel version returned by uname is actually the msys version
  61       if ret.returncode() == 0 and ret.stdout().startswith('2')
  62         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  63         if cc.find_library('z').found()
  64           add_global_arguments('-DZ_SOLO', language: 'c')
  65         endif
  66       endif
  67     endif
  68   endif
  69 endif
  70
  71 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  72 # not a subproject, because subprojects are not allowed to call
  73 # add_global_arguments().
  74 if not meson.is_subproject() and cc.get_id() == 'msvc'
  75   add_global_arguments(
  76       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  77       language: ['c', 'cpp'])
  78 endif
  79
  80 building_full = get_option('default_library') == 'static'
  81 tools_option = 'tools=auto'
  82 if building_full and not get_option('tools').disabled()
  83   # Do not build subprojects tools when we build them against gst-full
  84   tools_option = 'tools=disabled'
  85 endif
  86
  87 # Ordered list of subprojects (dict has no ordering guarantees)
  88 subprojects = [
  89   ['gstreamer', {'build-hotdoc': true, 'subproject_options': [tools_option]}],
  90   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
  91   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
  92   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
  93   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
  94   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
  95   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
  96   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
  97   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
  98   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
  99   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
 100   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
 101   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
 102   ['gstreamer-sharp', { 'option': get_option('sharp') }],
 103   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
 104   ['gst-python', { 'option': get_option('python')}],
 105   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
 106   ['gst-plugins-rs', { 'option': get_option('rs'), 'match_gst_version': false}],
 107 ]
 108
 109 symlink = '''
 110 import os
 111
 112 os.symlink(os.path.join('@1@', 'subprojects', '@0@'),
 113   os.path.join('@1@', '@0@'))
 114 '''
 115
 116 if build_system == 'windows'
 117   subproject('win-flex-bison-binaries')
 118   subproject('win-nasm')
 119 elif build_system == 'darwin'
 120   subproject('macos-bison-binary')
 121 endif
 122
 123 orc_subproject = subproject('orc', required: get_option('orc'))
 124
 125 foreach custom_subproj: get_option('custom_subprojects').split(',')
 126     if custom_subproj != ''
 127         message ('Adding custom subproject ' + custom_subproj)
 128         subprojects += [[custom_subproj, {'match_gst_version': false}]]
 129     endif
 130 endforeach
 131
 132
 133 subprojects_names = []
 134 plugins_doc_caches = []
 135 orc_update_targets = []
 136 all_plugins = []
 137 all_tools = {}
 138 # Using a list and not a dict to keep the ordering to build the chain of `gir`
 139 # dependencies
 140 all_libraries = []
 141 foreach sp : subprojects
 142   project_name = sp[0]
 143   build_infos = sp[1]
 144   is_required = build_infos.get('option', true)
 145   sysdep = build_infos.get('sysdep', '')
 146   sysdep_version = build_infos.get('sysdep_version', '')
 147   match_gst_version = build_infos.get('match_gst_version', true)
 148   default_options =  build_infos.get('subproject_options', [])
 149
 150   if match_gst_version
 151     subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
 152   elif sysdep != ''
 153       sysdep_dep = dependency(sysdep, version: sysdep_version, required: false, default_options: default_options)
 154       if not sysdep_dep.found()
 155         subproj = subproject(project_name, required: is_required, default_options: default_options)
 156       endif
 157   else
 158     subproj = subproject(project_name, required: is_required, default_options: default_options)
 159   endif
 160
 161   if subproj.found()
 162     plugins = subproj.get_variable('plugins', [])
 163     all_plugins += plugins
 164     all_libraries += subproj.get_variable('libraries', [])
 165     if not get_option('tools').disabled()
 166       all_tools += subproj.get_variable('gst_tools', {})
 167     endif
 168
 169     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 170
 171     subprojects_names += [project_name]
 172
 173     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 174       if plugins.length() > 0
 175         plugins_doc_caches += [subproj.get_variable('plugins_doc_dep', [])]
 176       endif
 177       if documented_projects != ''
 178         documented_projects += ','
 179       endif
 180       documented_projects  += project_name
 181     endif
 182   endif
 183 endforeach
 184
 185 # Check if we need to also build glib-networking for TLS modules
 186 glib_dep = dependency('glib-2.0')
 187 if glib_dep.type_name() == 'internal'
 188   subproject('glib-networking', required : get_option('tls'),
 189              default_options: ['gnutls=auto', 'openssl=auto'])
 190 endif
 191
 192 plugins_doc_dep = custom_target('plugins-doc-cache',
 193   command: [python3, '-c', 'print("Built all doc caches")'],
 194   input: plugins_doc_caches,
 195   output: 'plugins_doc_caches',
 196   capture: true,
 197 )
 198
 199 if meson.is_cross_build() or build_machine.system() == 'windows'
 200     if get_option('doc').enabled()
 201         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 202     endif
 203
 204     documented_projects = ''
 205     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 206 else
 207   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 208   if not hotdoc_p.found()
 209     documented_projects = ''
 210     message('Not building documentation as hotdoc was not found')
 211   endif
 212 endif
 213
 214 write_file_contents = '''
 215 import os
 216 import sys
 217
 218 assert len(sys.argv) >= 3
 219 fname = sys.argv[1]
 220 contents = sys.argv[2]
 221
 222 with open(fname, 'w') as f:
 223     f.write(contents)
 224 '''
 225
 226 configure_file(
 227   output : 'GstDocumentedSubprojects',
 228   command : [python3,
 229              '-c', write_file_contents,
 230              '@OUTPUT@',
 231              documented_projects]
 232 )
 233
 234 if documented_projects != ''
 235   subproject('gst-docs', required: get_option('doc').enabled())
 236   message('Gst docs subprojects: ' + documented_projects)
 237 endif
 238
 239 all_plugins_paths = []
 240 all_plugins_dirs = []
 241 foreach plugin: all_plugins
 242   all_plugins_paths += plugin.full_path()
 243   all_plugins_dirs += fs.parent(plugin.full_path())
 244 endforeach
 245 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 246 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 247 all_plugins_paths = pathsep.join(all_plugins_paths)
 248
 249 devenv = environment()
 250 devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 251 devenv.set('CURRENT_GST', meson.current_source_dir())
 252 devenv.set('GST_VERSION', meson.project_version())
 253 devenv.set('GST_ENV', 'gst-' + meson.project_version())
 254 devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
 255 devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
 256 meson.add_devenv(devenv)
 257
 258 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 259 configure_file(
 260   output : 'GstPluginsPath.json',
 261   command : [generate_plugins_paths,
 262              '@OUTPUT@',
 263              all_plugins_paths]
 264 )
 265
 266 if building_full
 267   cdata = configuration_data()
 268   cdata.set_quoted('GST_API_VERSION', apiversion)
 269   cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
 270   cdata.set_quoted('PACKAGE_VERSION', gst_version)
 271   cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 272   configure_file(output : 'config.h', configuration : cdata)
 273   configinc = include_directories('.')
 274   gst_c_args = ['-DHAVE_CONFIG_H']
 275
 276   # Generate a .c file which declare and register all built plugins
 277   plugins_names = []
 278   foreach plugin: all_plugins
 279     plugins_names += plugin.full_path()
 280   endforeach
 281   all_plugin_names = ';'.join(plugins_names)
 282
 283   static_plugins = get_option('gst-full-plugins')
 284   if static_plugins == '*'
 285     static_plugins = all_plugin_names
 286   endif
 287   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 288   init_static_plugins_c = configure_file(
 289     output: 'gstinitstaticplugins.c',
 290     command : [generate_init_static_plugins,
 291                '-o ' + '@OUTPUT@',
 292                '-p ' + static_plugins,
 293                '-e ' + get_option('gst-full-elements'),
 294                '-t ' + get_option('gst-full-typefind-functions'),
 295                '-d ' + get_option('gst-full-device-providers'),
 296                '-T ' + get_option('gst-full-dynamic-types')
 297                ]
 298   )
 299
 300   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 301
 302   # Get a list of libraries that needs to be exposed in the ABI.
 303   exposed_libs = []
 304   exposed_deps = []
 305   exposed_girs = []
 306   incdir_deps = []
 307   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 308   all_libs = '*' in wanted_libs
 309
 310   foreach pkgname_library : all_libraries
 311     pkg_name = pkgname_library[0]
 312     lib_def = pkgname_library[1]
 313
 314     if pkg_name in wanted_libs or all_libs
 315       if lib_def.has_key('lib')
 316         exposed_deps += dependency(pkg_name)
 317         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 318         exposed_libs += [lib_def['lib']]
 319       endif
 320
 321       if lib_def.has_key('gir')
 322         exposed_girs += lib_def['gir']
 323       endif
 324     endif
 325   endforeach
 326
 327   # glib and gobject are part of our public API. If we are using glib from the
 328   # system then our pkg-config file must require it. If we built it as
 329   # subproject then we need to link_whole it.
 330   glib_deps = []
 331   glib_dep = dependency('glib-2.0')
 332   gobject_dep = dependency('gobject-2.0')
 333   if gobject_dep.type_name() == 'internal'
 334     glib_subproject = subproject('glib')
 335     exposed_libs += glib_subproject.get_variable('libglib')
 336     exposed_libs += glib_subproject.get_variable('libgobject')
 337     incdir_deps += [
 338       glib_dep.partial_dependency(includes: true),
 339       gobject_dep.partial_dependency(includes: true),
 340     ]
 341   else
 342     glib_deps = [glib_dep, gobject_dep]
 343   endif
 344
 345   link_deps = []
 346   if get_option('gst-full-version-script') != ''
 347     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 348     link_arg = '-Wl,--version-script=' + symbol_map
 349     if cc.has_link_argument(link_arg)
 350       gstfull_link_args += link_arg
 351       link_deps += symbol_map
 352     elif cc.get_id() == 'msvc'
 353       warning('FIXME: Provide a def file to publish the public symbols')
 354     else
 355       warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
 356     endif
 357   endif
 358
 359   # Build both shared and static library
 360   gstfull = both_libraries('gstreamer-full-1.0',
 361     init_static_plugins_c,
 362     link_with : all_plugins,
 363     link_args: gstfull_link_args,
 364     link_whole : exposed_libs,
 365     dependencies : incdir_deps + glib_deps,
 366     link_depends : link_deps,
 367     install : true,
 368   )
 369
 370   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 371     dependencies : incdir_deps + glib_deps,
 372     include_directories: include_directories('.')
 373   )
 374
 375   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 376   if gst_full_libs_private == []
 377     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 378   endif
 379
 380   if not get_option('introspection').disabled()
 381     built_girs = {}
 382     foreach gir: exposed_girs
 383       includes = []
 384       foreach include: gir.get('includes', [])
 385         includes += [built_girs.get(include, include)]
 386       endforeach
 387
 388       gir += {
 389         'includes': includes,
 390         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 391         'install': true,
 392       }
 393       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 394     endforeach
 395   endif
 396
 397   pkgconfig.generate(gstfull,
 398     requires: glib_deps,
 399     libraries_private: gst_full_libs_private,
 400     subdirs : 'gstreamer-1.0')
 401   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 402
 403   if not get_option('tools').disabled()
 404     foreach tool, data: all_tools
 405       exe_name = '@0@-@1@'.format(tool, apiversion)
 406       extra_args = data.get('extra_c_args', [])
 407       sources = data.get('files')
 408       deps = []
 409       foreach d : data.get('deps', [])
 410         if d not in exposed_deps
 411           deps += d
 412         endif
 413       endforeach
 414
 415       executable(exe_name,
 416         sources,
 417         install: true,
 418         include_directories : [configinc],
 419         dependencies : [gst_full_dep] + deps,
 420         c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
 421       )
 422
 423       if data.has_key('man_page')
 424         install_man(data.get('man_page'))
 425       endif
 426
 427     endforeach
 428   endif
 429 endif
 430
 431 message('Building subprojects: ' + ', '.join(subprojects_names))
 432
 433 setenv = find_program('gst-env.py')
 434
 435 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
 436               '--srcdir=@0@'.format(meson.global_source_root())]
 437
 438 subdir('tests')
 439 subdir('ci/fuzzing')
 440
 441 if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 442   # FIXME: Ideally we could get the wrapper directly from meson
 443   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 444   sysroot = meson.get_cross_property('sys_root')
 445   if sysroot != ''
 446     # Logic from meson
 447     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 448   endif
 449 endif
 450
 451 run_target('devenv', command : devenv_cmd)
 452
 453 if orc_subproject.found() and orc_update_targets.length() > 0
 454   alias_target('update-orc-dist', orc_update_targets)
 455 endif
 456
 457 dotnet_format = find_program('dotnet-format', required: false)
 458 if dotnet_format.found()
 459     run_target('csharp_format_check',
 460         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 461             '--check'
 462         ],
 463     )
 464     run_target('csharp_format_apply',
 465         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 466         ],
 467     )
 468 endif
 469
 470 summary({
 471   'gstreamer-full library': building_full,
 472 }, section: 'Build options', bool_yn: true, list_sep: '  ')
 473
 474 gst_tools = []
 475 foreach tool, data: all_tools
 476   gst_tools += tool
 477 endforeach
 478
 479 summary({
 480     'Tools': gst_tools,
 481 }, section: 'Build options', list_sep: ', ')