libs/gst/net/meson.build

   1 gst_net_sources = [
   2   'gstnetaddressmeta.c',
   3   'gstnetclientclock.c',
   4   'gstnetcontrolmessagemeta.c',
   5   'gstnettimepacket.c',
   6   'gstnettimeprovider.c',
   7   'gstptpclock.c',
   8   'gstntppacket.c',
   9   'gstnetutils.c',
  10 ]
  11
  12 gst_net_headers = [
  13  'gstnet.h',
  14  'gstnetaddressmeta.h',
  15  'gstnetclientclock.h',
  16  'gstnetcontrolmessagemeta.h',
  17  'gstnettimepacket.h',
  18  'gstnettimeprovider.h',
  19  'gstptpclock.h',
  20  'net-prelude.h',
  21  'net.h',
  22 ]
  23 install_headers(gst_net_headers, subdir : 'gstreamer-1.0/gst/net/')
  24
  25 gst_net_gen_sources = []
  26 gst_net = library('gstnet-@0@'.format(apiversion),
  27   gst_net_sources,
  28   c_args : gst_c_args,
  29   include_directories : [configinc, libsinc],
  30   version : libversion,
  31   soversion : soversion,
  32   darwin_versions : osxversion,
  33   install : true,
  34   dependencies : [gio_dep, gst_base_dep],
  35 )
  36
  37 if build_gir
  38   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/net/net.h' ]
  39   gst_net_gir = gnome.generate_gir(gst_net,
  40     sources : gst_net_sources + gst_net_headers,
  41     namespace : 'GstNet',
  42     nsversion : apiversion,
  43     identifier_prefix : 'Gst',
  44     symbol_prefix : 'gst',
  45     export_packages : 'gstreamer-net-1.0',
  46     dependencies : [gst_base_dep],
  47     include_directories : [configinc, libsinc],
  48     includes : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gio-2.0', 'Gst-1.0'],
  49     install : true,
  50     extra_args : gst_gir_extra_args,
  51   )
  52   gst_net_gen_sources += [gst_net_gir]
  53 endif
  54
  55 gst_net_dep = declare_dependency(link_with : gst_net,
  56   include_directories : [libsinc],
  57   sources: gst_net_gen_sources,
  58   dependencies : [gst_base_dep])