m4/esd.m4

   1 # Configure paths for ESD
   2 # Manish Singh    98-9-30
   3 # stolen back from Frank Belew
   4 # stolen from Manish Singh
   5 # Shamelessly stolen from Owen Taylor
   6
   7 dnl AM_PATH_ESD([MINIMUM-VERSION, [ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND]]])
   8 dnl Test for ESD, and define ESD_CFLAGS and ESD_LIBS
   9 dnl
  10 AC_DEFUN([AM_PATH_ESD],
  11 [dnl
  12 dnl Get the cflags and libraries from the esd-config script
  13 dnl
  14 AC_ARG_WITH(esd-prefix,
  15   AC_HELP_STRING([--with-esd-prefix=PFX],
  16                  [prefix where ESD is installed (optional)]),
  17   esd_prefix="$withval", esd_prefix="")
  18
  19 AC_ARG_WITH(esd-exec-prefix,
  20   AC_HELP_STRING([--with-esd-exec-prefix=PFX],
  21                  [exec prefix where ESD is installed (optional)]),
  22   esd_exec_prefix="$withval", esd_exec_prefix="")
  23
  24 AC_ARG_ENABLE(esdtest,
  25   AC_HELP_STRING([--disable-esdtest],
  26                  [do not try to compile and run a test ESD program]),
  27   , enable_esdtest=yes)
  28
  29   if test x$esd_exec_prefix != x ; then
  30      esd_args="$esd_args --exec-prefix=$esd_exec_prefix"
  31      if test x${ESD_CONFIG+set} != xset ; then
  32         ESD_CONFIG=$esd_exec_prefix/bin/esd-config
  33      fi
  34   fi
  35   if test x$esd_prefix != x ; then
  36      esd_args="$esd_args --prefix=$esd_prefix"
  37      if test x${ESD_CONFIG+set} != xset ; then
  38         ESD_CONFIG=$esd_prefix/bin/esd-config
  39      fi
  40   fi
  41
  42   AC_PATH_PROG(ESD_CONFIG, esd-config, no)
  43   min_esd_version=ifelse([$1], ,0.2.7,$1)
  44   AC_MSG_CHECKING(for ESD - version >= $min_esd_version)
  45   no_esd=""
  46   if test "$ESD_CONFIG" = "no" ; then
  47     no_esd=yes
  48   else
  49     AC_LANG_SAVE
  50     AC_LANG_C
  51     ESD_CFLAGS=`$ESD_CONFIG $esdconf_args --cflags`
  52     ESD_LIBS=`$ESD_CONFIG $esdconf_args --libs`
  53
  54     esd_major_version=`$ESD_CONFIG $esd_args --version | \
  55            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
  56     esd_minor_version=`$ESD_CONFIG $esd_args --version | \
  57            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
  58     esd_micro_version=`$ESD_CONFIG $esd_config_args --version | \
  59            sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\3/'`
  60     if test "x$enable_esdtest" = "xyes" ; then
  61       ac_save_CFLAGS="$CFLAGS"
  62       ac_save_LIBS="$LIBS"
  63       CFLAGS="$CFLAGS $ESD_CFLAGS"
  64       LIBS="$LIBS $ESD_LIBS"
  65 dnl
  66 dnl Now check if the installed ESD is sufficiently new. (Also sanity
  67 dnl checks the results of esd-config to some extent
  68 dnl
  69       rm -f conf.esdtest
  70       AC_TRY_RUN([
  71 #include <stdio.h>
  72 #include <stdlib.h>
  73 #include <string.h>
  74 #include <esd.h>
  75
  76 char*
  77 my_strdup (char *str)
  78 {
  79   char *new_str;
  80
  81   if (str)
  82     {
  83       new_str = malloc ((strlen (str) + 1) * sizeof(char));
  84       strcpy (new_str, str);
  85     }
  86   else
  87     new_str = NULL;
  88
  89   return new_str;
  90 }
  91
  92 int main ()
  93 {
  94   int major, minor, micro;
  95   char *tmp_version;
  96
  97   system ("touch conf.esdtest");
  98
  99   /* HP/UX 9 (%@#!) writes to sscanf strings */
 100   tmp_version = my_strdup("$min_esd_version");
 101   if (sscanf(tmp_version, "%d.%d.%d", &major, &minor, &micro) != 3) {
 102      printf("%s, bad version string\n", "$min_esd_version");
 103      exit(1);
 104    }
 105
 106    if (($esd_major_version > major) ||
 107       (($esd_major_version == major) && ($esd_minor_version > minor)) ||
 108       (($esd_major_version == major) && ($esd_minor_version == minor) && ($esd_micro_version >= micro)))
 109     {
 110       return 0;
 111     }
 112   else
 113     {
 114       printf("\n*** 'esd-config --version' returned %d.%d.%d, but the minimum version\n", $esd_major_version, $esd_minor_version, $esd_micro_version);
 115       printf("*** of ESD required is %d.%d.%d. If esd-config is correct, then it is\n", major, minor, micro);
 116       printf("*** best to upgrade to the required version.\n");
 117       printf("*** If esd-config was wrong, set the environment variable ESD_CONFIG\n");
 118       printf("*** to point to the correct copy of esd-config, and remove the file\n");
 119       printf("*** config.cache before re-running configure\n");
 120       return 1;
 121     }
 122 }
 123
 124 ],, no_esd=yes,[echo $ac_n "cross compiling; assumed OK... $ac_c"])
 125        CFLAGS="$ac_save_CFLAGS"
 126        LIBS="$ac_save_LIBS"
 127        AC_LANG_RESTORE
 128      fi
 129   fi
 130   if test "x$no_esd" = x ; then
 131      AC_MSG_RESULT(yes)
 132      ifelse([$2], , :, [$2])
 133   else
 134      AC_MSG_RESULT(no)
 135      if test "$ESD_CONFIG" = "no" ; then
 136        echo "*** The esd-config script installed by ESD could not be found"
 137        echo "*** If ESD was installed in PREFIX, make sure PREFIX/bin is in"
 138        echo "*** your path, or set the ESD_CONFIG environment variable to the"
 139        echo "*** full path to esd-config."
 140      else
 141        if test -f conf.esdtest ; then
 142         :
 143        else
 144           echo "*** Could not run ESD test program, checking why..."
 145           CFLAGS="$CFLAGS $ESD_CFLAGS"
 146           LIBS="$LIBS $ESD_LIBS"
 147           AC_LANG_SAVE
 148           AC_LANG_C
 149           AC_TRY_LINK([
 150 #include <stdio.h>
 151 #include <esd.h>
 152 ],      [ return 0; ],
 153         [ echo "*** The test program compiled, but did not run. This usually means"
 154           echo "*** that the run-time linker is not finding ESD or finding the wrong"
 155           echo "*** version of ESD. If it is not finding ESD, you'll need to set your"
 156           echo "*** LD_LIBRARY_PATH environment variable, or edit /etc/ld.so.conf to point"
 157           echo "*** to the installed location  Also, make sure you have run ldconfig if that"
 158           echo "*** is required on your system"
 159           echo "***"
 160           echo "*** If you have an old version installed, it is best to remove it, although"
 161           echo "*** you may also be able to get things to work by modifying LD_LIBRARY_PATH"],
 162         [ echo "*** The test program failed to compile or link. See the file config.log for the"
 163           echo "*** exact error that occured. This usually means ESD was incorrectly installed"
 164           echo "*** or that you have moved ESD since it was installed. In the latter case, you"
 165           echo "*** may want to edit the esd-config script: $ESD_CONFIG" ])
 166           CFLAGS="$ac_save_CFLAGS"
 167           LIBS="$ac_save_LIBS"
 168           AC_LANG_RESTORE
 169        fi
 170      fi
 171      ESD_CFLAGS=""
 172      ESD_LIBS=""
 173      ifelse([$3], , :, [$3])
 174   fi
 175   AC_SUBST(ESD_CFLAGS)
 176   AC_SUBST(ESD_LIBS)
 177   rm -f conf.esdtest
 178 ])
 179
 180 dnl AM_ESD_SUPPORTS_MULTIPLE_RECORD([ACTION-IF-SUPPORTS [, ACTION-IF-NOT-SUPPORTS]])
 181 dnl Test, whether esd supports multiple recording clients (version >=0.2.21)
 182 dnl
 183 AC_DEFUN([AM_ESD_SUPPORTS_MULTIPLE_RECORD],
 184 [dnl
 185   AC_MSG_NOTICE([whether installed esd version supports multiple recording clients])
 186   ac_save_ESD_CFLAGS="$ESD_CFLAGS"
 187   ac_save_ESD_LIBS="$ESD_LIBS"
 188   AM_PATH_ESD(0.2.21,
 189     ifelse([$1], , [
 190       AM_CONDITIONAL(ESD_SUPPORTS_MULTIPLE_RECORD, true)
 191       AC_DEFINE(ESD_SUPPORTS_MULTIPLE_RECORD, 1,
 192         [Define if you have esound with support of multiple recording clients.])],
 193     [$1]),
 194     ifelse([$2], , [AM_CONDITIONAL(ESD_SUPPORTS_MULTIPLE_RECORD, false)], [$2])
 195     if test "x$ac_save_ESD_CFLAGS" != x ; then
 196        ESD_CFLAGS="$ac_save_ESD_CFLAGS"
 197     fi
 198     if test "x$ac_save_ESD_LIBS" != x ; then
 199        ESD_LIBS="$ac_save_ESD_LIBS"
 200     fi
 201   )
 202 ])