meson.build

   1 project('gstreamer-full', 'c',
   2   version : '1.21.2.1',
   3   meson_version : '>= 0.62.0',
   4   default_options : ['buildtype=debugoptimized',
   5                      # Needed due to https://github.com/mesonbuild/meson/issues/1889,
   6                      # but this can cause problems in the future. Remove it
   7                      # when it's no longer necessary.
   8                      'cpp_std=c++14'])
   9
  10 apiversion = '1.0'
  11 gst_version = '>= @0@'.format(meson.project_version())
  12
  13 build_system = build_machine.system()
  14 cc = meson.get_compiler('c')
  15
  16 fs = import('fs')
  17 gnome = import('gnome')
  18 pkgconfig = import('pkgconfig')
  19 python3 = import('python').find_installation()
  20 # Ensure that we're not being run from inside the development environment
  21 # because that will confuse meson, and it might find the already-built
  22 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  23 # reconfigure because ninja doesn't care about the env.
  24 ensure_not_devenv = '''
  25 import os
  26 assert('GST_ENV' not in os.environ)
  27 '''
  28 cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
  29 if cmdres.returncode() != 0
  30   error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
  31 endif
  32
  33 # Install gst-indent pre-commit hook
  34 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
  35
  36 # On macOS, you have to run "Install Certificates.command" otherwise Python
  37 # doesn't have access to the latest SSL CA Certificates, and Meson will fail to
  38 # download wrap files from websites that use, for example, Let's Encrypt.
  39 # We already recommend this in the README, but add a warning here as well.
  40 # Can't make this an error because the user might be using XCode's Python
  41 # 3 which doesn't have this script.
  42 if build_system == 'darwin'
  43   python3_cacert_file = python3.get_path('data') / 'etc/openssl/cert.pem'
  44   install_cert_cmd = '/Applications/Python @0@/Install Certificates.command'.format(python3.language_version())
  45   if not fs.is_symlink(python3_cacert_file) and fs.is_file(install_cert_cmd)
  46     warning('Please run "@0@" so that Python has access to the latest SSL certificates. Meson might fail to download some wraps without it.'.format(install_cert_cmd))
  47   endif
  48 endif
  49
  50 documented_projects = ''
  51 # Make it possible to use msys2 built zlib which fails
  52 # when not using the mingw toolchain as it uses unistd.h
  53 if not meson.is_subproject() and cc.get_id() == 'msvc'
  54   uname = find_program('uname', required: false)
  55   if uname.found()
  56     ret = run_command(uname, '-o', check: false)
  57     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  58       ret = run_command(uname, '-r', check: false)
  59       # The kernel version returned by uname is actually the msys version
  60       if ret.returncode() == 0 and ret.stdout().startswith('2')
  61         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  62         if cc.find_library('z').found()
  63           add_global_arguments('-DZ_SOLO', language: 'c')
  64         endif
  65       endif
  66     endif
  67   endif
  68 endif
  69
  70 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  71 # not a subproject, because subprojects are not allowed to call
  72 # add_global_arguments().
  73 if not meson.is_subproject() and cc.get_id() == 'msvc'
  74   add_global_arguments(
  75       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  76       language: ['c', 'cpp'])
  77 endif
  78
  79 building_full = get_option('default_library') == 'static'
  80 tools_option = []
  81 if building_full and not get_option('tools').disabled()
  82   # Do not build subprojects tools when we build them against gst-full
  83   tools_option = ['tools=disabled']
  84 endif
  85
  86 # Ordered list of subprojects (dict has no ordering guarantees)
  87 subprojects = [
  88   ['gstreamer', {'build-hotdoc': true, 'subproject_options': tools_option}],
  89   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
  90   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
  91   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
  92   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
  93   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
  94   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
  95   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
  96   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': tools_option}],
  97   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
  98   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': tools_option}],
  99   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
 100   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
 101   ['gstreamer-sharp', { 'option': get_option('sharp') }],
 102   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
 103   ['gst-python', { 'option': get_option('python')}],
 104   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
 105   ['gst-plugins-rs', { 'option': get_option('rs'), 'build-hotdoc': true, 'match_gst_version': false}],
 106 ]
 107
 108 if build_system == 'windows'
 109   subproject('win-flex-bison-binaries')
 110   subproject('win-nasm')
 111 elif build_system == 'darwin'
 112   subproject('macos-bison-binary')
 113 endif
 114
 115 orc_option = get_option('orc')
 116 # There is a check below to keep this in sync with subprojects/gst-plugins-base/meson.build
 117 orc_req = '>= 0.4.24'
 118 orc_source_option = get_option('orc-source')
 119 orc_subproject = disabler()
 120 if orc_option.allowed()
 121   if orc_source_option == 'subproject'
 122     orc_subproject = subproject('orc', required: orc_option)
 123   else
 124     dependency('orc-0.4', version: orc_req, required: orc_option,
 125                allow_fallback: orc_source_option == 'auto')
 126   endif
 127 endif
 128
 129 foreach custom_subproj: get_option('custom_subprojects').split(',')
 130     if custom_subproj != ''
 131         message ('Adding custom subproject ' + custom_subproj)
 132         subprojects += [[custom_subproj, {'match_gst_version': false}]]
 133     endif
 134 endforeach
 135
 136
 137 subprojects_names = []
 138 plugins_doc_caches = []
 139 orc_update_targets = []
 140 all_plugins = []
 141 all_tools = {}
 142 # Using a list and not a dict to keep the ordering to build the chain of `gir`
 143 # dependencies
 144 all_libraries = []
 145 foreach sp : subprojects
 146   project_name = sp[0]
 147   build_infos = sp[1]
 148   is_required = build_infos.get('option', true)
 149   sysdep = build_infos.get('sysdep', '')
 150   sysdep_version = build_infos.get('sysdep_version', '')
 151   match_gst_version = build_infos.get('match_gst_version', true)
 152   default_options =  build_infos.get('subproject_options', [])
 153
 154   if match_gst_version
 155     subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
 156   elif sysdep != ''
 157       sysdep_dep = dependency(sysdep, version: sysdep_version, required: false, default_options: default_options)
 158       if not sysdep_dep.found()
 159         subproj = subproject(project_name, required: is_required, default_options: default_options)
 160       endif
 161   else
 162     subproj = subproject(project_name, required: is_required, default_options: default_options)
 163   endif
 164
 165   if project_name == 'gst-plugins-base'
 166     gst_base_orc_req = subproj.get_variable('orc_req', '')
 167     if gst_base_orc_req != orc_req
 168       error('orc_req is "@0@" but it should be "@1@" from subprojects/gst-plugins-base/meson.build'
 169             .format(orc_req, gst_base_orc_req))
 170     endif
 171   endif
 172
 173   if subproj.found()
 174     plugins = subproj.get_variable('gst_plugins', [])
 175     legacy_plugins = subproj.get_variable('plugins', [])
 176     all_plugins += plugins
 177     if plugins.length() == 0 and legacy_plugins.length() > 0
 178       warning(f'DEPRECATED use of the `plugins` variable in @project_name@.')
 179       warning('The variable should now be called `gst_plugins` and use:')
 180       warning('`declare_dependency( link_with: <plugin_target>, variable: {\'full_path\': <plugin_target>.full_path()})` instead')
 181       foreach plugin: legacy_plugins
 182         all_plugins += [declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})]
 183       endforeach
 184     endif
 185
 186     all_libraries += subproj.get_variable('gst_libraries', [])
 187     if not get_option('tools').disabled()
 188       all_tools += subproj.get_variable('gst_tools', {})
 189     endif
 190
 191     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 192
 193     subprojects_names += [project_name]
 194
 195     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 196       plugins_doc_caches += [subproj.get_variable('gst_plugins_doc_dep', [])]
 197       if documented_projects != ''
 198         documented_projects += ','
 199       endif
 200       documented_projects  += project_name
 201     endif
 202   endif
 203 endforeach
 204
 205 # Check if we need to also build glib-networking for TLS modules
 206 giomodules = []
 207 glib_dep = dependency('glib-2.0')
 208 if glib_dep.type_name() == 'internal'
 209   subp = subproject('glib-networking', required : get_option('tls'),
 210              default_options: ['gnutls=auto', 'openssl=auto'])
 211   if subp.found()
 212     giomodules += subp.get_variable('giomodules', [])
 213   endif
 214 endif
 215
 216 gst_plugins_doc_dep = custom_target('plugins-doc-cache',
 217   command: [python3, '-c', 'print("Built all doc caches")'],
 218   input: plugins_doc_caches,
 219   output: 'plugins_doc_caches',
 220   capture: true,
 221 )
 222
 223 if meson.is_cross_build() or build_machine.system() == 'windows'
 224     if get_option('doc').enabled()
 225         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 226     endif
 227
 228     documented_projects = ''
 229     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 230 else
 231   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 232   if not hotdoc_p.found()
 233     documented_projects = ''
 234     message('Not building documentation as hotdoc was not found')
 235   endif
 236 endif
 237
 238 write_file_contents = '''
 239 import os
 240 import sys
 241
 242 assert len(sys.argv) >= 3
 243 fname = sys.argv[1]
 244 contents = sys.argv[2]
 245
 246 with open(fname, 'w') as f:
 247     f.write(contents)
 248 '''
 249
 250 configure_file(
 251   output : 'GstDocumentedSubprojects',
 252   command : [python3,
 253              '-c', write_file_contents,
 254              '@OUTPUT@',
 255              documented_projects]
 256 )
 257
 258 if documented_projects != ''
 259   subproject('gst-docs', required: get_option('doc').enabled())
 260   message('Gst docs subprojects: ' + documented_projects)
 261 endif
 262
 263 all_plugins_paths = []
 264 all_plugins_dirs = []
 265 plugins_names = []
 266 foreach plugin: all_plugins
 267   plugin_path = plugin.get_variable('full_path')
 268   all_plugins_paths += plugin_path
 269   all_plugins_dirs += fs.parent(plugin_path)
 270   plugins_names += plugin_path
 271 endforeach
 272
 273 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 274 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 275 all_plugins_paths = pathsep.join(all_plugins_paths)
 276
 277 devenv = environment()
 278 if not building_full
 279   devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 280 else
 281   # Make sure the current build directory is first in PATH so we prefer tools
 282   # built here that links on gst-full instead instead of those built in
 283   # subprojects.
 284   devenv.prepend('PATH', meson.current_build_dir())
 285 endif
 286 devenv.set('CURRENT_GST', meson.current_source_dir())
 287 devenv.set('GST_VERSION', meson.project_version())
 288 devenv.set('GST_ENV', 'gst-' + meson.project_version())
 289 devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
 290 devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
 291 meson.add_devenv(devenv)
 292
 293 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 294 configure_file(
 295   output : 'GstPluginsPath.json',
 296   command : [generate_plugins_paths,
 297              '@OUTPUT@',
 298              all_plugins_paths]
 299 )
 300
 301 if building_full
 302   cdata = configuration_data()
 303   cdata.set_quoted('GST_API_VERSION', apiversion)
 304   cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
 305   cdata.set_quoted('PACKAGE_VERSION', gst_version)
 306   cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 307   configure_file(output : 'config.h', configuration : cdata)
 308   configinc = include_directories('.')
 309   gst_c_args = ['-DHAVE_CONFIG_H']
 310
 311   # Generate a .c file which declare and register all built plugins
 312   all_plugin_names = ';'.join(plugins_names)
 313
 314   static_plugins = get_option('gst-full-plugins')
 315   if static_plugins == '*'
 316     static_plugins = all_plugin_names
 317   endif
 318   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 319   init_static_plugins_c = configure_file(
 320     output: 'gstinitstaticplugins.c',
 321     command : [generate_init_static_plugins,
 322                '-o ' + '@OUTPUT@',
 323                '-p ' + static_plugins,
 324                '-e ' + get_option('gst-full-elements'),
 325                '-t ' + get_option('gst-full-typefind-functions'),
 326                '-d ' + get_option('gst-full-device-providers'),
 327                '-T ' + get_option('gst-full-dynamic-types'),
 328                '--giomodules', ';'.join(giomodules),
 329                ]
 330   )
 331
 332   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 333
 334   # Get a list of libraries that needs to be exposed in the ABI.
 335   exposed_libs = []
 336   exposed_deps = []
 337   exposed_girs = []
 338   incdir_deps = []
 339   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 340   all_libs = '*' in wanted_libs
 341
 342   foreach pkgname_library : all_libraries
 343     pkg_name = pkgname_library[0]
 344     lib_def = pkgname_library[1]
 345
 346     if pkg_name in wanted_libs or all_libs
 347       if lib_def.has_key('lib')
 348         exposed_deps += dependency(pkg_name)
 349         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 350         exposed_libs += [lib_def['lib']]
 351       endif
 352
 353       if lib_def.has_key('gir')
 354         exposed_girs += lib_def['gir']
 355       endif
 356     endif
 357   endforeach
 358
 359   # glib and gobject are part of our public API. If we are using glib from the
 360   # system then our pkg-config file must require it. If we built it as
 361   # subproject then we need to link_whole it.
 362   glib_deps = []
 363   glib_dep = dependency('glib-2.0')
 364   gobject_dep = dependency('gobject-2.0')
 365   if gobject_dep.type_name() == 'internal'
 366     glib_subproject = subproject('glib')
 367     exposed_libs += glib_subproject.get_variable('libglib')
 368     exposed_libs += glib_subproject.get_variable('libgobject')
 369     incdir_deps += [
 370       glib_dep.partial_dependency(includes: true),
 371       gobject_dep.partial_dependency(includes: true),
 372     ]
 373   else
 374     glib_deps = [glib_dep, gobject_dep]
 375   endif
 376
 377   link_deps = []
 378   if get_option('gst-full-version-script') != ''
 379     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 380     link_arg = '-Wl,--version-script=' + symbol_map
 381     if cc.has_link_argument(link_arg)
 382       gstfull_link_args += link_arg
 383       link_deps += symbol_map
 384     elif cc.get_id() == 'msvc'
 385       warning('FIXME: Provide a def file to publish the public symbols')
 386     else
 387       warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
 388     endif
 389   endif
 390
 391   giomodules_deps = []
 392   foreach module : giomodules
 393     giomodules_deps += dependency(module)
 394   endforeach
 395
 396   # Build both shared and static library
 397   gstfull = both_libraries('gstreamer-full-1.0',
 398     init_static_plugins_c,
 399     link_args: gstfull_link_args,
 400     link_whole : exposed_libs,
 401     dependencies : [incdir_deps, glib_deps, all_plugins, giomodules_deps],
 402     link_depends : link_deps,
 403     install : true,
 404   )
 405
 406   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 407     dependencies : incdir_deps + glib_deps,
 408     include_directories: include_directories('.')
 409   )
 410
 411   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 412   if gst_full_libs_private == []
 413     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 414   endif
 415
 416   if not get_option('introspection').disabled()
 417     built_girs = {}
 418     foreach gir: exposed_girs
 419       includes = []
 420       foreach include: gir.get('includes', [])
 421         includes += [built_girs.get(include, include)]
 422       endforeach
 423
 424       gir += {
 425         'includes': includes,
 426         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 427         'install': true,
 428       }
 429       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 430     endforeach
 431   endif
 432
 433   pkgconfig.generate(gstfull,
 434     requires: glib_deps,
 435     libraries_private: gst_full_libs_private,
 436     subdirs : 'gstreamer-1.0')
 437   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 438
 439   if not get_option('tools').disabled()
 440     foreach tool, data: all_tools
 441       exe_name = '@0@-@1@'.format(tool, apiversion)
 442       extra_args = data.get('extra_c_args', [])
 443       sources = data.get('files')
 444       install_tag = data.get('install_tag', 'bin')
 445       deps = []
 446       foreach d : data.get('deps', [])
 447         if d not in exposed_deps
 448           deps += d
 449         endif
 450       endforeach
 451
 452       executable(exe_name,
 453         sources,
 454         install: true,
 455         install_tag: install_tag,
 456         include_directories : [configinc],
 457         dependencies : [gst_full_dep] + deps,
 458         c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
 459       )
 460
 461       if data.has_key('man_page')
 462         install_man(data.get('man_page'))
 463       endif
 464
 465     endforeach
 466   endif
 467 endif
 468
 469 message('Building subprojects: ' + ', '.join(subprojects_names))
 470
 471 setenv = find_program('gst-env.py')
 472
 473 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
 474               '--srcdir=@0@'.format(meson.global_source_root())]
 475
 476 subdir('tests')
 477 subdir('ci/fuzzing')
 478
 479 if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 480   # FIXME: Ideally we could get the wrapper directly from meson
 481   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 482   sysroot = meson.get_cross_property('sys_root')
 483   if sysroot != ''
 484     # Logic from meson
 485     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 486   endif
 487 endif
 488
 489 run_target('devenv', command : devenv_cmd)
 490
 491 if orc_subproject.found() and orc_update_targets.length() > 0
 492   alias_target('update-orc-dist', orc_update_targets)
 493 endif
 494
 495 dotnet_format = find_program('dotnet-format', required: false)
 496 if dotnet_format.found()
 497     run_target('csharp_format_check',
 498         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 499             '--check'
 500         ],
 501     )
 502     run_target('csharp_format_apply',
 503         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 504         ],
 505     )
 506 endif
 507
 508 summary({
 509   'gstreamer-full library': building_full,
 510 }, section: 'Build options', bool_yn: true, list_sep: '  ')
 511
 512 gst_tools = []
 513 foreach tool, data: all_tools
 514   gst_tools += tool
 515 endforeach
 516
 517 summary({
 518     'Tools': gst_tools,
 519 }, section: 'Build options', list_sep: ', ')