libs/gst/net/meson.build

   1 gst_net_sources = [
   2   'gstnetaddressmeta.c',
   3   'gstnetclientclock.c',
   4   'gstnetcontrolmessagemeta.c',
   5   'gstnettimepacket.c',
   6   'gstnettimeprovider.c',
   7   'gstptpclock.c',
   8   'gstntppacket.c',
   9   'gstnetutils.c',
  10 ]
  11
  12 gst_net_headers = [
  13  'gstnet.h',
  14  'gstnetaddressmeta.h',
  15  'gstnetclientclock.h',
  16  'gstnetcontrolmessagemeta.h',
  17  'gstnettimepacket.h',
  18  'gstnettimeprovider.h',
  19  'gstptpclock.h',
  20  'net-prelude.h',
  21  'net.h',
  22 ]
  23 install_headers(gst_net_headers, subdir : 'gstreamer-1.0/gst/net/')
  24
  25 if libtype != 'shared'
  26   gst_net_static = static_library('gstnet-@0@'.format(apiversion),
  27     gst_net_sources,
  28     c_args : gst_c_args,
  29     include_directories : [configinc, libsinc],
  30     install : true,
  31     dependencies : [gio_dep, gst_base_dep],
  32   )
  33   gst_net = gst_net_static
  34 endif
  35
  36 gst_net_gen_sources = []
  37 if libtype != 'static'
  38   gst_net_shared = shared_library('gstnet-@0@'.format(apiversion),
  39     gst_net_sources,
  40     c_args : gst_c_args,
  41     include_directories : [configinc, libsinc],
  42     version : libversion,
  43     soversion : soversion,
  44     install : true,
  45     dependencies : [gio_dep, gst_base_dep],
  46   )
  47   gst_net = gst_net_shared
  48   if build_gir
  49     gst_gir_extra_args = gir_init_section + [ '--c-include=gst/net/net.h' ]
  50     gst_net_gir = gnome.generate_gir(gst_net_shared,
  51       sources : gst_net_sources + gst_net_headers,
  52       namespace : 'GstNet',
  53       nsversion : apiversion,
  54       identifier_prefix : 'Gst',
  55       symbol_prefix : 'gst',
  56       export_packages : 'gstreamer-net-1.0',
  57       dependencies : [gst_base_dep],
  58       include_directories : [configinc, libsinc],
  59       includes : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gio-2.0', 'Gst-1.0'],
  60       install : true,
  61       extra_args : gst_gir_extra_args,
  62     )
  63     gst_net_gen_sources += [gst_net_gir]
  64   endif
  65 endif
  66
  67 gst_net_dep = declare_dependency(link_with : gst_net,
  68   include_directories : [libsinc],
  69   sources: gst_net_gen_sources,
  70   dependencies : [gst_base_dep])