meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.17.2.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version = meson.project_version()
  10 version_arr = gst_version.split('.')
  11 gst_version_major = version_arr[0].to_int()
  12 gst_version_minor = version_arr[1].to_int()
  13 gst_version_micro = version_arr[2].to_int()
  14  if version_arr.length() == 4
  15   gst_version_nano = version_arr[3].to_int()
  16 else
  17   gst_version_nano = 0
  18 endif
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 curversion = gst_version_minor * 100 + gst_version_micro
  25 libversion = '@0@.@1@.0'.format(soversion, curversion)
  26 osxversion = curversion + 1
  27
  28 glib_req = '>= 2.44.0'
  29 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  30
  31 cc = meson.get_compiler('c')
  32 mathlib = cc.find_library('m', required : false)
  33
  34 cdata = configuration_data()
  35
  36 # Ignore several spurious warnings for things gstreamer does very commonly
  37 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39 # NOTE: Only add warnings here if you are sure they're spurious
  40 if cc.get_id() == 'msvc'
  41   add_project_arguments(
  42       '/wd4018', # implicit signed/unsigned conversion
  43       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  44       '/wd4244', # lossy type conversion (e.g. double -> int)
  45       '/wd4305', # truncating type conversion (e.g. double -> float)
  46       language : 'c')
  47 endif
  48
  49 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  50   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  51 endif
  52
  53 # Symbol visibility
  54 if cc.get_id() == 'msvc'
  55   export_define = '__declspec(dllexport) extern'
  56 elif cc.has_argument('-fvisibility=hidden')
  57   add_project_arguments('-fvisibility=hidden', language: 'c')
  58   export_define = 'extern __attribute__ ((visibility ("default")))'
  59 else
  60   export_define = 'extern'
  61 endif
  62
  63 # Passing this through the command line would be too messy
  64 cdata.set('GST_API_EXPORT', export_define)
  65
  66 # Disable strict aliasing
  67 if cc.has_argument('-fno-strict-aliasing')
  68   add_project_arguments('-fno-strict-aliasing', language: 'c')
  69 endif
  70
  71 cdata.set('VERSION', '"@0@"'.format(gst_version))
  72 cdata.set('PACKAGE', '"gst-editing-services"')
  73 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  74 cdata.set('PACKAGE_BUGREPORT', '"https://gitlab.freedesktop.org/gstreamer/gst-editing-services/issues/new"')
  75 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  76 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  77 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  78 cdata.set('GST_LICENSE', '"LGPL"')
  79
  80 # Mandatory GST deps
  81 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  82     fallback : ['gstreamer', 'gst_dep'])
  83 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  84     fallback : ['gst-plugins-base', 'pbutils_dep'])
  85 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  86     fallback : ['gst-plugins-base', 'video_dep'])
  87 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  88     fallback : ['gstreamer', 'gst_base_dep'])
  89 if host_machine.system() != 'windows'
  90   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  91     required : get_option('tests'),
  92     fallback : ['gstreamer', 'gst_check_dep'])
  93 endif
  94 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  95   fallback : ['gstreamer', 'gst_controller_dep'])
  96 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : get_option('validate'),
  97   fallback : ['gst-devtools', 'validate_dep'])
  98
  99 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 100 libxml_dep = dependency('libxml-2.0', required: get_option('xptv'))
 101 cdata.set('DISABLE_XPTV', not libxml_dep.found())
 102
 103 # TODO Properly port to Gtk 3
 104 # gtk_dep = dependency('gtk+-3.0', required : false)
 105
 106 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
 107                gstcontroller_dep, gio_dep, libxml_dep, mathlib]
 108
 109 if gstvalidate_dep.found()
 110     libges_deps = libges_deps + [gstvalidate_dep]
 111     cdata.set('HAVE_GST_VALIDATE', 1)
 112 endif
 113
 114 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 115 gnome = import('gnome')
 116
 117 # Fixme, not very elegant.
 118 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 119 gir_init_section = [ '--add-init-section=' + \
 120     'extern void gst_init(gint*,gchar**);' + \
 121     'extern void ges_init(void);' + \
 122     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 123     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 124     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 125     'g_setenv("GST_DEBUG", "0", TRUE);' + \
 126     'gst_init(NULL,NULL);' + \
 127     'ges_init();', '--quiet']
 128
 129 has_python = false
 130 if build_gir
 131   pymod = import('python')
 132   python = pymod.find_installation(required: get_option('python'))
 133   if python.found()
 134     # Workaround for https://github.com/mesonbuild/meson/issues/5629
 135     pythonver = python.language_version()
 136     python_dep = dependency('python-@0@-embed'.format(pythonver), version: '>=3', required: false)
 137     if not python_dep.found()
 138       python_dep = python.dependency(required : get_option('python'))
 139     endif
 140   else
 141     python_dep = dependency('', required: false)
 142   endif
 143   if python_dep.found()
 144     python_abi_flags = python.get_variable('ABIFLAGS', '')
 145     pylib_loc = get_option('libpython-dir')
 146
 147     error_msg = ''
 148     if not cc.compiles('#include <Python.h>', dependencies: [python_dep])
 149       error_msg = 'Could not compile a simple program against python'
 150     elif pylib_loc == ''
 151       check_path_exists = 'import os, sys; assert(os.path.exists(sys.argv[1]))'
 152       pylib_loc = python.get_variable('LIBPL', '')
 153       if host_machine.system() != 'windows' and host_machine.system() != 'darwin'
 154         pylib_ldlibrary = python.get_variable('LDLIBRARY', '')
 155         if run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary)).returncode() != 0
 156           # Workaround for Fedora
 157           pylib_loc = python.get_variable('LIBDIR', '')
 158           message('pylib_loc = @0@'.format(pylib_loc))
 159         endif
 160
 161         res = run_command(python, '-c', check_path_exists, join_paths(pylib_loc, pylib_ldlibrary))
 162         if res.returncode() != 0
 163           error_msg = '@0@ doesn\' exist, can\'t use python'.format(join_paths(pylib_loc, pylib_ldlibrary))
 164         endif
 165       endif
 166       if error_msg == ''
 167         pylib_suffix = 'so'
 168         if host_machine.system() == 'windows'
 169           pylib_suffix = 'dll'
 170         elif host_machine.system() == 'darwin'
 171           pylib_suffix = 'dylib'
 172         endif
 173
 174         gmodule_dep = dependency('gmodule-2.0')
 175         libges_deps = libges_deps + [python_dep, gmodule_dep]
 176         has_python = true
 177         message('python_abi_flags = @0@'.format(python_abi_flags))
 178         message('pylib_loc = @0@'.format(pylib_loc))
 179         cdata.set('HAS_PYTHON', true)
 180         cdata.set('PY_LIB_LOC', '"@0@"'.format(pylib_loc))
 181         cdata.set('PY_ABI_FLAGS', '"@0@"'.format(python_abi_flags))
 182         cdata.set('PY_LIB_SUFFIX', '"@0@"'.format(pylib_suffix))
 183         cdata.set('PYTHON_VERSION', '"@0@"'.format(python_dep.version()))
 184       else
 185           if get_option('python').enabled()
 186             error(error_msg)
 187           else
 188             message(error_msg)
 189           endif
 190       endif
 191     endif
 192   endif
 193 endif
 194
 195 ges_c_args = ['-DHAVE_CONFIG_H', '-DG_LOG_DOMAIN="GES"']
 196 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 197
 198 pkgconfig = import('pkgconfig')
 199 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 200 if get_option('default_library') == 'shared'
 201   # If we don't build static plugins there is no need to generate pc files
 202   plugins_pkgconfig_install_dir = disabler()
 203 endif
 204
 205 if gst_dep.type_name() == 'internal'
 206   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 207 else
 208   # We can't check that in the case of subprojects as we won't
 209   # be able to build against an internal dependency (which is not built yet)
 210   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 211 endif
 212
 213 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 214   add_project_arguments('-Wno-unused', language: 'c')
 215 endif
 216
 217 warning_flags = [
 218   '-Wmissing-declarations',
 219   '-Wmissing-prototypes',
 220   '-Wredundant-decls',
 221   '-Wundef',
 222   '-Wwrite-strings',
 223   '-Wformat',
 224   '-Wformat-security',
 225   '-Winit-self',
 226   '-Wmissing-include-dirs',
 227   '-Waddress',
 228   '-Wno-multichar',
 229   '-Wdeclaration-after-statement',
 230   '-Wvla',
 231   '-Wpointer-arith',
 232 ]
 233
 234 foreach extra_arg : warning_flags
 235   if cc.has_argument (extra_arg)
 236     add_project_arguments([extra_arg], language: 'c')
 237   endif
 238 endforeach
 239
 240 python3 = import('python').find_installation()
 241 configinc = include_directories('.')
 242 subdir('ges')
 243 subdir('plugins')
 244 subdir('tools')
 245 subdir('pkgconfig')
 246 subdir('tests')
 247 subdir('examples')
 248 subdir('docs')
 249
 250 override_detector = '''
 251 import sys
 252 import os
 253
 254 prefix = sys.argv[1]
 255 version = sys.version_info
 256
 257 # If we are installing in the same prefix as PyGobject
 258 # make sure to install in the right place.
 259 import gi.overrides
 260
 261 overrides_path = os.path.dirname(gi.overrides.__file__)
 262 if os.path.commonprefix([overrides_path, prefix]) == prefix:
 263     print(overrides_path)
 264     exit(0)
 265
 266 # Otherwise follow python's way of install site packages inside
 267 # the provided prefix
 268 if os.name == 'posix':
 269     print(os.path.join(
 270         prefix, 'lib', 'python%d.%d' % (version.major, version.minor),
 271         'site-packages', 'gi', 'overrides'))
 272 else:
 273     print(os.path.join(
 274         prefix, 'Lib', 'Python%d%d' % (version.major, version.minor),
 275         'site-packages', 'gi', 'overrides'))
 276 '''
 277 pygi_override_dir = get_option('pygi-overrides-dir')
 278 if pygi_override_dir == ''
 279     cres = run_command(python3, '-c', override_detector, get_option('prefix'))
 280     if cres.returncode() == 0
 281       pygi_override_dir = cres.stdout().strip()
 282     endif
 283     if cres.stderr() != ''
 284         message(cres.stderr())
 285     endif
 286 endif
 287
 288 if pygi_override_dir != ''
 289   message('pygobject overrides directory ' + pygi_override_dir)
 290   subdir('bindings/python')
 291 endif
 292
 293 # Set release date
 294 if gst_version_nano == 0
 295   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 296   run_result = run_command(extract_release_date, gst_version, files('gst-editing-services.doap'))
 297   if run_result.returncode() == 0
 298     release_date = run_result.stdout().strip()
 299     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 300     message('Package release date: ' + release_date)
 301   else
 302     # Error out if our release can't be found in the .doap file
 303     error(run_result.stderr())
 304   endif
 305 endif
 306
 307 configure_file(output: 'config.h', configuration: cdata)
 308
 309 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')