libs/gst/controller/meson.build

   1 gst_controller_sources = [
   2   'gstargbcontrolbinding.c',
   3   'gstdirectcontrolbinding.c',
   4   'gsttimedvaluecontrolsource.c',
   5   'gstinterpolationcontrolsource.c',
   6   'gstproxycontrolbinding.c',
   7   'gsttriggercontrolsource.c',
   8   'gstlfocontrolsource.c',
   9 ]
  10
  11 controller_mkenum_headers = [
  12   'gstinterpolationcontrolsource.h',
  13   'gstlfocontrolsource.h',
  14 ]
  15
  16 gst_controller_headers = controller_mkenum_headers + [
  17   'gstargbcontrolbinding.h',
  18   'gstdirectcontrolbinding.h',
  19   'gsttimedvaluecontrolsource.h',
  20   'gstinterpolationcontrolsource.h',
  21   'gstproxycontrolbinding.h',
  22   'gsttriggercontrolsource.h',
  23   'gstlfocontrolsource.h',
  24   'controller-prelude.h',
  25   'controller.h',
  26 ]
  27 install_headers(gst_controller_headers, subdir : 'gstreamer-1.0/gst/controller/')
  28
  29 controller_enums = gnome.mkenums_simple('controller-enumtypes',
  30   sources : controller_mkenum_headers,
  31   header_prefix : '#include <gst/controller/controller-prelude.h>',
  32   body_prefix : '#include "config.h"',
  33   decorator : 'GST_CONTROLLER_API',
  34   install_header : true,
  35   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/controller'))
  36 gstcontroller_c = controller_enums[0]
  37 gstcontroller_h = controller_enums[1]
  38
  39 gst_controller_gen_sources = [gstcontroller_h]
  40 gst_controller = library('gstcontroller-@0@'.format(apiversion),
  41   gst_controller_sources, gstcontroller_h, gstcontroller_c,
  42   c_args : gst_c_args + ['-DBUILDING_GST_CONTROLLER'],
  43   install : true,
  44   version : libversion,
  45   soversion : soversion,
  46   darwin_versions : osxversion,
  47   include_directories : [configinc, libsinc],
  48   dependencies : [gobject_dep, glib_dep, mathlib, gst_dep],
  49 )
  50
  51 if build_gir
  52   gst_gir_extra_args = gir_init_section + [ '--c-include=gst/controller/controller.h' ]
  53   gst_controller_gir = gnome.generate_gir(gst_controller,
  54     sources : gst_controller_sources + gst_controller_headers + [gstcontroller_h] + [gstcontroller_c],
  55     namespace : 'GstController',
  56     nsversion : apiversion,
  57     identifier_prefix : 'Gst',
  58     symbol_prefix : 'gst',
  59     export_packages : 'gstreamer-controller-1.0',
  60     dependencies : [gst_dep],
  61     include_directories : [configinc, libsinc, privinc],
  62     includes : ['GLib-2.0', 'GObject-2.0', 'GModule-2.0', 'Gst-1.0'],
  63     install : true,
  64     extra_args : gst_gir_extra_args,
  65   )
  66   gst_controller_gen_sources += [gst_controller_gir]
  67 endif
  68
  69 gst_controller_dep = declare_dependency(link_with : gst_controller,
  70   include_directories : [libsinc],
  71   sources: gst_controller_gen_sources,
  72   dependencies : [gst_dep])