meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.19.0.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 api_version = '1.0'
  19 libavfilter_dep = dependency('libavfilter', version: '>= 7.16.100',
  20   fallback: ['FFmpeg', 'libavfilter_dep'])
  21 libavformat_dep = dependency('libavformat', version: '>= 58.12.100',
  22   fallback: ['FFmpeg', 'libavformat_dep'])
  23 libavcodec_dep = dependency('libavcodec', version: '>= 58.18.100',
  24   fallback: ['FFmpeg', 'libavcodec_dep'])
  25 libavutil_dep = dependency('libavutil', version: '>= 56.14.100',
  26   fallback: ['FFmpeg', 'libavutil_dep'])
  27
  28 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  29
  30 cc = meson.get_compiler('c')
  31
  32 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  33 #if LIBAVCODEC_VERSION_MICRO >= 100
  34 /* FFmpeg uses 100+ as its micro version */
  35 #else
  36 #error libav provider should be FFmpeg
  37 #endif'''
  38
  39 libav_deps_type_name = ''
  40
  41 foreach dep: libav_deps
  42   if libav_deps_type_name != '' and dep.type_name() != libav_deps_type_name
  43     error('Libav deps must be either all internal or all external')
  44   endif
  45   libav_deps_type_name = dep.type_name()
  46 endforeach
  47
  48 if dep.type_name() != 'internal'
  49   if not cc.compiles(check_ffmpeg_src, dependencies : libav_deps, name : 'libav is provided by FFmpeg')
  50     error('Uncompatible libavcodec found')
  51   endif
  52 endif
  53
  54 cdata = configuration_data()
  55 cdata.set('LIBAV_SOURCE', '"system install"')
  56 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  57 cdata.set('PACKAGE', '"gst-libav"')
  58
  59 # GStreamer package name and origin url
  60 gst_package_name = get_option('package-name')
  61 if gst_package_name == ''
  62   if gst_version_nano == 0
  63     gst_package_name = 'GStreamer FFMPEG Plug-ins source release'
  64   elif gst_version_nano == 1
  65     gst_package_name = 'GStreamer FFMPEG Plug-ins git'
  66   else
  67     gst_package_name = 'GStreamer FFMPEG Plug-ins prerelease'
  68   endif
  69 endif
  70 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  71 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
  72
  73
  74 check_headers = [['unistd.h', 'HAVE_UNISTD_H']]
  75
  76 foreach h : check_headers
  77   if cc.has_header(h.get(0))
  78     cdata.set(h.get(1), 1)
  79   endif
  80 endforeach
  81
  82 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  83 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  84   fallback : ['gstreamer', 'gst_dep'])
  85 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  86   fallback : ['gstreamer', 'gst_base_dep'])
  87
  88 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  89     fallback : ['gst-plugins-base', 'video_dep'])
  90 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
  91     fallback : ['gst-plugins-base', 'audio_dep'])
  92 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  93     fallback : ['gst-plugins-base', 'pbutils_dep'])
  94 libm = cc.find_library('m', required : false)
  95
  96 gst_libav_args = ['-DHAVE_CONFIG_H']
  97 if cc.get_id() == 'msvc'
  98   # Ignore several spurious warnings for things gstreamer does very commonly
  99   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
 100   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
 101   # NOTE: Only add warnings here if you are sure they're spurious
 102   add_project_arguments(
 103       '/wd4018', # implicit signed/unsigned conversion
 104       '/wd4146', # unary minus on unsigned (beware INT_MIN)
 105       '/wd4244', # lossy type conversion (e.g. double -> int)
 106       '/wd4305', # truncating type conversion (e.g. double -> float)
 107       language : 'c')
 108 endif
 109
 110 # Symbol visibility
 111 if cc.has_argument('-fvisibility=hidden')
 112   add_project_arguments('-fvisibility=hidden', language: 'c')
 113 endif
 114
 115 # Don't export any symbols from static ffmpeg libraries
 116 if cc.has_link_argument('-Wl,--exclude-libs=ALL')
 117   add_project_link_arguments('-Wl,--exclude-libs=ALL', language: 'c')
 118 endif
 119
 120 # Disable strict aliasing
 121 if cc.has_argument('-fno-strict-aliasing')
 122   add_project_arguments('-fno-strict-aliasing', language: 'c')
 123 endif
 124
 125 if gst_dep.type_name() == 'internal'
 126     gst_proj = subproject('gstreamer')
 127
 128     if not gst_proj.get_variable('gst_debug')
 129         message('GStreamer debug system is disabled')
 130         add_project_arguments('-Wno-unused', language: 'c')
 131     else
 132         message('GStreamer debug system is enabled')
 133     endif
 134 else
 135     # We can't check that in the case of subprojects as we won't
 136     # be able to build against an internal dependency (which is not built yet)
 137     if not cc.compiles('''
 138 #include <gst/gstconfig.h>
 139 #ifdef GST_DISABLE_GST_DEBUG
 140 #error "debugging disabled, make compiler fail"
 141 #endif''' , dependencies: gst_dep)
 142         message('GStreamer debug system is disabled')
 143         add_project_arguments('-Wno-unused', language: 'c')
 144     else
 145         message('GStreamer debug system is enabled')
 146     endif
 147 endif
 148
 149 warning_flags = [
 150   '-Wmissing-declarations',
 151   '-Wmissing-prototypes',
 152   '-Wold-style-definition',
 153   '-Wredundant-decls',
 154   '-Wundef',
 155   '-Wwrite-strings',
 156   '-Wformat',
 157   '-Wformat-nonliteral',
 158   '-Wformat-security',
 159   '-Winit-self',
 160   '-Wmissing-include-dirs',
 161   '-Waddress',
 162   '-Wno-multichar',
 163   '-Waggregate-return',
 164   '-Wdeclaration-after-statement',
 165   '-Wvla',
 166   '-Wpointer-arith',
 167 ]
 168
 169 foreach extra_arg : warning_flags
 170   if cc.has_argument (extra_arg)
 171     add_project_arguments([extra_arg], language: 'c')
 172   endif
 173 endforeach
 174
 175 configinc = include_directories('.')
 176 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 177
 178 pkgconfig = import('pkgconfig')
 179 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 180 if get_option('default_library') == 'shared'
 181   # If we don't build static plugins there is no need to generate pc files
 182   plugins_pkgconfig_install_dir = disabler()
 183 endif
 184
 185 plugins = []
 186 subdir('ext/libav')
 187 subdir('docs')
 188
 189 # Set release date
 190 if gst_version_nano == 0
 191   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 192   run_result = run_command(extract_release_date, gst_version, files('gst-libav.doap'))
 193   if run_result.returncode() == 0
 194     release_date = run_result.stdout().strip()
 195     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 196     message('Package release date: ' + release_date)
 197   else
 198     # Error out if our release can't be found in the .doap file
 199     error(run_result.stderr())
 200   endif
 201 endif
 202
 203 configure_file(output: 'config.h', configuration: cdata)
 204
 205 python3 = import('python').find_installation()
 206 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')